WIP: wazuh rest api plugin

apps/wazuh/restapi/custom/api.pm

@@ -0,0 +1,210 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::wazuh::restapi::custom::api;
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use JSON::XS;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self  = {};
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments => {
+            'hostname:s@' => { name => 'hostname' },
+            'username:s@' => { name => 'username' },
+            'password:s@' => { name => 'password' },
+            'timeout:s@'  => { name => 'timeout' },
+            'port:s@'     => { name => 'port' },
+            'proto:s@'    => { name => 'proto' },
+        });
+    }
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};    
+    $self->{http} = centreon::plugins::http->new(%options);
+
+    return $self;
+
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? shift(@{$self->{option_results}->{hostname}}) : undef;
+    $self->{username} = (defined($self->{option_results}->{username})) ? shift(@{$self->{option_results}->{username}}) : '';
+    $self->{password} = (defined($self->{option_results}->{password})) ? shift(@{$self->{option_results}->{password}}) : '';
+    $self->{timeout}  = (defined($self->{option_results}->{timeout})) ? shift(@{$self->{option_results}->{timeout}}) : 10;
+    $self->{port}     = (defined($self->{option_results}->{port})) ? shift(@{$self->{option_results}->{port}}) : 55000;
+    $self->{proto}    = (defined($self->{option_results}->{proto})) ? shift(@{$self->{option_results}->{proto}}) : 'https';
+ 
+    if (!defined($self->{hostname})) {
+        $self->{output}->add_option_msg(short_msg => 'Need to specify hostname option.');
+        $self->{output}->option_exit();
+    }
+
+    if (!defined($self->{hostname}) ||
+        scalar(@{$self->{option_results}->{hostname}}) == 0) {
+        return 0;
+    }
+    return 1;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{credentials} = 1;
+    $self->{option_results}->{basic} = 1;
+    $self->{option_results}->{username} = $self->{username};
+    $self->{option_results}->{password} = $self->{password};
+    
+    if (!defined($self->{option_results}->{ssl_opt})) {
+        $self->{option_results}->{ssl_opt} = ['SSL_verify_mode => SSL_VERIFY_NONE'];
+    }
+    if (!defined($self->{option_results}->{curl_opt})) {
+        $self->{option_results}->{curl_opt} = ['CURLOPT_SSL_VERIFYPEER => 0', 'CURLOPT_SSL_VERIFYHOST => 0'];
+    }
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Accept', value => 'application/json');
+    $self->{http}->set_options(%{$self->{option_results}});
+}
+
+sub request {
+    my ($self, %options) = @_;
+
+    $self->settings();
+    my $content = $self->{http}->request(
+        url_path => $options{path},
+        unknown_status => '', warning_status => '', critical_status => '', 
+    );
+
+    if ($self->{http}->get_code() != 200) {
+        $self->{output}->add_option_msg(short_msg => 'Connection issue : ' . $self->{http}->get_message() . ' (' . $self->{http}->get_code() . ')');
+        $self->{output}->option_exit();
+    }
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($content);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response");
+        $self->{output}->option_exit();
+    }
+    if ($decoded->{error} != 0) {
+        $self->{output}->add_option_msg(short_msg => "api error $decoded->{error}: " . $decoded->{message});
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Wazuh REST API
+
+=head1 SYNOPSIS
+
+Wazuh Rest API custom mode
+
+=head1 REST API OPTIONS
+
+=over 8
+
+=item B<--hostname>
+
+Wazuh hostname.
+
+=item B<--username>
+
+Wazuh username.
+
+=item B<--password>
+
+Wazuh password.
+
+=item B<--timeout>
+
+Set HTTP timeout in seconds (Default: '10').
+
+=item B<--proto>
+
+Set protocol (default: 'https')
+
+=item B<--port>
+
+Set HTTP port (default: 55000)
+
+=back
+
+=head1 DESCRIPTION
+
+B<custom>.
+
+=cut

apps/wazuh/restapi/mode/agents.pm

@@ -0,0 +1,167 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::wazuh::restapi::mode::agents;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold catalog_status_calc);
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+
+    my $msg = sprintf('status: %s [node name: %s]', 
+        $self->{result_values}->{status},
+        $self->{result_values}->{node_name}
+    );
+    return $msg;
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'global', type => 0, cb_prefix_output => 'prefix_global_output' },
+        { name => 'agent', type => 1, cb_prefix_output => 'prefix_agent_output', message_multiple => 'All agents are ok' }
+    ];
+    
+    $self->{maps_counters}->{global} = [];
+    foreach ('active', 'pending', 'neverconnected', 'disconnected') {
+        push @{$self->{maps_counters}->{global}}, {
+            label => $_, nlabel => 'agents.' . $_ . '.count', display_ok => 0, set => {
+                key_values => [ { name => $_ } ],
+                output_template => $_ . ': %s',
+                perfdatas => [
+                    { value => $_ . '_absolute', template => '%s', min => 0 },
+                ],
+            }
+        };
+    }
+    
+    $self->{maps_counters}->{agent} = [
+        { label => 'status', threshold => 0, set => {
+                key_values => [ { name => 'status' }, { name => 'display' }, { name => 'node_name' } ],
+                closure_custom_calc => \&catalog_status_calc,
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => \&catalog_status_threshold,
+            }
+        },
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
+    bless $self, $class;
+    
+    $options{options}->add_options(arguments => {
+        'filter-name:s'       => { name => 'filter_name' },
+        'warning-status:s'    => { name => 'warning_status', default => '' },
+        'critical-status:s'   => { name => 'critical_status', default => '' },
+    });
+    
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->change_macros(macros => ['warning_status', 'critical_status']);
+}
+
+sub prefix_global_output {
+    my ($self, %options) = @_;
+    
+    return "Total agents ";
+}
+
+sub prefix_agent_output {
+    my ($self, %options) = @_;
+    
+    return "Agent '" . $options{instance_value}->{display} . "' ";
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    $self->{global} = { active => 0, pending => 0, neverconnected => 0, disconnected => 0 };
+    $self->{agent} = {};
+    my $result = $options{custom}->request(path => '/agents?select=name,status,node_name');
+    foreach (@{$result->{data}->{items}}) {
+        if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
+            $_->{name} !~ /$self->{option_results}->{filter_name}/) {
+            $self->{output}->output_add(long_msg => "skipping agent '" . $_->{name} . "': no matching filter.", debug => 1);
+            next;
+        }
+
+
+        my $status = lc($_->{status});
+        $self->{agent}->{$_->{id}} = {
+            display => $_->{name},
+            node_name => $_->{node_name},
+            status => $status,
+        };
+        
+        $self->{global}->{$status}++;
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check wazuh agents.
+
+=over 8
+
+=item B<--filter-counters>
+
+Only display some counters (regexp can be used).
+Example: --filter-counters='^iops$'
+
+=item B<--filter-name>
+
+Filter agent name (can be a regexp).
+
+=item B<--warning-status>
+
+Set warning threshold for status (Default: '').
+Can used special variables like: %{status}, %{node_name}, %{display}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '').
+Can used special variables like: %{status}, %{node_name}, %{display}
+
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'active', 'pending', 'neverconnected', 'disconnected'.
+
+=back
+
+=cut

apps/wazuh/restapi/plugin.pm

@@ -0,0 +1,49 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::wazuh::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    %{$self->{modes}} = (
+        'agents' => 'apps::wazuh::restapi::mode::agents',
+    );
+
+    $self->{custom_modes}{api} = 'apps::wazuh::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check Wazuh through HTTP/REST API.
+
+=cut