tyler.durden
/
centreon-plugins
mirror of https://github.com/centreon/centreon-plugins.git
1
0
Fork 0
Code Issues Packages Projects Releases Wiki Activity

(plugin) apps::thales::mistral::vs9::restapi - new (#4004)

This commit is contained in:
qgarnier 2022-10-20 10:19:25 +02:00 committed by GitHub
parent e0aa66c8b0
commit 7f8ec50903
6 changed files with 1927 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

316
centreon-plugins/apps/thales/mistral/vs9/restapi/custom/api.pm Normal file
View File

@ -0,0 +1,316 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package apps::thales::mistral::vs9::restapi::custom::api;
use strict;
use warnings;
use centreon::plugins::http;
use centreon::plugins::statefile;
use JSON::XS;
use Digest::MD5 qw(md5_hex);
sub new {
my ($class, %options) = @_;
my $self = {};
bless $self, $class;
if (!defined($options{output})) {
print "Class Custom: Need to specify 'output' argument.\n";
exit 3;
}
if (!defined($options{options})) {
$options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
$options{output}->option_exit();
}
if (!defined($options{noptions})) {
$options{options}->add_options(arguments => {
'api-username:s' => { name => 'api_username' },
'api-password:s' => { name => 'api_password' },
'hostname:s' => { name => 'hostname' },
'port:s' => { name => 'port' },
'proto:s' => { name => 'proto' },
'timeout:s' => { name => 'timeout' },
'unknown-http-status:s' => { name => 'unknown_http_status' },
'warning-http-status:s' => { name => 'warning_http_status' },
'critical-http-status:s' => { name => 'critical_http_status' },
'reload-cache-time:s' => { name => 'reload_cache_time', default => 60 }
});
}
$options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
$self->{output} = $options{output};
$self->{http} = centreon::plugins::http->new(%options, default_backend => 'curl');
$self->{cache} = centreon::plugins::statefile->new(%options);
return $self;
}
sub set_options {
my ($self, %options) = @_;
$self->{option_results} = $options{option_results};
}
sub set_defaults {}
sub check_options {
my ($self, %options) = @_;
$self->{option_results}->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : '';
$self->{option_results}->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 5572;
$self->{option_results}->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
$self->{option_results}->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 30;
$self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : '';
$self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : '';
$self->{unknown_http_status} = (defined($self->{option_results}->{unknown_http_status})) ? $self->{option_results}->{unknown_http_status} : '%{http_code} < 200 or %{http_code} >= 300';
$self->{warning_http_status} = (defined($self->{option_results}->{warning_http_status})) ? $self->{option_results}->{warning_http_status} : '';
$self->{critical_http_status} = (defined($self->{option_results}->{critical_http_status})) ? $self->{option_results}->{critical_http_status} : '';
if ($self->{option_results}->{hostname} eq '') {
$self->{output}->add_option_msg(short_msg => 'Need to specify --hostname option.');
$self->{output}->option_exit();
}
if ($self->{api_username} eq '') {
$self->{output}->add_option_msg(short_msg => 'Need to specify --api-username option.');
$self->{output}->option_exit();
}
if ($self->{api_password} eq '') {
$self->{output}->add_option_msg(short_msg => 'Need to specify --api-password option.');
$self->{output}->option_exit();
}
$self->{cache}->check_options(option_results => $self->{option_results});
return 0;
}
sub settings {
my ($self, %options) = @_;
return if (defined($self->{settings_done}));
$self->{http}->set_options(%{$self->{option_results}});
$self->{http}->add_header(key => 'Accept', value => 'application/json');
$self->{settings_done} = 1;
}
sub get_connection_info {
my ($self, %options) = @_;
return $self->{option_results}->{hostname} . ':' . $self->{option_results}->{port};
}
sub get_token {
my ($self, %options) = @_;
my $has_cache_file = $self->{cache}->read(statefile => 'thales_mistral_connect_' . md5_hex($self->get_connection_info() . '_' . $self->{api_username}));
my $token = $self->{cache}->get(name => 'token');
my $md5_secret_cache = $self->{cache}->get(name => 'md5_secret');
my $md5_secret = md5_hex($self->{api_username} . $self->{api_password});
if ($has_cache_file == 0 ||
!defined($token) ||
(defined($md5_secret_cache) && $md5_secret_cache ne $md5_secret)
) {
my $json_request = {
username => $self->{api_username},
password => $self->{api_password}
};
my $encoded;
eval {
$encoded = encode_json($json_request);
};
if ($@) {
$self->{output}->add_option_msg(short_msg => 'cannot encode json request');
$self->{output}->option_exit();
}
$self->settings();
my $content = $self->{http}->request(
method => 'POST',
url_path => '/api/auth/login',
query_form_post => $encoded,
unknown_status => $self->{unknown_http_status},
warning_status => $self->{warning_http_status},
critical_status => $self->{critical_http_status},
header => ['Content-Type: application/json']
);
my $decoded;
eval {
$decoded = JSON::XS->new->utf8->decode($content);
};
if ($@) {
$self->{output}->add_option_msg(short_msg => "Cannot decode json response");
$self->{output}->option_exit();
}
$token = $decoded->{access_token};
my $datas = {
updated => time(),
token => $token,
md5_secret => $md5_secret
};
$self->{cache}->write(data => $datas);
}
return $token;
}
sub clean_token {
my ($self, %options) = @_;
my $datas = { updated => time() };
$self->{cache}->write(data => $datas);
}
sub request_api {
my ($self, %options) = @_;
$self->settings();
my $token = $self->get_token();
my ($content) = $self->{http}->request(
url_path => '/api' . $options{endpoint},
get_param => $options{get_param},
header => ['Authorization: Bearer ' . $token],
unknown_status => '',
warning_status => '',
critical_status => ''
);
# Maybe token is invalid. so we retry
if ($self->{http}->get_code() < 200 || $self->{http}->get_code() >= 300) {
$self->clean_token();
$token = $self->get_token();
$content = $self->{http}->request(
url_path => '/api' . $options{endpoint},
get_param => $options{get_param},
header => ['Authorization: Bearer ' . $token],
unknown_status => $self->{unknown_http_status},
warning_status => $self->{warning_http_status},
critical_status => $self->{critical_http_status}
);
}
if (!defined($content) || $content eq '') {
$self->{output}->add_option_msg(short_msg => "API returns empty content [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
$self->{output}->option_exit();
}
my $decoded;
eval {
$decoded = JSON::XS->new->allow_nonref(1)->utf8->decode($content);
};
if ($@) {
$self->{output}->add_option_msg(short_msg => "Cannot decode response (add --debug option to display returned content)");
$self->{output}->option_exit();
}
return $decoded;
}
sub get_gateway_inventory {
my ($self, %options) = @_;
my $has_cache_file = $self->{cache}->read(statefile => 'thales_mistral_inventory_' . md5_hex($self->get_connection_info() . '_' . $self->{api_username}));
my $updated = $self->{cache}->get(name => 'updated');
my $inventory = $self->{cache}->get(name => 'gwInventory');
if ($has_cache_file == 0 || !defined($updated) || ((time() - $updated) > (($self->{option_results}->{reload_cache_time} * 60)))) {
my $cache = { updated => time() };
my $result = $self->request_api(
endpoint => '/ssIpsecGwHws',
get_param => ['projection=gatewayHwData']
);
$inventory = $result->{content};
$result = $self->request_api(endpoint => '/ssIpsecGwHws/status');
for (my $i = 0; $i < scalar(@$inventory); $i++) {
if (defined($result->{ $inventory->[$i]->{serialNumber} })) {
$inventory->[$i]->{status} = $result->{ $inventory->[$i]->{serialNumber} };
}
}
$result = $self->request_api(
endpoint => '/certificateGws',
get_param => ['projection=withGatewayHw']
);
for (my $i = 0; $i < scalar(@$inventory); $i++) {
$inventory->[$i]->{certificates} = [];
foreach my $cert (@{$result->{content}}) {
if ($inventory->[$i]->{serialNumber} eq $cert->{ssIpsecGwHw}->{serialNumber}) {
push @{$inventory->[$i]->{certificates}}, $cert;
last;
}
}
}
$cache->{gwInventory} = $inventory;
$self->{cache}->write(data => $cache);
}
return $inventory;
}
1;
__END__
=head1 NAME
Mistral vs9 API
=head1 REST API OPTIONS
Mistral vs9 API
=over 8
=item B<--hostname>
Set MMC hostname.
=item B<--port>
Port used (Default: 5572)
=item B<--proto>
Specify https if needed (Default: 'https')
=item B<--api-username>
API username.
=item B<--api-password>
API password.
=item B<--timeout>
Set timeout in seconds (Default: 30).
=back
=head1 DESCRIPTION
B<custom>.
=cut

1053
centreon-plugins/apps/thales/mistral/vs9/restapi/mode/devices.pm Normal file
View File

File diff suppressed because it is too large Load Diff

155
centreon-plugins/apps/thales/mistral/vs9/restapi/mode/discovery.pm Normal file
View File

@ -0,0 +1,155 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package apps::thales::mistral::vs9::restapi::mode::discovery;
use base qw(centreon::plugins::mode);
use strict;
use warnings;
use JSON::XS;
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options);
bless $self, $class;
$options{options}->add_options(arguments => {
'resource-type:s' => { name => 'resource_type' },
'prettify' => { name => 'prettify' }
});
return $self;
}
sub check_options {
my ($self, %options) = @_;
$self->SUPER::init(%options);
if (!defined($self->{option_results}->{resource_type}) || $self->{option_results}->{resource_type} eq '') {
$self->{option_results}->{resource_type} = 'device';
}
if ($self->{option_results}->{resource_type} !~ /^device$/) {
$self->{output}->add_option_msg(short_msg => 'unknown resource type');
$self->{output}->option_exit();
}
}
sub discovery_device {
my ($self, %options) = @_;
my $devices = $options{custom}->request_api(
endpoint => '/ssIpsecGwHws',
get_param => ['projection=gatewayHwData']
);
my $disco_data = [];
foreach my $device (@{$devices->{content}}) {
my $entry = {};
$entry->{id} = $device->{id};
$entry->{name} = defined($device->{name}) ? $device->{name} : '';
$entry->{serial_number} = $device->{serialNumber};
$entry->{firmware_version_current} = $device->{firmwareVersionCurrent};
$entry->{firmware_version_other} = $device->{firmwareVersionOther};
$entry->{product_name} = $device->{productName};
$entry->{platform_model} = $device->{platformModel};
$entry->{description} = defined($device->{description}) ? $device->{description} : '';
$entry->{physical_interfaces} = [];
if (defined($device->{physicalInterfaces})) {
foreach my $int (@{$device->{physicalInterfaces}}) {
push @{$entry->{physical_interfaces}}, {
name => $int->{name},
physical_address => defined($int->{physicalAddress}) ? $int->{physicalAddress} : '',
connection_type => $int->{connectionType},
domain => $int->{domain}
};
}
}
$entry->{gateway_name} = defined($device->{gatewayConf}) ? $device->{gatewayConf}->{name} : '';
$entry->{gateway_responder_only} = '';
$entry->{gateway_responder_only} = $device->{gatewayConf}->{responderOnly} =~ /true|1/i ? 'yes' : 'no' if (defined($device->{gatewayConf}));
$entry->{gateway_administration_ip} = defined($device->{gatewayConf}) ? $device->{gatewayConf}->{administrationIp} : '';
$entry->{gateway_active} = '';
$entry->{gateway_active} = $device->{gatewayConf}->{active} =~ /true|1/i ? 'yes' : 'no' if (defined($device->{gatewayConf}));
$entry->{gateway_offline} = '';
$entry->{gateway_offline} = $device->{gatewayConf}->{offline} =~ /true|1/i ? 'yes' : 'no' if (defined($device->{gatewayConf}));
$entry->{gateway_private_address} = defined($device->{gatewayConf}) ? $device->{gatewayConf}->{privateAddress}->{address} : '';
$entry->{gateway_private_address_netmask} = defined($device->{gatewayConf}) ? $device->{gatewayConf}->{privateAddress}->{netmask} : '';
push @$disco_data, $entry;
}
return $disco_data;
}
sub run {
my ($self, %options) = @_;
my $disco_stats;
$disco_stats->{start_time} = time();
my $results = [];
if ($self->{option_results}->{resource_type} eq 'device') {
$results = $self->discovery_device(
custom => $options{custom}
);
}
$disco_stats->{end_time} = time();
$disco_stats->{duration} = $disco_stats->{end_time} - $disco_stats->{start_time};
$disco_stats->{discovered_items} = scalar(@$results);
$disco_stats->{results} = $results;
my $encoded_data;
eval {
if (defined($self->{option_results}->{prettify})) {
$encoded_data = JSON::XS->new->utf8->canonical(1)->pretty->encode($disco_stats);
} else {
$encoded_data = JSON::XS->new->utf8->canonical(1)->encode($disco_stats);
}
};
if ($@) {
$encoded_data = '{"code":"encode_error","message":"Cannot encode discovered data into JSON format"}';
}
$self->{output}->output_add(short_msg => $encoded_data);
$self->{output}->display(nolabel => 1, force_ignore_perfdata => 1);
$self->{output}->exit();
}
1;
__END__
=head1 MODE
Resources discovery.
=over 8
=item B<--resource-type>
Choose the type of resources to discover (Can be: 'device').
=back
=cut

