version=2

	#This is the script that controls the animation of the speed boat in the transition scene:
	@music.pause
	@player.warp(speedboatscene.dat,0,-2,0)
	@level.update
	@level.wait(15)
	@entity.warp(0,0,-0.5,0)
	:if:<camera.thirdperson>=1
		@storage.set(bool,c_thirdpersonbefore,1)
	:else
		@storage.set(bool,c_thirdpersonbefore,0)
	:endif
	@camera.activatethirdperson
	@camera.setfocus(entity,0)
	@camera.reset
	@camera.setposition(0,7.1,9.3)
	@camera.setpitch(-0.7)
	@camera.update
	#This controls the current fading state of the screen:
	@storage.set(int,c_fade,255)
	@level.wait(10)
	@music.play(MagnetTrain,0)
	@music.resume
	:while:<entity.positionx(0)><170

		@entity.addtoposition(0,0.4,0,0)
		@camera.setyaw(<camera.yaw>+0.015)
		@level.update
		
		:if:<entity.positionx(0)>>135
			@storage.update(int,c_fade,+,3)
			@screen.setfade(<storage.get(int,c_fade)>)
		:else
			:if:<storage.get(int,c_fade)>>0
				@storage.update(int,c_fade,-,3)
				@screen.setfade(<storage.get(int,c_fade)>)
			:endif
		:endif

	:endwhile
	@level.wait(20)
	@screen.setfade(255)
	@camera.setfocustype(player)
	@camera.reset
	@camera.setpitch(0)
	:if:<storage.get(bool,c_thirdpersonbefore)>=0
		@camera.deactivatethirdperson
	:endif
:end