version=2
@storage.clear
:if:<register.registered(TTowerCompletewPrize)>=True
	@text.show(You can take the elevator~to return to the lobby!)
	:end
:endif

@storage.set(integer,time,<system.calcint(<system.unixtimestamp>)>-<register.value(Trainertowerstart)>)
:if:<storage.get(integer,time)>>50000
	@text.show(Congratulations on compl-~...~...~...~...*You took WAAAAY too long~to complete the tower!*No way am I rewarding~that sloppy performance!*Go back and try~it again!)
	:end
:endif

:if:1><storage.get(integer,time)>
	@text.show(....*....*....*You completed the challenge~before you even started?*Unlikely!*Next time try to~complete the challenge without~cheating!)
	@script.start(quest\tower\unregister)	
	@screen.fadeout
	@player.warp(14,0,10)
	@player.turnto(2)
	@player.move(0)
	@screen.fadein
	@storage.clear
	:end
:endif

:if:<register.registered(battletowersinglechallenge)>=true
	@storage.set(string,challenge,Single)
	@storage.set(string,chall,sing)
	@storage.set(integer,firstscore,483)
	@storage.set(integer,prizeone,471)
	@storage.set(integer,scoremax,570)
	@storage.set(integer,prizemax,21)
	@storage.set(integer,scorereg,1020)
	@storage.set(integer,prizereg,65)
:endif
:if:<register.registered(battletowerdoublechallenge)>=true
	@storage.set(string,challenge,Double)
	@storage.set(string,chall,doub)
	@storage.set(integer,firstscore,487)
	@storage.set(integer,prizeone,481)
	@storage.set(integer,scoremax,570)
	@storage.set(integer,prizemax,64)
	@storage.set(integer,scorereg,1020)
	@storage.set(integer,prizereg,63)
:endif
:if:<register.registered(battletowerknockoutchallenge)>=true
	@storage.set(string,challenge,Knockout)
	@storage.set(string,chall,knock)
	@storage.set(integer,firstscore,731)
	@storage.set(integer,prizeone,478)
	@storage.set(integer,scoremax,810)
	@storage.set(integer,prizemax,40)
	@storage.set(integer,scorereg,1500)
	@storage.set(integer,prizereg,39)
:endif
:if:<register.registered(battletowermixedchallenge)>=true
	@storage.set(string,challenge,Mixed)
	@storage.set(string,chall,mix)
	@storage.set(integer,firstscore,649)
	@storage.set(integer,prizeone,477)
	@storage.set(integer,scoremax,720)
	@storage.set(integer,prizemax,502)
	@storage.set(integer,scorereg,1320)
	@storage.set(integer,prizereg,62)
:endif

:if:<storage.get(integer,firstscore)>><register.value(TrT<storage.get(string,chall)>Rec)>
	@storage.set(integer,firstscore,<register.value(TrT<storage.get(string,chall)>Rec)>)
:endif

:if:<register.registered(Trainertowerstart)>=true
	@text.show(Congratulations on~completing the tower!)
	:if:<register.registered(TTower<storage.get(string,challenge)>FirstTime)>=False
		@Text.show(As a reward for your~first time completing~the Trainer Tower~<storage.get(string,challenge)> Challenge~I would like to give~you this TM!)
		@item.give(<storage.get(integer,prizeone)>,1)
		@item.messagegive(<storage.get(integer,prizeone)>,1)
		@register.register(TTower<storage.get(string,challenge)>FirstTime)
	:endif
	@text.show(Now, let's take a look~at your time!*...*...*Your completion time for~the Trainer Tower~<storage.get(string,challenge)> Challenge~is <storage.get(integer,time)> seconds.)
	:if:<storage.get(integer,firstscore)>><storage.get(integer,time)>
		@Text.show(AMAZING!*Congratulations,~you just set a new record!)
		@register.register(TTower<storage.get(string,challenge)>RecordHolder)
		:if:<register.registered(TTowerSingleRecordHolder)>=True <and> <register.registered(TTowerDoubleRecordHolder)>=True <and> <register.registered(TTowerKnockoutRecordHolder)>=True <and> <register.registered(TTowerMixedRecordHolder)>=True
			@Text.show(This means you now hold~the records in all four~challenges!*As a special reward I would~like you to have this~rare Pokémon from the~Galar Region!)
			:if:<pokemon.freeplaceinparty>=true
				:if:<system.random(512)>=1
					@pokemon.add(885,25,Reward from Tower Owner,5,at Trainer Tower,0,<player.name>,0,1)
				:else
					@pokemon.add(885,25,Reward from Tower Owner,5,at Trainer Tower)
				:endif
			:else
				@Text.show(Since you have a~full party I will deposit~it directly to your PC!)
				:if:<system.random(512)>=1
					@pokemon.addtostorage(885,25,Reward from Tower Owner,5,at Trainer Tower,0,<player.name>,0,1)
				:else
					@pokemon.addtostorage(885,25,Reward from Tower Owner,5,at Trainer Tower)
				:endif
			:endif
			@sound.play(success_small)
			@text.show(<player.name> received Dreepy!)
		:else
			@text.show(As a reward for your~amazing time please~take these items.)
			@item.give(<storage.get(integer,prizemax)>,3)
			@item.messagegive(<storage.get(integer,prizemax)>,3)
		:endif
	:else
		:if:<storage.get(integer,scoremax)>><storage.get(integer,time)>
			@text.show(WOW!*That's a very good time!*As a reward please~take this.)
			@item.give(<storage.get(integer,prizemax)>,1)
			@item.messagegive(<storage.get(integer,prizemax)>,1)
		:else
			:if:<storage.get(integer,scorereg)>><storage.get(integer,time)>
				@text.show(That's a good time!*As a reward please take this.)
				@item.give(<storage.get(integer,prizereg)>,1)
				@item.messagegive(<storage.get(integer,prizereg)>,1)
			:else
				@text.show(That's a decent time,~I look forward to seeing~you improve!)
			:endif
		:endif
	:endif

	:if:<register.value(TrT<storage.get(string,chall)>Rec)>><storage.get(integer,time)>
		@register.change(TrT<storage.get(string,chall)>Rec,<storage.get(integer,time)>)
		@Text.show(I have updated the~rankboard in the lobby~with your new time!)
	:endif
	@text.show(You can take the elevator~to return to the lobby!)
	@register.register(TTowerCompletewPrize)	
:endif
@storage.clear
:end