174
centreon-plugins/apps/thales/mistral/vs9/restapi/mode/mmccertificates.pm Normal file
View File

@ -0,0 +1,174 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package apps::thales::mistral::vs9::restapi::mode::mmccertificates;
use base qw(centreon::plugins::templates::counter);
use strict;
use warnings;
use DateTime;
use POSIX;
use centreon::plugins::misc;
my $unitdiv = { s => 1, w => 604800, d => 86400, h => 3600, m => 60 };
my $unitdiv_long = { s => 'seconds', w => 'weeks', d => 'days', h => 'hours', m => 'minutes' };
sub custom_certificate_expires_perfdata {
my ($self, %options) = @_;
$self->{output}->perfdata_add(
nlabel => $self->{nlabel} . '.' . $unitdiv_long->{ $self->{instance_mode}->{option_results}->{time_certificate_unit} },
unit => $self->{instance_mode}->{option_results}->{time_certificate_unit},
instances => $self->{result_values}->{name},
value => floor($self->{result_values}->{expires_seconds} / $unitdiv->{ $self->{instance_mode}->{option_results}->{time_certificate_unit} }),
warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{thlabel}),
critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{thlabel}),
min => 0
);
}
sub custom_certificate_expires_threshold {
my ($self, %options) = @_;
return $self->{perfdata}->threshold_check(
value => floor($self->{result_values}->{expires_seconds} / $unitdiv->{ $self->{instance_mode}->{option_results}->{time_certificate_unit} }),
threshold => [
{ label => 'critical-' . $self->{thlabel}, exit_litteral => 'critical' },
{ label => 'warning-'. $self->{thlabel}, exit_litteral => 'warning' },
{ label => 'unknown-'. $self->{thlabel}, exit_litteral => 'unknown' }
]
);
}
sub prefix_certificate_output {
my ($self, %options) = @_;
return sprintf(
"certificate '%s' ",
$options{instance_value}->{name}
);
}
sub set_counters {
my ($self, %options) = @_;
$self->{maps_counters_type} = [
{ name => 'certificates', type => 1, cb_prefix_output => 'prefix_certificate_output', message_multiple => 'all certificates are ok', skipped_code => { -10 => 1 } }
];
$self->{maps_counters}->{certificates} = [
{ label => 'certificate-expires', nlabel => 'certificate.expires', set => {
key_values => [ { name => 'expires_seconds' }, { name => 'expires_human' }, { name => 'name' } ],
output_template => 'expires in %s',
output_use => 'expires_human',
closure_custom_perfdata => $self->can('custom_certificate_expires_perfdata'),
closure_custom_threshold_check => $self->can('custom_certificate_expires_threshold')
}
}
];
}
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
bless $self, $class;
$options{options}->add_options(arguments => {
'time-certificate-unit:s' => { name => 'time_certificate_unit', default => 's' }
});
return $self;
}
sub check_options {
my ($self, %options) = @_;
$self->SUPER::check_options(%options);
if ($self->{option_results}->{time_certificate_unit} eq '' || !defined($unitdiv->{$self->{option_results}->{time_certificate_unit}})) {
$self->{option_results}->{time_certificate_unit} = 's';
}
}
sub add_certificate {
my ($self, %options) = @_;
return if ($options{cert}->{validityPeriodEnd} !~ /^\s*(\d{4})-(\d{2})-(\d{2})T(\d{2}):(\d{2}):(\d{2})\.\d+([+-].*)$/);
my $dt = DateTime->new(
year => $1,
month => $2,
day => $3,
hour => $4,
minute => $5,
second => $6,
time_zone => $7
);
$self->{certificates}->{ $options{cert}->{subjectCommonName} } = {
name => $options{cert}->{subjectCommonName},
expires_seconds => $dt->epoch() - time()
};
$self->{certificates}->{ $options{cert}->{subjectCommonName} }->{expires_seconds} = 0
if ($self->{certificates}->{ $options{cert}->{subjectCommonName} }->{expires_seconds} < 0);
$self->{certificates}->{ $options{cert}->{subjectCommonName} }->{expires_human} = centreon::plugins::misc::change_seconds(
value => $self->{certificates}->{ $options{cert}->{subjectCommonName} }->{expires_seconds}
);
}
sub manage_selection {
my ($self, %options) = @_;
my $certificates = $options{custom}->request_api(
endpoint => '/certificateCas',
get_param => ['projection=withSignedCertificates']
);
$self->{certificates} = {};
foreach my $cert (@{$certificates->{content}}) {
$self->add_certificate(cert => $cert);
foreach my $mmc (@{$cert->{certificatesMmc}}) {
$self->add_certificate(cert => $mmc);
}
}
}
1;
__END__
=head1 MODE
Check certificates.
=over 8
=item B<--time-certificate-unit>
Select the time unit for certificate threshold. May be 's' for seconds, 'm' for minutes,
'h' for hours, 'd' for days, 'w' for weeks. Default is seconds.
=item B<--warning-*> B<--critical-*>
Thresholds.
Can be: 'certificate-expires'.
=back
=cut

