version=2

	@npc.turn(0,3)
	@npc.move(0,2)
	@npc.turn(0,0)
	@npc.move(0,2)
	@npc.turn(0,1)
	@npc.move(0,3)
	@npc.turn(0,0)
	@npc.move(0,2)
	@npc.remove(0)

	@camera.deactivatethirdperson
	@player.turnto(1)
	@player.move(2)
	@player.turnto(2)
	@player.move(1)

	@text.show(You defeated opponent~no.<storage.get(integer,tower_streak)>.)
	@text.show(Allow me to heal your~Pokémon.)
	@pokemon.heal
	@screen.fadeout
	@sound.play(healing,True)
	@level.wait(150)
	@screen.fadein
	
	:if:<storage.get(integer,tower_streak)>=7 <or> <storage.get(integer,tower_streak)>=14
	:then
		:if:<storage.get(integer,tower_class)><2
		:then
			@register.change(battletower_challenge_<storage.get(integer,tower_level)>_class,<system.int(<storage.get(integer,tower_class)>+1)>)
		:endif
		@register.change(battletower_challenge_<storage.get(integer,tower_level)>_previous_streak,<math.int(7+<storage.get(integer,previous_streak)>)>)
	:endif

	@storage.set(integer,tower_class,<register.value(battletower_challenge_<storage.get(integer,tower_level)>_class)>)
	@storage.set(integer,previous_streak,<register.value(battletower_challenge_<storage.get(integer,tower_level)>_previous_streak)>)
	
	:if:<storage.get(integer,previous_streak)>=35 <and> <register.registered(tower_silver)>=false <or> <storage.get(integer,previous_streak)>=70 <and> <register.registered(tower_gold)>=false
	:then
		@storage.set(boolean,tower_brain,true)
		@script.start(frontier\battletower\challenge\beforebattle)
	:else
		:if:<storage.get(integer,tower_streak)>=7
		:then
			@script.start(frontier\battletower\challenge\won7)
		:else
			@storage.set(boolean,tower_brain,false)
			@script.start(frontier\battletower\challenge\beforebattle)
		:endif
	:endif

:end