diff --git a/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/custom/api.pm b/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/custom/api.pm
new file mode 100644
index 000000000..f39b961b3
--- /dev/null
+++ b/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/custom/api.pm
@@ -0,0 +1,217 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::monitoring::iplabel::newtest::restapi::custom::api;
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use JSON::XS;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self  = {};
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments => {
+            'api-username:s'         => { name => 'api_username' },
+            'api-password:s'         => { name => 'api_password' },
+            'hostname:s'             => { name => 'hostname' },
+            'port:s'                 => { name => 'port' },
+            'proto:s'                => { name => 'proto' },
+            'timeout:s'              => { name => 'timeout' },
+            'unknown-http-status:s'  => { name => 'unknown_http_status' },
+            'warning-http-status:s'  => { name => 'warning_http_status' },
+            'critical-http-status:s' => { name => 'critical_http_status' }
+        });
+    }
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};
+    $self->{http} = centreon::plugins::http->new(%options);
+    
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : '';
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 10;
+    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : '';
+    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : '';
+    $self->{unknown_http_status} = (defined($self->{option_results}->{unknown_http_status})) ? $self->{option_results}->{unknown_http_status} : '%{http_code} < 200 or %{http_code} >= 300';
+    $self->{warning_http_status} = (defined($self->{option_results}->{warning_http_status})) ? $self->{option_results}->{warning_http_status} : '';
+    $self->{critical_http_status} = (defined($self->{option_results}->{critical_http_status})) ? $self->{option_results}->{critical_http_status} : '';
+
+    if ($self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if ($self->{api_username} ne '' && $self->{api_password} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-password option.");
+        $self->{output}->option_exit();
+    }
+
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    if ($self->{api_username} ne '') {
+        $self->{option_results}->{credentials} = 1;
+        $self->{option_results}->{basic} = 1;
+        $self->{option_results}->{username} = $self->{api_username};
+        $self->{option_results}->{password} = $self->{api_password};
+    }
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    return if (defined($self->{settings_done}));
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Accept', value => 'application/json');
+    $self->{http}->add_header(key => 'Content-Type', value => 'application/json');
+    $self->{http}->set_options(%{$self->{option_results}});
+    $self->{settings_done} = 1;
+}
+
+sub get_hostname {
+    my ($self, %options) = @_;
+
+    return $self->{hostname};
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    $self->settings();
+
+    my $content = $self->{http}->request(
+        url_path => $options{endpoint},
+        unknown_status => $self->{unknown_http_status},
+        warning_status => $self->{warning_http_status},
+        critical_status => $self->{critical_http_status}
+    );
+    
+    if (!defined($content) || $content eq '') {
+        $self->{output}->add_option_msg(short_msg => "API returns empty content [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
+        $self->{output}->option_exit();
+    }
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($content);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode response (add --debug option to display returned content)");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+IP-Label newtest Rest API
+
+=head1 REST API OPTIONS
+
+IP-Label newtest Rest API
+
+=over 8
+
+=item B<--hostname>
+
+Newtest hostname.
+
+=item B<--port>
+
+Port used (Default: 8085)
+
+=item B<--proto>
+
+Specify https if needed (Default: 'http')
+
+=item B<--api-username>
+
+API username.
+
+=item B<--api-password>
+
+API password.
+
+=item B<--timeout>
+
+Set timeout in seconds (Default: 10).
+
+=back
+
+=head1 DESCRIPTION
+
+B<custom>.
+
+=cut
diff --git a/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/mode/scenarios.pm b/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/mode/scenarios.pm
new file mode 100644
index 000000000..91d0a258e
--- /dev/null
+++ b/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/mode/scenarios.pm
@@ -0,0 +1,264 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::monitoring::iplabel::newtest::restapi::mode::scenarios;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use Digest::MD5 qw(md5_hex);
+use POSIX;
+use DateTime;
+
+sub robot_long_output {
+    my ($self, %options) = @_;
+
+    return "checking robot '" . $options{instance_value}->{display} . "'";
+}
+
+sub prefix_robot_output {
+    my ($self, %options) = @_;
+
+    return "Robot '" . $options{instance_value}->{display} . "' ";
+}
+
+
+sub prefix_scenario_output {
+    my ($self, %options) = @_;
+
+    return "scenario '" . $options{instance_value}->{display} . "' ";
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+
+    $self->{maps_counters_type} = [
+        { name => 'robots', type => 3, cb_prefix_output => 'prefix_robot_output', cb_long_output => 'robot_long_output', indent_long_output => '    ', message_multiple => 'All robots are ok',
+            group => [
+                { name => 'scenarios', display_long => 1, cb_prefix_output => 'prefix_scenario_output',  message_multiple => 'All scenarios are ok', type => 1, skipped_code => { -10 => 1 } },
+            ]
+        }
+    ];
+
+    $self->{maps_counters}->{scenarios} = [
+        { label => 'dummy', threshold => 0, display_ok => 0, set => {
+                key_values => [ { name => 'last_exec' } ],
+                output_template => 'none',
+                perfdatas => []
+            }
+        },
+        { label => 'status-green', nlabel => 'scenario.status.green.percentage', set => {
+                key_values => [ { name => 'green_prct' }, { name => 'display' } ],
+                output_template => 'green status: %.2f %%',
+                perfdatas => [
+                    { template => '%.2f', min => 0, max => 100, unit => '%', label_extra_instance => 1 }
+                ]
+            }
+        },
+        { label => 'status-red', nlabel => 'scenario.status.red.percentage', set => {
+                key_values => [ { name => 'red_prct' }, { name => 'display' } ],
+                output_template => 'red status: %.2f %%',
+                perfdatas => [
+                    { template => '%.2f', min => 0, max => 100, unit => '%', label_extra_instance => 1 }
+                ]
+            }
+        },
+        { label => 'status-orange', nlabel => 'scenario.status.orange.percentage', set => {
+                key_values => [ { name => 'orange_prct' }, { name => 'display' } ],
+                output_template => 'orange status: %.2f %%',
+                perfdatas => [
+                    { template => '%.2f', min => 0, max => 100, unit => '%', label_extra_instance => 1 }
+                ]
+            }
+        },
+        { label => 'status-grey', nlabel => 'scenario.status.grey.percentage', set => {
+                key_values => [ { name => 'grey_prct' }, { name => 'display' } ],
+                output_template => 'grey status: %.2f %%',
+                perfdatas => [
+                    { template => '%.2f', min => 0, max => 100, unit => '%', label_extra_instance => 1 }
+                ]
+            }
+        }
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, statefile => 1, force_new_perfdata => 1);
+    bless $self, $class;
+
+    $options{options}->add_options(arguments => { 
+        'filter-robot-name:s'    => { name => 'filter_robot_name' },
+        'filter-scenario-name:s' => { name => 'filter_scenario_name' }
+    });
+
+    return $self;
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    $self->{cache_name} = 'iplabel_newtest_' . $self->{mode} . '_' . $options{custom}->get_hostname()  . '_' .
+        (defined($self->{option_results}->{filter_counters}) ? md5_hex($self->{option_results}->{filter_counters}) : md5_hex('all')) . '_' .
+        (defined($self->{option_results}->{filter_robot_name}) ? md5_hex($self->{option_results}->{filter_robot_name}) : md5_hex('all')) . '_' .
+        (defined($self->{option_results}->{filter_robot_name}) ? md5_hex($self->{option_results}->{filter_scenario_name}) : md5_hex('all'));
+    my $last_timestamp = $self->read_statefile_key(key => 'last_timestamp');
+    my $timespan = 5;
+    if (defined($last_timestamp)) {
+        $timespan = POSIX::ceil((time() - $last_timestamp) / 60);
+    } else {
+        $last_timestamp = time() - (60 * 5);
+    }
+
+    my $results = $options{custom}->request_api(endpoint => '/rest/api/results?range=' . $timespan);
+
+    my $mapping_status = {
+        completed => 'green',
+        failed => 'red',
+        warning => 'orange',
+        available => 'green',
+        suspended => 'grey',
+        outofrange => 'grey',
+        canceled => 'grey',
+        notrunning => 'grey',
+        unknown => 'grey'
+    };
+
+    # {
+    #    "Id": 54411512,
+    #    "ExecutionDate": "2020-06-24T15:01:39",
+    #    "ExecutionDateUtc": "2020-06-24T13:01:39",
+    #    "Status": "Warning",
+    #    "Value": 45000,
+    #    "ExclusionState": "None",
+    #    "Measure": {
+    #      "Id": 9,
+    #      "Name": "Sugar"
+    #    },
+    #    "Robot": {
+    #      "Id": 12,
+    #      "Name": "STOCKHOLM"
+    #    },
+    #    "ErrorMessage": ""
+    #}
+
+    $self->{robots} = {};
+
+    my $scenarios_last_exec = {};
+    my $i = scalar(@$results) - 1;
+    for (; $i >= 0; $i--) {
+        if (defined($self->{option_results}->{filter_robot_name}) && $self->{option_results}->{filter_robot_name} ne '' &&
+            $results->[$i]->{Robot}->{Name} !~ /$self->{option_results}->{filter_robot_name}/) {
+            $self->{output}->output_add(long_msg => "skipping scenario '" . $results->[$i]->{Measure}->{Name} . "': no matching filter.", debug => 1);
+            next;
+        }
+        if (defined($self->{option_results}->{filter_scenario_name}) && $self->{option_results}->{filter_scenario_name} ne '' &&
+            $results->[$i]->{Measure}->{Name} !~ /$self->{option_results}->{filter_scenario_name}/) {
+            $self->{output}->output_add(long_msg => "skipping scenario '" . $results->[$i]->{Measure}->{Name} . "': no matching filter.", debug => 1);
+            next;
+        }
+
+        next if ($results->[$i]->{ExecutionDateUtc} !~ /^(\d+)-(\d+)-(\d+)T(\d+):(\d+):(\d+)$/);
+        my $exec_time = DateTime->new(year => $1, month => $2, day => $3, hour => $4, minute => $5, second => $6, time_zone => 'UTC');
+        my $exec_epoch = $exec_time->epoch();
+
+        if (!defined($self->{robots}->{ $results->[$i]->{Robot}->{Name} })) {
+            $self->{robots}->{ $results->[$i]->{Robot}->{Name} } = {
+                display => $results->[$i]->{Robot}->{Name},
+                scenarios => {}
+            };
+        }
+        if (!defined($self->{robots}->{ $results->[$i]->{Robot}->{Name} }->{scenarios}->{ $results->[$i]->{Measure}->{Name} })) {
+            $self->{robots}->{ $results->[$i]->{Robot}->{Name} }->{scenarios}->{ $results->[$i]->{Measure}->{Name} } = {
+                display => $results->[$i]->{Measure}->{Name},
+                red_seconds => 0,
+                orange_seconds => 0,
+                grey_seconds => 0,
+                green_seconds => 0,
+                execution_time_total => 0,
+                execution_count => 0
+            };
+        }
+
+        my $uuid = $results->[$i]->{Robot}->{Name} . '~' . $results->[$i]->{Measure}->{Name};
+        if (!defined($scenarios_last_exec->{$uuid})) {
+            $scenarios_last_exec->{$uuid} = $self->read_statefile_key(key => $uuid . '_last_exec');
+            if (!defined($scenarios_last_exec->{$uuid})) {
+                $scenarios_last_exec->{$uuid} = { time => $last_timestamp, status => lc($results->[$i]->{Status}) };
+                next;
+            }
+        }
+        next if ($exec_epoch < $last_timestamp);
+
+        $self->{robots}->{ $results->[$i]->{Robot}->{Name} }->{scenarios}->{ $results->[$i]->{Measure}->{Name} }->{ $mapping_status->{ $scenarios_last_exec->{$uuid}->{status} } . '_seconds' } += $exec_epoch - $scenarios_last_exec->{$uuid}->{time};
+        $self->{robots}->{ $results->[$i]->{Robot}->{Name} }->{scenarios}->{ $results->[$i]->{Measure}->{Name} }->{execution_time_total} += $results->[$i]->{Value};
+        $self->{robots}->{ $results->[$i]->{Robot}->{Name} }->{scenarios}->{ $results->[$i]->{Measure}->{Name} }->{execution_count}++;
+
+        $scenarios_last_exec->{$uuid}->{time} = $exec_epoch;
+        $scenarios_last_exec->{$uuid}->{status} = lc($results->[$i]->{Status});
+    }
+
+    my $current_timestamp = time();
+    # we add current timestamp gap
+    foreach my $robot_name (keys %{$self->{robots}}) {
+        foreach my $scenario_name (keys %{$self->{robots}->{$robot_name}->{scenarios}}) {
+            my $uuid = $robot_name . '~' . $scenario_name;
+            $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{ $mapping_status->{ $scenarios_last_exec->{$uuid}->{status} } . '_seconds' } += $current_timestamp - $scenarios_last_exec->{$uuid}->{time};
+            $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{last_exec} = $scenarios_last_exec->{$uuid};
+           
+            my $total_time = $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{green_seconds} +
+                $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{red_seconds} +
+                $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{orange_seconds} +
+                $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{grey_seconds};
+            $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{green_prct} =
+               $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{green_seconds} * 100 / $total_time;
+            $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{red_prct} =
+               $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{red_seconds} * 100 / $total_time;
+            $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{orange_prct} =
+               $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{orange_seconds} * 100 / $total_time;
+            $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{grey_prct} =
+               $self->{robots}->{ $robot_name }->{scenarios}->{ $scenario_name }->{grey_seconds} * 100 / $total_time;
+        }
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check scenarios.
+
+=over 8
+
+=item B<--filter-node-id>
+
+Filter nodes (can be a regexp).
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'ping-received-lasttime' (s).
+
+=back
+
+=cut
diff --git a/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/plugin.pm b/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/plugin.pm
new file mode 100644
index 000000000..e320b32c5
--- /dev/null
+++ b/centreon-plugins/apps/monitoring/iplabel/newtest/restapi/plugin.pm
@@ -0,0 +1,49 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::monitoring::iplabel::newtest::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ( $class, %options ) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '0.1';
+    $self->{modes} = {
+        'scenarios' => 'apps::monitoring::iplabel::newtest::restapi::mode::scenarios'
+    };
+
+    $self->{custom_modes}{api} = 'apps::monitoring::iplabel::newtest::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check IP-Label newtest using Rest API.
+
+=cut