178
centreon-plugins/apps/thales/mistral/vs9/restapi/mode/mmccluster.pm Normal file
View File

@ -0,0 +1,178 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package apps::thales::mistral::vs9::restapi::mode::mmccluster;
use base qw(centreon::plugins::templates::counter);
use strict;
use warnings;
use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold_ng);
sub custom_cluster_status_output {
my ($self, %options) = @_;
return sprintf(
'enabled: %s, replication status: %s',
$self->{result_values}->{enabled},
$self->{result_values}->{replicationStatus}
);
}
sub prefix_cluster_output {
my ($self, %options) = @_;
return 'cluster ';
}
sub prefix_node_output {
my ($self, %options) = @_;
return sprintf(
"node '%s' ",
$options{instance_value}->{name}
);
}
sub set_counters {
my ($self, %options) = @_;
$self->{maps_counters_type} = [
{ name => 'cluster', type => 0, cb_prefix_output => 'prefix_cluster_output' },
{ name => 'nodes', type => 1, cb_prefix_output => 'prefix_node_output', message_multiple => 'all nodes are ok', skipped_code => { -10 => 1 } },
];
$self->{maps_counters}->{cluster} = [
{
label => 'cluster-status',
type => 2,
unknown_default => '%{replicationStatus} =~ /unknown/i',
warning_default => '%{replicationStatus} =~ /not_synchronized/i',
set => {
key_values => [ { name => 'replicationStatus' }, { name => 'enabled' } ],
closure_custom_output => $self->can('custom_cluster_status_output'),
closure_custom_perfdata => sub { return 0; },
closure_custom_threshold_check => \&catalog_status_threshold_ng
}
},
{ label => 'synchronization-done', display_ok => 0, nlabel => 'cluster.synchronization.done.percentage', set => {
key_values => [ { name => 'synchronizationDone' } ],
output_template => 'synchronization done: %s %%',
perfdatas => [
{ template => '%s', min => 0, max => 100, unit => '%' }
]
}
}
];
$self->{maps_counters}->{nodes} = [
{
label => 'node-status',
type => 2,
warning_default => '%{status} =~ /disconnected/i',
set => {
key_values => [ { name => 'status' }, { name => 'name' } ],
output_template => 'status: %s',
closure_custom_perfdata => sub { return 0; },
closure_custom_threshold_check => \&catalog_status_threshold_ng
}
}
];
}
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
bless $self, $class;
$options{options}->add_options(arguments => {
});
return $self;
}
sub manage_selection {
my ($self, %options) = @_;
my $cluster = $options{custom}->request_api(endpoint => '/managementCenters/cluster');
$self->{cluster} = {
enabled => $cluster->{enabled} =~ /true|1/i ? 'yes' : 'no',
replicationStatus => lc($cluster->{replicationStatus}),
synchronizationDone => $cluster->{synchronizePercentageDone}
};
$self->{nodes} = {};
foreach (keys %{$cluster->{statusList}}) {
$self->{nodes}->{$_} = {
name => $_,
status => $cluster->{statusList}->{$_} =~ /true|1/i ? 'connected' : 'disconnected'
};
}
}
1;
__END__
=head1 MODE
Check MMC cluster status.
=over 8
=item B<--unknown-cluster-status>
Set unknown threshold for status (Default: '%{replicationStatus} =~ /unknown/i').
Can used special variables like: %{enabled}, %{replicationStatus}
=item B<--warning-cluster-status>
Set warning threshold for status (Default: '%{replicationStatus} =~ /not_synchronized/i').
Can used special variables like: %{enabled}, %{replicationStatus}
=item B<--critical-cluster-status>
Set critical threshold for status.
Can used special variables like: %{status}, %{name}
=item B<--unknown-node-status>
Set unknown threshold for status.
Can used special variables like: %{status}, %{name}
=item B<--warning-node-status>
Set warning threshold for status (Default: '%{status} =~ /disconnected/i').
Can used special variables like: %{status}, %{name}
=item B<--critical-node-status>
Set critical threshold for status.
Can used special variables like: %{status}, %{name}
=item B<--warning-*> B<--critical-*>
Thresholds.
Can be: 'synchronization-done'.
=back
=cut

51
centreon-plugins/apps/thales/mistral/vs9/restapi/plugin.pm Normal file
View File

@ -0,0 +1,51 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package apps::thales::mistral::vs9::restapi::plugin;
use strict;
use warnings;
use base qw(centreon::plugins::script_custom);
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options);
bless $self, $class;
$self->{modes} = {
'devices' => 'apps::thales::mistral::vs9::restapi::mode::devices',
'discovery' => 'apps::thales::mistral::vs9::restapi::mode::discovery',
'mmc-certificates' => 'apps::thales::mistral::vs9::restapi::mode::mmccertificates',
'mmc-cluster' => 'apps::thales::mistral::vs9::restapi::mode::mmccluster'
};
$self->{custom_modes}->{api} = 'apps::thales::mistral::vs9::restapi::custom::api';
return $self;
}
1;
__END__
=head1 PLUGIN DESCRIPTION
Check Thales Mistral version 9 through HTTP/REST API.
=cut