version=2

	@Text.Show(Welcome to the Battle Factory!*I oversee trainer's individual~challenges.*This is the~Challenge Mode.~If you would like to enter~the factory, you must have~only 1 Pokémon.*Also, you have to save~your game before entering.*Would you like to~challenge the Factory?)
	@Options.Show(Yes,No)
	:when:Yes
		@player.save
		@sound.play(Save)
		@text.show(<player.name>~saved the game.)
		@storage.set(boolean,thirdperson,<player.thirdperson>)

		:if:<pokemon.count>>1
		:then
			@Text.Show(Please remove <system.calcint(<pokemon.count>-1)> Pokémon~from your party.)
			@Screen.StorageSystem
		:endif

		:if:<register.registered(frontier_battlefactory_challenge_values_created)>=false
		:then
			@register.register(battlefactory_challenge_50_class,INT,0)
			@register.register(battlefactory_challenge_50_best,INT,0)
			@register.register(battlefactory_challenge_50_previous_streak,INT,0)
			@register.register(battlefactory_challenge_100_class,INT,0)
			@register.register(battlefactory_challenge_100_best,INT,0)
			@register.register(battlefactory_challenge_100_previous_streak,INT,0)
			@register.register(frontier_battlefactory_challenge_values_created)
		:endif		

		@storage.set(integer,factory_streak,0)
		@storage.set(boolean,factory_brain,false)

		:if:<pokemon.count>=1 <and> <pokemon.countbattle>=1
		:then
			@text.show(Which challenge do~you want to start?)
			@options.show(Lv. 50,Lv. 100,Cancel)
			:when:Lv. 50
				@storage.set(integer,factory_level,50)
				@storage.set(integer,previous_streak,<register.value(battlefactory_challenge_50_previous_streak)>)
				@storage.set(integer,factory_class,<register.value(battlefactory_challenge_50_class)>)
			:when:Lv. 100
				@storage.set(integer,factory_level,100)
				@storage.set(integer,previous_streak,<register.value(battlefactory_challenge_100_previous_streak)>)
				@storage.set(integer,factory_class,<register.value(battlefactory_challenge_100_class)>)
			:when:Cancel
				@Text.Show(Well, come back and see~us again when you have*prepared yourself for~the challenge.)
				:endscript
			:endwhen
			
			@pokemon.heal
			@storage.set(string,factory_pokemonstore,<pokemon.data(0)>)
			@pokemon.clear

			@pokemon.add(<pokemon.generatefrontier(<storage.get(integer,factory_level)>,<storage.get(integer,factory_class)>)>)
			@pokemon.add(<pokemon.generatefrontier(<storage.get(integer,factory_level)>,<storage.get(integer,factory_class)>)>)
			@pokemon.add(<pokemon.generatefrontier(<storage.get(integer,factory_level)>,<storage.get(integer,factory_class)>)>)
			
			@Text.Show(Well, now you are~prepared.)
			@pokedex.setautodetect(0)

			@script.start(frontier\battlefactory\challenge\intro_walk)
		:else
			@Text.Show(It seems you have~too many Pokémon.*Please return when you are~prepared to use exactly~1 Pokémon.)
		:endif
	:when:No
		@Text.Show(Well, come back and see~us again when you have*prepared yourself for~the challenge.)
	:endwhen
:end