version=2

	@storage.set(str,billspcname,Someone's PC)

	:if:<register.registered(bill_encounter)>=true
		@storage.set(str,billspcname,Bill's PC)
	:endif

	:if:<pokemon.counthalloffame>>0
		@storage.set(str,computer_options,<storage.get(str,billspcname)>,Inbox,Prof. Oak's PC,Hall of Fame,Log off)
		@options.setcancelindex(4)
	:else
		:if:<player.haspokedex>=true
			@storage.set(str,computer_options,<storage.get(str,billspcname)>,Inbox,Prof. Oak's PC,Log off)
			@options.setcancelindex(3)
		:else
			@storage.set(str,computer_options,<storage.get(str,billspcname)>,Inbox,Log off)
			@options.setcancelindex(2)
		:endif
	:endif
	
	@options.show(<storage.get(str,computer_options)>)
		:when:<storage.get(str,billspcname)>
			@sound.play(PC\pc_logon)
			@screen.storagesystem
			@script.start(computer_choose)
		:when:Inbox
			@sound.play(PC\pc_logon)
			@screen.mailsystem
			@script.start(computer_choose)
		:when:Prof. Oak's PC
			@sound.play(PC\pc_logon)
			@script.start(pallet\evaldist)
			@text.show(Choose a host to~connect to.)
			@script.start(computer_choose)
		:when:Hall of Fame
			@sound.play(PC\pc_logon)
			@screen.halloffame
			@script.start(computer_choose)
		:when:Log off
			@sound.play(PC\pc_off)
			:endscript
	:endwhen

:end