version=2

:if:<register.registered(sbeam_first)>=false
	@text.show(You know, I might be just an~engineer, but I've taken an~interest in certain Pokémon.*Steel-types are so riveting!)
	@register.register(sbeam_first)
:endif

@text.show(As I observe the docks~and the lighthouse...~A Steel-type technique comes~to mind instantly!)

:if:<player.badges><8
	@text.show(Seems to me you'll need~more experience before I can~share what I've envisioned.)
:else
	@text.show(You seem very capable.*Tell me, do you want one~of your Pokémon to learn~the marvelous Steel Beam?)
	@options.show(Yes,No)
	:when:Yes
		@text.show(Show me which one.)
		@pokemon.select(1)
		:if:<pokemon.selected>>-1
			:if:<pokemon.type1(<pokemon.selected>)>=steel <or> <pokemon.type2(<pokemon.selected>)>=steel <or> <pokemon.number(<pokemon.selected>)>=493 <or> <pokemon.number(<pokemon.selected>)>=773
				:if:<pokemon.hasattack(<pokemon.selected>,796)>=false
					@text.show(Right, let's get working.)
					:if:<pokemon.countattacks(<pokemon.selected>)>=4
						@pokemon.learnattack(<pokemon.selected>,796)
						:if:<pokemon.hasattack(<pokemon.selected>,796)>=true
							@text.show(Now that <pokemon.name(<pokemon.selected>)>~has that move, I'm sure your~bond will be even stronger!)
							:end
						:else
							@text.show(Scrapping the idea?*I'll be here if you change~your mind.)
							:end
						:endif
					:else
						@pokemon.addattack(<pokemon.selected>,796)
						@sound.play(success_small)
						@text.show(<pokemon.name(<pokemon.selected>)> learned~Steel Beam!)
						@text.show(Now that <pokemon.name(<pokemon.selected>)>~has that move, I'm sure your~bond will be even stronger!)	
						:end
					:endif
				:else
					@text.show(Don't be silly, you're~already heavy metal!)
					:end
				:endif
			:else
				@text.show(Your <pokemon.name(<pokemon.selected>)> is~not metal enough for the move.)
				:end
			:endif
		:else
			@text.show(Scrapping the idea?*I'll be here if you change~your mind.)
			:end
		:endif
	:when:No
		@text.show(Scrapping the idea?*I'll be here if you change~your mind.)
		:end
	:endwhen
:endif

:end