version=2

:if:<register.registered(dmatron_first)>=false
	@text.show(They know me as the one~and only Dragon Matron!*My Dragon-type techniques~are unmatched!)
	@register.register(dmatron_first)
:endif

@text.show(If you've come to me,~you must be looking to~master the Dragon-type.)

:if:<player.badges><8
	@text.show(However, you must gather~more experience before you~are ready to handle the~power I have to share.)
:else
	@text.show(You are a respectable~trainer.*Tell me, do you want one~of your Pokémon to learn~the most powerful Dragon~move, Draco Meteor?)
	@options.show(Yes,No)
	:when:Yes
		@text.show(Present me the Dragon...)
		@pokemon.select(1)
		:if:<pokemon.selected>>-1
			:if:<pokemon.type1(<pokemon.selected>)>=dragon <or> <pokemon.type2(<pokemon.selected>)>=dragon <or> <pokemon.number(<pokemon.selected>)>=493 <or> <pokemon.number(<pokemon.selected>)>=773
				:if:<pokemon.hasattack(<pokemon.selected>,434)>=false
					@text.show(I shall teach it, then.)
					:if:<pokemon.countattacks(<pokemon.selected>)>=4
						@pokemon.learnattack(<pokemon.selected>,434)
						:if:<pokemon.hasattack(<pokemon.selected>,434)>=true
							@text.show(Now that <pokemon.name(<pokemon.selected>)>~masters the draconic power,~nothing stands a chance!)	
							:end
						:else
							@text.show(Such a waste of potential.*I'll be here if you change~your mind.)
							:end
						:endif
					:else
						@pokemon.addattack(<pokemon.selected>,434)
						@sound.play(success_small)
						@text.show(<pokemon.name(<pokemon.selected>)> learned~Draco Meteor!)
						@text.show(Now that <pokemon.name(<pokemon.selected>)>~masters the draconic power,~nothing stands a chance!)	
						:end
					:endif
				:else
					@text.show(That Pokémon is a master of~the draconic powers already.)
					:end
				:endif
			:else
				@text.show(Your <pokemon.name(<pokemon.selected>)> is~no Dragon, I'm afraid...)
				:end
			:endif
		:else
			@text.show(Such a waste of potential.*I'll be here if you change~your mind.)
			:end
		:endif
	:when:No
		@text.show(Such a waste of potential.*I'll be here if you change~your mind.)
		:end
	:endwhen
:endif

:end