mirror of
https://github.com/acidanthera/audk.git
synced 2025-07-31 01:24:12 +02:00
e3ba31da1c
https://bugzilla.tianocore.org/show_bug.cgi?id=1373 Replace BSD 2-Clause License with BSD+Patent License. This change is based on the following emails: https://lists.01.org/pipermail/edk2-devel/2019-February/036260.html https://lists.01.org/pipermail/edk2-devel/2018-October/030385.html RFCs with detailed process for the license change: V3: https://lists.01.org/pipermail/edk2-devel/2019-March/038116.html V2: https://lists.01.org/pipermail/edk2-devel/2019-March/037669.html V1: https://lists.01.org/pipermail/edk2-devel/2019-March/037500.html Contributed-under: TianoCore Contribution Agreement 1.1 Signed-off-by: Michael D Kinney <michael.d.kinney@intel.com> Reviewed-by: Ray Ni <ray.ni@intel.com>
71 lines
2.5 KiB
NASM
71 lines
2.5 KiB
NASM
;------------------------------------------------------------------------------
|
|
;
|
|
; Copyright (c) 2006 - 2012, Intel Corporation. All rights reserved.<BR>
|
|
; Portitions copyright (c) 2011, Apple Inc. All rights reserved.
|
|
; SPDX-License-Identifier: BSD-2-Clause-Patent
|
|
;
|
|
;------------------------------------------------------------------------------
|
|
|
|
EXTERN CopyMem:PROC
|
|
EXTERN ZeroMem:PROC
|
|
|
|
.code
|
|
|
|
;------------------------------------------------------------------------------
|
|
; EFI_STATUS
|
|
; EFIAPI
|
|
; SecTemporaryRamSupport (
|
|
; IN CONST EFI_PEI_SERVICES **PeiServices, // %rcx
|
|
; IN EFI_PHYSICAL_ADDRESS TemporaryMemoryBase, // %rdx
|
|
; IN EFI_PHYSICAL_ADDRESS PermanentMemoryBase, // %r8
|
|
; IN UINTN CopySize // %r9
|
|
; )
|
|
;------------------------------------------------------------------------------
|
|
SecTemporaryRamSupport PROC
|
|
; Adjust callers %rbp to account for stack move
|
|
sub rbp, rdx ; Calc offset of %rbp in Temp Memory
|
|
add rbp, r8 ; add in permanent base to offset
|
|
|
|
push rbp ; stack frame is for the debugger
|
|
mov rbp, rsp
|
|
|
|
push rdx ; Save TemporaryMemoryBase
|
|
push r8 ; Save PermanentMemoryBase
|
|
push r9 ; Save CopySize
|
|
|
|
;
|
|
; Copy all of temp RAM to permanent memory, including stack
|
|
;
|
|
; CopyMem (PermanentMemoryBase, TemporaryMemoryBase, CopySize);
|
|
; %rcx, %rdx, %r8
|
|
mov rcx, r8 ; Shift arguments
|
|
mov r8, r9
|
|
sub rsp, 028h ; Allocate register spill area & 16-byte align stack
|
|
call CopyMem
|
|
; Temp mem stack now copied to permanent location. %esp still in temp memory
|
|
add rsp, 028h
|
|
|
|
pop r9 ; CopySize (old stack)
|
|
pop r8 ; PermanentMemoryBase (old stack)
|
|
pop rdx ; TemporaryMemoryBase (old stack)
|
|
|
|
mov rcx, rsp ; Move to new stack
|
|
sub rcx, rdx ; Calc offset of stack in Temp Memory
|
|
add rcx, r8 ; Calc PermanentMemoryBase address
|
|
mov rsp, rcx ; Update stack
|
|
; Stack now points to permanent memory
|
|
|
|
; ZeroMem (TemporaryMemoryBase /* rcx */, CopySize /* rdx */);
|
|
mov rcx, rdx
|
|
mov rdx, r9
|
|
sub rsp, 028h ; Allocate register spill area & 16-byte align stack
|
|
call ZeroMem
|
|
add rsp, 028h
|
|
|
|
; This data comes off the NEW stack
|
|
pop rbp
|
|
ret
|
|
SecTemporaryRamSupport ENDP
|
|
|
|
END
|