From 7783a1aefcf0b9001f1e9a3346907160a8130199 Mon Sep 17 00:00:00 2001
From: garnier-quentin <garnier.quentin@gmail.com>
Date: Thu, 11 Jul 2019 14:24:48 +0200
Subject: [PATCH] Fix #1176

---
 apps/vmware/vcsa/restapi/custom/api.pm  | 266 ++++++++++++++++++++++++
 apps/vmware/vcsa/restapi/mode/health.pm | 134 ++++++++++++
 apps/vmware/vcsa/restapi/plugin.pm      |  54 +++++
 3 files changed, 454 insertions(+)
 create mode 100644 apps/vmware/vcsa/restapi/custom/api.pm
 create mode 100644 apps/vmware/vcsa/restapi/mode/health.pm
 create mode 100644 apps/vmware/vcsa/restapi/plugin.pm

diff --git a/apps/vmware/vcsa/restapi/custom/api.pm b/apps/vmware/vcsa/restapi/custom/api.pm
new file mode 100644
index 000000000..d29c3ca59
--- /dev/null
+++ b/apps/vmware/vcsa/restapi/custom/api.pm
@@ -0,0 +1,266 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::vmware::vcsa::restapi::custom::api;
+
+use base qw(centreon::plugins::mode);
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use centreon::plugins::statefile;
+use JSON::XS;
+use Digest::MD5 qw(md5_hex);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments =>  {
+            'hostname:s'        => { name => 'hostname' },
+            'port:s'            => { name => 'port'},
+            'proto:s'           => { name => 'proto' },
+            'api-username:s'    => { name => 'api_username' },
+            'api-password:s'    => { name => 'api_password' },
+            'timeout:s'         => { name => 'timeout', default => 30 },
+        });
+    }
+    
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};
+    $self->{http} = centreon::plugins::http->new(%options);
+    $self->{cache} = centreon::plugins::statefile->new(%options);
+
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : undef;
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 30;
+    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : undef;
+    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : undef;
+
+    if (!defined($self->{hostname}) || $self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_username}) || $self->{api_username} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-username option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_password}) || $self->{api_password} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-password option.");
+        $self->{output}->option_exit();
+    }
+
+    $self->{cache}->check_options(option_results => $self->{option_results});
+
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{timeout} = $self->{timeout};
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Content-Type', value => 'application/json;charset=UTF-8');
+    $self->{http}->add_header(key => 'Accept', value => 'application/json;charset=UTF-8');
+    if (defined($self->{session_id})) {
+        $self->{http}->add_header(key => 'vmware-api-session-id', value => $self->{session_id});
+    } else {
+        $self->{http}->add_header(key => 'vmware-api-session-id', value => 'null');
+    }
+    $self->{http}->set_options(%{$self->{option_results}});
+}
+
+sub json_decode {
+    my ($self, %options) = @_;
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($options{content});
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response: $@");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+sub clean_session_id {
+    my ($self, %options) = @_;
+
+    my $datas = { last_timestamp => time() };
+    $options{statefile}->write(data => $datas);
+    $self->{session_id} = undef;
+}
+
+sub authenticate {
+    my ($self, %options) = @_;
+
+    my $has_cache_file = $options{statefile}->read(statefile => 'vcsa_api_' . md5_hex($self->{option_results}->{hostname}) . '_' . md5_hex($self->{option_results}->{api_username}));
+    my $session_id = $options{statefile}->get(name => 'session_id');
+    
+    if ($has_cache_file == 0 || !defined($session_id)) {        
+        my $content = $self->{http}->request(
+            method => 'POST',
+            url_path => '/rest/com/vmware/cis/session',
+            credentials => 1, basic => 1,
+            username => $self->{api_username},
+            password => $self->{api_password},
+            warning_status => '', unknown_status => '', critical_status => ''
+        );
+        if ($self->{http}->get_code() != 200) {
+            $self->{output}->add_option_msg(short_msg => "Login error [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
+            $self->{output}->option_exit();
+        }
+
+        my $decoded = $self->json_decode(content => $content);
+
+        if (defined($decoded) && defined($decoded->{value})) {
+            $session_id = $decoded->{value};
+        } else {
+            $self->{output}->add_option_msg(short_msg => "Error retrieving session_id");
+            $self->{output}->option_exit();
+        }
+
+        my $datas = { last_timestamp => time(), session_id => $session_id };
+        $options{statefile}->write(data => $datas);
+    }
+
+    $self->{session_id} = $session_id;
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    $self->settings();
+    if (!defined($self->{session_id})) {
+        $self->authenticate(statefile => $self->{cache});
+    }
+    my $content = $self->{http}->request(%options, 
+        warning_status => '', unknown_status => '', critical_status => ''
+    );
+
+    # Maybe there is an issue with the session_id. So we retry.
+    if ($self->{http}->get_code() != 200) {
+        $self->clean_session_id();
+        $self->authenticate(statefile => $self->{cache});
+        $content = $self->{http}->request(%options, 
+            warning_status => '', unknown_status => '', critical_status => ''
+        );
+    }
+
+    my $decoded = $self->json_decode(content => $content);
+    if (!defined($decoded)) {
+        $self->{output}->add_option_msg(short_msg => "Error while retrieving data (add --debug option for detailed message)");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+VCSA Rest API
+
+=head1 REST API OPTIONS
+
+=over 8
+
+=item B<--hostname>
+
+Set hostname or IP of vsca.
+
+=item B<--port>
+
+Set port (Default: '443').
+
+=item B<--proto>
+
+Specify https if needed (Default: 'https').
+
+=item B<--api-username>
+
+Set username.
+
+=item B<--api-password>
+
+Set password.
+
+=item B<--timeout>
+
+Threshold for HTTP timeout (Default: '30').
+
+=back
+
+=cut
diff --git a/apps/vmware/vcsa/restapi/mode/health.pm b/apps/vmware/vcsa/restapi/mode/health.pm
new file mode 100644
index 000000000..40ca37683
--- /dev/null
+++ b/apps/vmware/vcsa/restapi/mode/health.pm
@@ -0,0 +1,134 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::vmware::vcsa::restapi::mode::health;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold catalog_status_calc);
+
+sub custom_status_output { 
+    my ($self, %options) = @_;
+
+    my $msg .= 'health is ' . $self->{result_values}->{health};
+    return $msg;
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+
+    $self->{maps_counters_type} = [
+        { name => 'service', type => 1, cb_prefix_output => 'prefix_service_output', message_multiple => 'All services are ok', skipped_code => { -10 => 1 } }
+    ];
+
+    $self->{maps_counters}->{service} = [
+        { label => 'status', threshold => 0, set => {
+                key_values => [ { name => 'health' }, { name => 'display' } ],
+                closure_custom_calc => \&catalog_status_calc,
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => \&catalog_status_threshold,
+            }
+        },
+    ];
+}
+
+sub prefix_service_output {
+    my ($self, %options) = @_;
+
+    return "Service '" . $options{instance_value}->{display} ."' ";
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments => {
+        'filter-service:s'  => { name => 'filter_service' },
+        'unknown-status:s'  => { name => 'unknown_status', default => '' },
+        'warning-status:s'  => { name => 'warning_status', default => '' },
+        'critical-status:s' => { name => 'critical_status', default => '%{health} !~ /green/' },
+    });
+
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->change_macros(macros => [
+        'warning_status', 'critical_status', 'unknown_status',
+    ]);
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $endpoint = '/rest/appliance/health/';
+    my @services = ('applmgmt', 'database-storage', 'load', 'mem', 'software-packages', 'storage', 'swap', 'system');
+    $self->{service} = {};
+    foreach (@services) {
+        if (defined($self->{option_results}->{filter_service}) && $self->{option_results}->{filter_service} ne '' &&
+            $_ !~ /$self->{option_results}->{filter_service}/) {
+            $self->{output}->output_add(long_msg => "skipping  '" . $_  . "': no matching filter.", debug => 1);
+            next;
+        }
+
+        my $result = $options{custom}->request_api(url_path => $endpoint . $_);
+        $self->{service}->{$_} = { 
+            display => $_,
+            health => $result->{value}, 
+        };
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check service health.
+
+=over 8
+
+=item B<--unknown-status>
+
+Set unknown threshold for status.
+Can used special variables like: %{health}, %{display}
+
+=item B<--warning-status>
+
+Set warning threshold for status.
+Can used special variables like: %{health}, %{display}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '%{health} !~ /green/').
+Can used special variables like: %{health}, %{display}
+
+=back
+
+=cut
diff --git a/apps/vmware/vcsa/restapi/plugin.pm b/apps/vmware/vcsa/restapi/plugin.pm
new file mode 100644
index 000000000..373a74410
--- /dev/null
+++ b/apps/vmware/vcsa/restapi/plugin.pm
@@ -0,0 +1,54 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::vmware::vcsa::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ($class, %options) = @_;
+
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    %{$self->{modes}} = (
+        'health'    => 'apps::vmware::vcsa::restapi::mode::health',
+    );
+
+    $self->{custom_modes}{api} = 'apps::vmware::vcsa::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check vCenter Server Appliance (VCSA) through HTTP/REST API.
+
+=over 8
+
+=back
+
+=cut