version=2

:if:<environment.day>=Tuesday <or> <environment.day>=Thursday <or> <environment.day>=Saturday
:then

:if:<register.registered(bugcontest_done)>=true
:then
#Contest done this week
@text.show(Today's Contest is~over. We hope you*will participate~in the future.)
:end
:endif

#Bug catching contest is today:
@text.show(Today's <environment.day>.~That means the*Bug-Catching Contest~is on today.*The rules are simple.*Using one of your~Pokémon, catch a*bug Pokémon to be~judged.*Would you like to~give it a try?)
@options.show(Yes,No)
:when:Yes

#Check for Pokemon in party:
:if:<pokemon.count>>1
:then
#Has more than 1 Pokemon in party, thus the script stops.
@text.show(Uh-oh...*You have more than~one Pokémon.*You'll have to deposit~all but one Pokémon to~boxes on the PC.)
:end
:endif

#Enter the contest (Remove all Sport Balls from bag, then add 20):
@register.registertime(bugcontest_done,1,day)

@text.show(Here are the Sport~Balls for the~Contest.)
@item.clearitem(177)
@item.give(177,20)
@item.messagegive(177,20)

@text.show(The person who~gets the strongest bug~Pokémon is the winner.*If you run out of~Sport Balls, you're~done.*You may keep the~last Pokémon you~catch as your own.*Go out and catch~the strongest bug*Pokémon you can~find!)

@music.play(bugcontest)
#make the player walk into the park + the wardens have to close the gate afterwards.
@player.turnto(1)
@player.move(3)
@player.turnto(2)
@player.move(1)
@player.turnto(1)
@player.move(1)
@screen.fadeout
@player.warp(nationalpark\contest.dat,13,0.1,47,3)
@level.update
@npc.warp(0,14,0,47)
@npc.warp(1,11,0,47)
@screen.fadein
@player.move(1)
@player.turnto(2)
@npc.turn(0,1)
@npc.turn(1,3)
@npc.move(0,1)
@npc.move(1,1)
@npc.turn(0,0)
@npc.turn(1,0)

@script.start(nationalpark\unregister_NPCs)

:when:No
@text.show(OK. We hope you'll~take part in the~future.)
:end
:endwhen

:else
#Not the correct day.
@text.show(Some Pokémon can~only be seen in the Park.)
:endif

:end