#
# Copyright 2024 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#

package network::juniper::common::screenos::snmp::mode::listvpn;

use base qw(centreon::plugins::mode);

use strict;
use warnings;

sub new {
    my ($class, %options) = @_;
    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
    bless $self, $class;
    
    $options{options}->add_options(arguments =>
                                {
                                  "filter-name:s"    => { name => 'filter_name' },
                                });
    $self->{vpn} = {};

    return $self;
}

sub check_options {
    my ($self, %options) = @_;
    $self->SUPER::init(%options);
}

my %map_state = (0 => 'inactive', 1 => 'active');

my $mapping = {
    nsVpnMonVpnName     => { oid => '.1.3.6.1.4.1.3224.4.1.1.1.4' },
    nsVpnMonP1State     => { oid => '.1.3.6.1.4.1.3224.4.1.1.1.21', map => \%map_state },
    nsVpnMonP2State     => { oid => '.1.3.6.1.4.1.3224.4.1.1.1.23', map => \%map_state },
};

sub manage_selection {
    my ($self, %options) = @_;

    my $snmp_result = $options{snmp}->get_multiple_table(oids => [ 
                                                            { oid => $mapping->{nsVpnMonVpnName}->{oid} },
                                                            { oid => $mapping->{nsVpnMonP1State}->{oid} },
                                                            { oid => $mapping->{nsVpnMonP2State}->{oid} }
                                                        ],
                                                        return_type => 1, nothing_quit => 1);
    foreach my $oid (keys %{$snmp_result}) {
        next if ($oid !~ /^$mapping->{nsVpnMonVpnName}->{oid}\.(.*)$/);
        my $instance = $1;
        my $result = $options{snmp}->map_instance(mapping => $mapping, results => $snmp_result, instance => $instance);
        
        $result->{nsVpnMonVpnName} =~ s/\\//g;
        if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
            $result->{nsVpnMonVpnName} !~ /$self->{option_results}->{filter_name}/) {
            $self->{output}->output_add(long_msg => "skipping '" . $result->{nsVpnMonVpnName} . "': no matching filter.", debug => 1);
            next;
        }
        
        $self->{vpn}->{$instance} = { 
            name => $result->{nsVpnMonVpnName},
            p1state => $result->{nsVpnMonP1State},
            p2state => $result->{nsVpnMonP2State}
        };
    }
}

sub run {
    my ($self, %options) = @_;
  
    $self->manage_selection(%options);
    foreach my $instance (sort keys %{$self->{vpn}}) { 
        $self->{output}->output_add(long_msg => '[name = ' . $self->{vpn}->{$instance}->{name} . 
                                                "] [p1state = " . $self->{vpn}->{$instance}->{p1state} . 
                                                "] [p2state = " . $self->{vpn}->{$instance}->{p2state} . ']'
        );
    }
    
    $self->{output}->output_add(severity => 'OK',
                                short_msg => 'List VPN:');
    $self->{output}->display(nolabel => 1, force_ignore_perfdata => 1, force_long_output => 1);
    $self->{output}->exit();
}

sub disco_format {
    my ($self, %options) = @_;
    
    $self->{output}->add_disco_format(elements => ['name', 'p1state', 'p2state']);
}

sub disco_show {
    my ($self, %options) = @_;

    $self->manage_selection(%options);
    foreach my $instance (sort keys %{$self->{vpn}}) {             
        $self->{output}->add_disco_entry(
            name => $self->{vpn}->{$instance}->{name}, 
            p1state => $self->{vpn}->{$instance}->{p1state},
            p2state => $self->{vpn}->{$instance}->{p2state}
        );
    }
}

1;

__END__

=head1 MODE

List VPN.

=over 8

=item B<--filter-name>

Filter by VPN (can be a regexp).

=back

=cut
    
