P3D-Legacy/P3D/Content/Data/Scripts/pewter/dnascientist.dat

version=2
@text.show(Hi there!*My research specialty~is DNA and genetics.)
:if:<register.registered(taotriocomplete)>=true
	:if:<register.registered(kyuremexplainer)>=false
		@text.show(I recently made a major breakthrough with some help from my colleagues in Unova.*The special properties of the Legendary Pokémon Kyurem make its DNA really compatible with that of the Pokémon Zekrom and Reshiram.*So compatible infact that I was able to design a machine that would be able to combine either of them with Kyurem to unlock Kyurem's full potential.*The only problem is that all three of these Pokémon are extremely rare legendary creatures.*The ones sighted in Unova have all ready been captured.*Oh you have found and captured them in Johto?*Marvelous!*It will take a few minutes to get the equipment turned on but once I do I can help you fuse either Reshiram or Zekrom with Kyurem.)
		@npc.turn(2,0)
		@npc.move(2,2)
		@npc.remove(2)
		@sound.play(enter)
		@entity.remove(3)
		@register.register(kyuremexplainer)
		:end
	:endif
	:if:<register.registered(KyuremFused)>=true
		@text.show(I can defuse your Kyurem-<register.value(KyuremFused)>, if you would like?)
		@options.show(Yes,No)
			:when:Yes
				:if:<pokemon.freeplaceinparty>
					@pokemon.select(0)
					:if:<pokemon.number(<pokemon.selected>)>=649 <and> <pokemon.additionaldata(<pokemon.selected>)>=<register.value(KyuremFused)>
						@text.show(Okay, I will be back with your defused Pokémon in just a second.)
						@pokemon.cry(649)
						@npc.turn(2,0)
						@npc.move(2,2)
						@sound.play(enter)
						@level.wait(20)
						@sound.play(heal)
						@level.wait(20)
						@npc.turn(2,2)
						@sound.play(enter)
						@npc.move(2,2)
						@npc.warp(2,~,0.25,~)
						@level.update
						@text.show(Success!*Here is your regular Kyurem.)
						@pokemon.cry(649)
						@pokemon.setadditionalvalue(<pokemon.selected>,)
						@pokemon.removeattackid(<pokemon.selected>,553)
						@pokemon.removeattackid(<pokemon.selected>,554)
						@pokemon.removeattackid(<pokemon.selected>,558)
						@pokemon.removeattackid(<pokemon.selected>,559)
						:select:<register.value(KyuremFused)>
							:when:black
								@text.show(And here is your Zekrom.)
								@pokemon.cry(644)
								@pokemon.add(<register.value(KyuremFuseData)>)
							:when:white
								@text.show(And here is your Reshiram.)
								@pokemon.cry(643)
								@pokemon.add(<register.value(KyuremFuseData)>)
						:endwhen
						@text.show(Let me know if I can fuse Kyurem for you in the future!)
						@register.unregister(KyuremFused,str)
						@register.unregister(KyuremFuseData,str)
						:end
					:else
						@text.show(That isn't the correct Pokémon. Please bring me your Kyurem-<register.value(KyuremFused)> if you want me to defuse it.)
						:end
					:endif
				:else
					@text.show(You will need space in your party for both of the formally fused Pokémon.*Please make room before returning.)
					:end
				:endif
			:when:No
				:end
		:endwhen
	:else
		@text.show(I can fuse your Kyurem, if you would like?)
		@options.show(Yes,No)
			:when:Yes
				@text.show(Okay I will need a Kyurem to start the process.)
				@pokemon.select(0)
				:if:<pokemon.number(<pokemon.selected>)>=649
					@pokemon.cry(649)
					@Text.show(I will also need a Reshiram or a Zekrom.)
					@storage.set(int,kyurempid,<pokemon.selected>)
					@pokemon.select(0)
					:if:<pokemon.number(<pokemon.selected>)>=643
						@text.show(Okay, I will be back with your defused Pokémon in just a second.)
						@pokemon.cry(643)
						@npc.turn(2,0)
						@npc.move(2,2)
						@sound.play(enter)
						@level.wait(20)
						@sound.play(heal)
						@level.wait(20)
						@npc.turn(2,2)
						@sound.play(enter)
						@npc.move(2,2)
						@npc.warp(2,~,0.25,~)
						@level.update
						@text.show(Success!*Here is your Kyurem-White.)
						@pokemon.cry(649)
						@pokemon.setadditionalvalue(<storage.get(int,kyurempid)>,white)
						@register.register(KyuremFuseData,str,<pokemon.data(<pokemon.selected>)>)
						@pokemon.remove(<pokemon.data(<pokemon.selected>)>)
					:else
						:if:<pokemon.number(<pokemon.selected>)>=644
							@text.show(Okay, I will be back with your defused Pokémon in just a second.)
							@pokemon.cry(644)
							@npc.turn(2,0)
							@npc.move(2,2)
							@sound.play(enter)
							@level.wait(20)
							@sound.play(heal)
							@level.wait(20)
							@npc.turn(2,2)
							@sound.play(enter)
							@npc.move(2,2)
							@npc.warp(2,~,0.25,~)
							@level.update
							@text.show(Success!*Here is your Kyurem-Black.)
							@pokemon.cry(649)
							@pokemon.setadditionalvalue(<storage.get(int,kyurempid)>,black)
							@register.register(KyuremFuseData,str,<pokemon.data(<pokemon.selected>)>)
							@pokemon.remove(<pokemon.data(<pokemon.selected>)>)
						:else
							@text.show(I need a Reshiram or a Zekrom to perform the fusion.)
						:endif
					:endif
					:end
				:else
					@text.show(I need a Kyurem to fuse.)
					:end
				:endif
			:when:No
				:end
		:endwhen
	:endif
:endif
:end