#
# Copyright 2024 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#

package apps::tosca::restapi::custom::api;

use strict;
use warnings;
use centreon::plugins::http;
use JSON::XS;

sub new {
    my ($class, %options) = @_;
    my $self  = {};
    bless $self, $class;

    if (!defined($options{output})) {
        print "Class Custom: Need to specify 'output' argument.\n";
        exit 3;
    }
    if (!defined($options{options})) {
        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
        $options{output}->option_exit();
    }
    
    if (!defined($options{noptions})) {
        $options{options}->add_options(arguments => {
            'hostname:s'             => { name => 'hostname' },
            'port:s'                 => { name => 'port' },
            'proto:s'                => { name => 'proto' },
            'api-username:s'         => { name => 'api_username' },
            'api-password:s'         => { name => 'api_password' },
            'url-path:s'             => { name => 'url_path' },
            'timeout:s'              => { name => 'timeout' },
            'unknown-http-status:s'  => { name => 'unknown_http_status' },
            'warning-http-status:s'  => { name => 'warning_http_status' },
            'critical-http-status:s' => { name => 'critical_http_status' }
        });
    }
    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);

    $self->{output} = $options{output};
    $self->{http} = centreon::plugins::http->new(%options, default_backend => 'curl');
    
    return $self;
}

sub set_options {
    my ($self, %options) = @_;

    $self->{option_results} = $options{option_results};
}

sub set_defaults {}

sub check_options {
    my ($self, %options) = @_;

    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : '';
    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 80;
    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'http';
    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 10;
    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : '';
    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : '';
    $self->{url_path} = (defined($self->{option_results}->{url_path})) ? $self->{option_results}->{url_path} : '/rest/toscacommander';
    $self->{unknown_http_status} = (defined($self->{option_results}->{unknown_http_status})) ? $self->{option_results}->{unknown_http_status} : '%{http_code} < 200 or %{http_code} >= 300';
    $self->{warning_http_status} = (defined($self->{option_results}->{warning_http_status})) ? $self->{option_results}->{warning_http_status} : '';
    $self->{critical_http_status} = (defined($self->{option_results}->{critical_http_status})) ? $self->{option_results}->{critical_http_status} : '';

    if ($self->{hostname} eq '') {
        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
        $self->{output}->option_exit();
    }
    if ($self->{api_username} eq '' || $self->{api_password} eq '') {
        $self->{output}->add_option_msg(short_msg => "Need to specify --api-username and --api-password options.");
        $self->{output}->option_exit();
    }

    return 0;
}

sub build_options_for_httplib {
    my ($self, %options) = @_;

    $self->{option_results}->{hostname} = $self->{hostname};
    $self->{option_results}->{timeout} = $self->{timeout};
    $self->{option_results}->{port} = $self->{port};
    $self->{option_results}->{proto} = $self->{proto};
    $self->{option_results}->{timeout} = $self->{timeout};
    if ($self->{api_username} ne '') {
        $self->{option_results}->{credentials} = 1;
        $self->{option_results}->{basic} = 1;
        $self->{option_results}->{username} = $self->{api_username};
        $self->{option_results}->{password} = $self->{api_password};
    }
}

sub settings {
    my ($self, %options) = @_;

    return if (defined($self->{settings_done}));
    $self->build_options_for_httplib();
    $self->{http}->add_header(key => 'Accept', value => 'application/json');
    $self->{http}->set_options(%{$self->{option_results}});
    $self->{settings_done} = 1;
}

sub get_hostname {
    my ($self, %options) = @_;

    return $self->{hostname};
}

sub request_api {
    my ($self, %options) = @_;

    $self->settings();

    my $content = $self->{http}->request(
        url_path => $options{endpoint},
        unknown_status => $self->{unknown_http_status},
        warning_status => $self->{warning_http_status},
        critical_status => $self->{critical_http_status}
    );
    
    if (!defined($content) || $content eq '') {
        $self->{output}->add_option_msg(short_msg => "API returns empty content [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
        $self->{output}->option_exit();
    }

    my $decoded;
    eval {
        $decoded = JSON::XS->new->utf8->decode($content);
    };
    if ($@) {
        $self->{output}->add_option_msg(short_msg => "Cannot decode response (add --debug option to display returned content)");
        $self->{output}->option_exit();
    }

    return $decoded;
}

sub get_object_representation {
    my ($self, %options) = @_;

    my $response = $self->request_api(
        endpoint => $self->{url_path} . "/" . $options{workspace} . "/object/" . $options{object_id}
    );
    
    if (!defined($response->{TypeName}) || $response->{TypeName} ne $options{object_type}) {
        $self->{output}->add_option_msg(short_msg => "Retrieved '" . $response->{TypeName} . "' object type, expected '" . $options{object_type} . "'");
        $self->{output}->option_exit();
    }
    
    if (!defined($response->{Attributes}) || ref($response->{Attributes}) ne 'ARRAY') {
        $self->{output}->add_option_msg(short_msg => "Cannot retrieve object representation attributes");
        $self->{output}->option_exit();
    }

    my %results;
    foreach my $attribute (@{$response->{Attributes}}) {
        $results{$attribute->{Name}} = $attribute->{Value};
    }

    return %results;
}

sub get_association_object_id {
    my ($self, %options) = @_;

    my $response = $self->request_api(
        endpoint => $self->{url_path} . "/" . $options{workspace} . "/object/" . $options{object_id} . "/association/" . $options{association}
    );
    
    if (!defined(@$response[0]) || !defined(@$response[0]->{UniqueId})) {
        $self->{output}->add_option_msg(short_msg => "Cannot retrieve association object ID");
        $self->{output}->option_exit();
    }

    return @$response[0]->{UniqueId};
}

sub get_scenario_last_log {
    my ($self, %options) = @_;

    my $scenario_last_log_id = $self->get_association_object_id(
        workspace => $options{workspace},
        object_id => $options{scenario_id},
        association => 'ActualLog'
    );

    my %log = $self->get_object_representation(
        workspace => $options{workspace},
        object_id => $scenario_last_log_id,
        object_type => 'ExecutionTestCaseLog'
    );

    return %log;
}

sub get_execution_list {
    my ($self, %options) = @_;

    my %execution_list = $self->get_object_representation(
        workspace => $options{workspace},
        object_id => $options{execution_list_id},
        object_type => 'ExecutionList'
    );

    return %execution_list;
}

1;

__END__

=head1 NAME

Tosca Commander REST Webservice (TCRS)

=head1 REST API OPTIONS

Tosca Commander REST Webservice (TCRS)

=over 8

=item B<--hostname>

Tosca hostname.

=item B<--port>

Port used (default: 80)

=item B<--proto>

Specify https if needed (default: 'http')

=item B<--api-username>

Tosca Commander API username.

=item B<--api-password>

Tosca Commander API password.

=item B<--url-path>

API base url path (default: '/rest/toscacommander').

=item B<--timeout>

Set timeout in seconds (default: 10).

=back

=head1 DESCRIPTION

B<custom>.

=cut
