#
# Copyright 2017 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#

package cloud::docker::mode::memory;

use base qw(centreon::plugins::mode);

use strict;
use warnings;

sub new {
    my ($class, %options) = @_;
    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
    bless $self, $class;

    $self->{version} = '1.1';
    $options{options}->add_options(arguments =>
        {
            "port:s"      => { name => 'port' },
            "name:s"      => { name => 'name' },
            "id:s"        => { name => 'id' },
            "warning:s"   => { name => 'warning' },
            "critical:s"  => { name => 'critical' },
        });

    return $self;
}

sub check_options {
    my ($self, %options) = @_;
    $self->SUPER::init(%options);

    if ((defined($self->{option_results}->{name})) && (defined($self->{option_results}->{id}))) {
        $self->{output}->add_option_msg(short_msg => "Please set the name or id option");
        $self->{output}->option_exit();
    }

    if ((!defined($self->{option_results}->{name})) && (!defined($self->{option_results}->{id}))) {
        $self->{output}->add_option_msg(short_msg => "Please set the name or id option");
        $self->{output}->option_exit();
    }

    if (($self->{perfdata}->threshold_validate(label => 'warning', value => $self->{option_results}->{warning})) == 0) {
       $self->{output}->add_option_msg(short_msg => "Wrong warning threshold '" . $self->{option_results}->{warning} . "'.");
       $self->{output}->option_exit();
    }

    if (($self->{perfdata}->threshold_validate(label => 'critical', value => $self->{option_results}->{critical})) == 0) {
       $self->{output}->add_option_msg(short_msg => "Wrong critical threshold '" . $self->{option_results}->{critical} . "'.");
       $self->{output}->option_exit();
    }
}

sub run {
    my ($self, %options) = @_;

    my $urlpath;
    if (defined($self->{option_results}->{id})) {
        $urlpath = "/containers/".$self->{option_results}->{id}."/stats";
    } elsif (defined($self->{option_results}->{name})) {
        $urlpath = "/containers/".$self->{option_results}->{name}."/stats";
    }
    my $port = $self->{option_results}->{port};
    my $containerapi = $options{custom};

    my $webcontent = $containerapi->api_request(urlpath => $urlpath,
                                                port => $port);

    my $total_size = $webcontent->{memory_stats}->{limit};
    my $memory_used = $webcontent->{memory_stats}->{usage};
    my $memory_free = $webcontent->{memory_stats}->{limit} - $webcontent->{memory_stats}->{usage};
    my $prct_used = $memory_used * 100 / $total_size;
    my $prct_free = 100 - $prct_used;
    my $failed_counter = $webcontent->{memory_stats}->{failcnt};
    my $memory_cached = $webcontent->{memory_stats}->{stats}->{cache};
    my $memory_rss = $webcontent->{memory_stats}->{stats}->{rss};

    my $exit = $self->{perfdata}->threshold_check(value => $prct_used, threshold => [ { label => 'critical', 'exit_litteral' => 'critical' }, { label => 'warning', exit_litteral => 'warning' } ]);
    my ($total_value, $total_unit) = $self->{perfdata}->change_bytes(value => $total_size);
    my ($used_value, $used_unit) = $self->{perfdata}->change_bytes(value => $memory_used);
    my ($free_value, $free_unit) = $self->{perfdata}->change_bytes(value => $memory_free);
    my ($cached_value, $cached_unit) = $self->{perfdata}->change_bytes(value => $memory_cached);
    my ($rss_value, $rss_unit) = $self->{perfdata}->change_bytes(value => $memory_rss);


    $self->{output}->output_add(severity => $exit,
                                short_msg => sprintf("Memory Total: %s Used: %s (%.2f%%) Free: %s %.2f%%) Cached: %s RSS: %s  Failed: %s",
                                                    $total_value . " " . $total_unit,
                                                    $used_value . " " . $used_unit, $prct_used,
                                                    $free_value . " " . $free_unit, $prct_free,
                                                    $cached_value . " " . $cached_unit,
                                                    $rss_value . " " . $rss_unit,
                                                    $failed_counter)
                                );

    $self->{output}->perfdata_add(label => "used",
                                    value => $webcontent->{memory_stats}->{usage},
                                    warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning', total => $total_size, cast_int => 1),
                                    critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical', total => $total_size, cast_int => 1),
                                    min => 0,
                                    max => $webcontent->{memory_stats}->{limit},
                                    );

	$self->{output}->perfdata_add(label => "cached",
                                    value => $webcontent->{memory_stats}->{stats}->{cache},
                                    min => 0,
                                    );

	$self->{output}->perfdata_add(label => "rss",
                                    value => $webcontent->{memory_stats}->{stats}->{rss},
                                    min => 0,
                                    );

	$self->{output}->perfdata_add(label => "failed",
                                    value => $webcontent->{memory_stats}->{failcnt},
                                    min => 0,
                                    );

    $self->{output}->display();
    $self->{output}->exit();

}

1;

__END__

=head1 MODE

Check Container's memory usage

=head2 DOCKER OPTIONS

=item B<--port>

Port used by Docker

=item B<--id>

Specify one container's id

=item B<--name>

Specify one container's name

=head2 MODE OPTIONS

=item B<--warning>

Threshold warning in percent.

=item B<--critical>

Threshold critical in percent.

=back

=cut
