From 6d3d8b84e2174eb3a04c27c24cd758e32c8b1a5d Mon Sep 17 00:00:00 2001
From: CPbN <cpbnfo@gmail.com>
Date: Sun, 7 Apr 2019 16:45:52 +0200
Subject: [PATCH] New 3CX plugin

---
 apps/3cx/plugin.pm              |  63 ++++++++
 apps/3cx/restapi/custom/api.pm  | 269 ++++++++++++++++++++++++++++++++
 apps/3cx/restapi/mode/status.pm |  81 ++++++++++
 3 files changed, 413 insertions(+)
 create mode 100644 apps/3cx/plugin.pm
 create mode 100644 apps/3cx/restapi/custom/api.pm
 create mode 100644 apps/3cx/restapi/mode/status.pm

diff --git a/apps/3cx/plugin.pm b/apps/3cx/plugin.pm
new file mode 100644
index 000000000..b5ee82b48
--- /dev/null
+++ b/apps/3cx/plugin.pm
@@ -0,0 +1,63 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::3cx::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ($class, %options) = @_;
+
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    %{$self->{modes}} = (
+                            'status'        => 'apps::3cx::restapi::mode::status',
+                         );
+
+    $self->{custom_modes}{api} = 'apps::3cx::restapi::custom::api';
+
+    return $self;
+}
+
+sub init {
+    my ($self, %options) = @_;
+
+    $self->SUPER::init(%options);
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check 3CX ressources through its HTTPS remote API.
+
+Requirements: at least 3CX 15.5.
+
+=over 8
+
+=back
+
+=cut
diff --git a/apps/3cx/restapi/custom/api.pm b/apps/3cx/restapi/custom/api.pm
new file mode 100644
index 000000000..568019210
--- /dev/null
+++ b/apps/3cx/restapi/custom/api.pm
@@ -0,0 +1,269 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::3cx::restapi::custom::api;
+
+use base qw(centreon::plugins::mode);
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use centreon::plugins::statefile;
+use JSON::XS;
+use Digest::MD5 qw(md5_hex);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments =>  {
+            "hostname:s"            => { name => 'hostname' },
+            "port:s"                => { name => 'port'},
+            "proto:s"               => { name => 'proto' },
+            "api-username:s"        => { name => 'api_username' },
+            "api-password:s"        => { name => 'api_password' },
+            "timeout:s"             => { name => 'timeout', default => 30 },
+        });
+    }
+    
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};
+    $self->{http} = centreon::plugins::http->new(%options);
+    $self->{cache} = centreon::plugins::statefile->new(%options);
+
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : undef;
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 30;
+    $self->{ssl_opt} = (defined($self->{option_results}->{ssl_opt})) ? $self->{option_results}->{ssl_opt} : undef;
+    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : undef;
+    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : undef;
+
+    if (!defined($self->{hostname}) || $self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_username}) || $self->{api_username} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-username option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_password}) || $self->{api_password} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-password option.");
+        $self->{output}->option_exit();
+    }
+
+    $self->{cache}->check_options(option_results => $self->{option_results});
+
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{ssl_opt} = $self->{ssl_opt};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{warning_status} = '';
+    $self->{option_results}->{critical_status} = '';
+    $self->{option_results}->{unknown_status} = '%{http_code} < 200 or %{http_code} >= 300';
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Content-Type', value => 'application/json;charset=UTF-8');
+    if (defined($self->{cookie})) {
+        $self->{http}->add_header(key => 'Cookie', value => '.AspNetCore.Cookies=' . $self->{cookie});
+    }
+    $self->{http}->set_options(%{$self->{option_results}});
+}
+
+sub get_cookie {
+    my ($self, %options) = @_;
+
+    my $has_cache_file = $options{statefile}->read(statefile => '3cx_api_' . md5_hex($self->{option_results}->{hostname}) . '_' . md5_hex($self->{option_results}->{api_username}));
+    my $cookie = $options{statefile}->get(name => 'cookie');
+    my $expires_on = $options{statefile}->get(name => 'expires_on');
+    
+    if ($has_cache_file == 0 || !defined($cookie) || (($expires_on - time()) < 10)) {
+        my $post_data = '{"Username":"' . $self->{api_username} . '",' .
+            '"Password":"' . $self->{api_password} . '"}';
+        
+        $self->settings();
+
+        my $content = $self->{http}->request(method => 'POST', query_form_post => $post_data,
+                                             url_path => '/api/login');
+
+        $cookie = $self->{http}->get_header(name => 'Set-Cookie');
+        if (defined ($cookie) && $cookie =~ /^.AspNetCore.Cookies=([^;]+);.*/) {
+            $cookie = $1;
+        } else {
+            $self->{output}->output_add(long_msg => $content, debug => 1);
+            $self->{output}->add_option_msg(short_msg => "Error retrieving cookie");
+            $self->{output}->option_exit();
+        }
+
+        my $datas = { last_timestamp => time(), cookie => $cookie, expires_on => time() + 7200 };
+        $options{statefile}->write(data => $datas);
+    }
+
+    return $cookie;
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    if (!defined($self->{cookie})) {
+        $self->{cookie} = $self->get_cookie(statefile => $self->{cache});
+    }
+
+    $self->settings();
+
+    my $content = $self->{http}->request(%options);
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($content);
+    };
+    if ($@) {
+        $self->{output}->output_add(long_msg => $content, debug => 1);
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response: $@");
+        $self->{output}->option_exit();
+    }
+    if (!defined($decoded)) {
+        $self->{output}->output_add(long_msg => $decoded, debug => 1);
+        $self->{output}->add_option_msg(short_msg => "Error while retrieving data (add --debug option for detailed message)");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+sub internal_single_status {
+    my ($self, %options) = @_;
+    
+    my $status = $self->request_api(method => 'GET', url_path =>'/api/SystemStatus/GetSingleStatus');
+    return $status;
+}
+
+sub api_single_status {
+    my ($self, %options) = @_;
+
+    my $status = $self->internal_single_status();
+    return $status->{Health};
+}
+
+sub internal_system_status {
+    my ($self, %options) = @_;
+    
+    my $status = $self->request_api(method => 'GET', url_path =>'/api/SystemStatus');
+    return $status;
+}
+
+sub api_system_status {
+    my ($self, %options) = @_;
+
+    my $status = $self->internal_system_status();
+    return $status;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+3CX Rest API
+
+=head1 REST API OPTIONS
+
+=over 8
+
+=item B<--hostname>
+
+Set hostname or IP of 3CX server.
+
+=item B<--port>
+
+Set 3CX Port (Default: '443').
+
+=item B<--proto>
+
+Specify https if needed (Default: 'https').
+
+=item B<--api-username>
+
+Set 3CX Username.
+
+=item B<--api-password>
+
+Set 3CX Password.
+
+=item B<--timeout>
+
+Threshold for HTTP timeout (Default: '30').
+
+=back
+
+=cut
diff --git a/apps/3cx/restapi/mode/status.pm b/apps/3cx/restapi/mode/status.pm
new file mode 100644
index 000000000..57d7a6c84
--- /dev/null
+++ b/apps/3cx/restapi/mode/status.pm
@@ -0,0 +1,81 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::3cx::restapi::mode::status;
+
+use base qw(centreon::plugins::mode);
+
+use strict;
+use warnings;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments =>
+                                {
+                                });
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::init(%options);
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    $self->{single} = $options{custom}->api_single_status();
+    $self->{system} = $options{custom}->api_system_status();
+}
+
+sub run {
+    my ($self, %options) = @_;
+
+    $self->manage_selection(%options);
+    foreach my $item (sort keys %{$self->{single}}) {
+        $self->{output}->output_add(severity => $self->{single}->{$item} ? 'OK' : 'CRITICAL',
+                                    short_msg => $item . ': ' . ($self->{single}->{$item} ? 'OK' : 'NOK'));
+    }
+    $self->{output}->output_add(severity => $self->{system}->{HasNotRunningServices} ? 'CRITICAL' : 'OK',
+                                short_msg => 'Services: ' . ($self->{system}->{HasNotRunningServices} ? 'NOK' : 'OK'));
+    $self->{output}->output_add(severity => $self->{system}->{HasUnregisteredSystemExtensions} ? 'CRITICAL' : 'OK',
+                                short_msg => 'Extensions: ' . ($self->{system}->{HasUnregisteredSystemExtensions} ? 'NOK' : 'OK'));
+
+    $self->{output}->display(force_ignore_perfdata => 1);
+    $self->{output}->exit();
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+List status
+
+=over 8
+
+=back
+
+=cut