From 95c50cacefe00cc152fb91d4ae2b92563420e7e1 Mon Sep 17 00:00:00 2001
From: garnier-quentin <qgarnier@centreon.com>
Date: Thu, 6 Oct 2016 12:12:58 +0200
Subject: [PATCH] + add vtom plugin restapi

---
 apps/vtom/restapi/custom/api.pm     | 209 +++++++++++++++++
 apps/vtom/restapi/mode/jobstatus.pm | 334 ++++++++++++++++++++++++++++
 apps/vtom/restapi/plugin.pm         |  49 ++++
 3 files changed, 592 insertions(+)
 create mode 100644 apps/vtom/restapi/custom/api.pm
 create mode 100644 apps/vtom/restapi/mode/jobstatus.pm
 create mode 100644 apps/vtom/restapi/plugin.pm

diff --git a/apps/vtom/restapi/custom/api.pm b/apps/vtom/restapi/custom/api.pm
new file mode 100644
index 000000000..3a8629712
--- /dev/null
+++ b/apps/vtom/restapi/custom/api.pm
@@ -0,0 +1,209 @@
+#
+# Copyright 2016 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::vtom::restapi::custom::api;
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use JSON::XS;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self  = {};
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments => 
+                    {
+                      "hostname:s@" => { name => 'hostname' },
+                      "port:s@"     => { name => 'port' },
+                      "proto:s@"    => { name => 'proto' },
+                      "username:s@" => { name => 'username' },
+                      "password:s@" => { name => 'password' },
+                      "proxyurl:s@" => { name => 'proxyurl' },
+                      "timeout:s@"  => { name => 'timeout' },
+                    });
+    }
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};    
+    $self->{http} = centreon::plugins::http->new(output => $self->{output});
+
+    return $self;
+
+}
+
+# Method to manage multiples
+sub set_options {
+    my ($self, %options) = @_;
+    # options{options_result}
+
+    $self->{option_results} = $options{option_results};
+}
+
+# Method to manage multiples
+sub set_defaults {
+    my ($self, %options) = @_;
+    # options{default}
+    
+    # Manage default value
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    # return 1 = ok still hostname
+    # return 0 = no hostname left
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? shift(@{$self->{option_results}->{hostname}}) : undef;
+    $self->{port} = (defined($self->{option_results}->{port})) ? shift(@{$self->{option_results}->{port}}) : 30080;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? shift(@{$self->{option_results}->{proto}}) : 'http';
+    $self->{username} = (defined($self->{option_results}->{username})) ? shift(@{$self->{option_results}->{username}}) : '';
+    $self->{password} = (defined($self->{option_results}->{password})) ? shift(@{$self->{option_results}->{password}}) : '';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? shift(@{$self->{option_results}->{timeout}}) : 10;
+    $self->{proxyurl} = (defined($self->{option_results}->{proxyurl})) ? shift(@{$self->{option_results}->{proxyurl}}) : undef;
+ 
+    if (!defined($self->{hostname})) {
+        $self->{output}->add_option_msg(short_msg => "Need to specify hostname option.");
+        $self->{output}->option_exit();
+    }
+
+    if (!defined($self->{hostname}) ||
+        scalar(@{$self->{option_results}->{hostname}}) == 0) {
+        return 0;
+    }
+    return 1;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{proxyurl} = $self->{proxyurl};
+    $self->{option_results}->{credentials} = 1;
+    $self->{option_results}->{username} = $self->{username};
+    $self->{option_results}->{password} = $self->{password};
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    $self->build_options_for_httplib();
+    $self->{http}->set_options(%{$self->{option_results}});
+}
+
+sub get {
+    my ($self, %options) = @_;
+
+    $self->settings();
+
+    my $response = $self->{http}->request(url_path => $options{path},
+                                          critical_status => '', warning_status => '');
+    my $content;
+    eval {
+        $content = JSON::XS->new->utf8->decode($response);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response: $@");
+        $self->{output}->option_exit();
+    }
+    if (defined($content->{errmsg})) {
+        $self->{output}->add_option_msg(short_msg => "Cannot get data: " . $content->{errmsg});
+        $self->{output}->option_exit();
+    }
+    
+    return $content;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+VTOM REST API
+
+=head1 SYNOPSIS
+
+VTOM Rest API custom mode
+
+=head1 REST API OPTIONS
+
+=over 8
+
+=item B<--hostname>
+
+VTOM hostname.
+
+=item B<--port>
+
+Port used (Default: 30080)
+
+=item B<--proto>
+
+Specify https if needed (Default: 'http')
+
+=item B<--username>
+
+Storeonce username.
+
+=item B<--password>
+
+Storeonce password.
+
+=item B<--proxyurl>
+
+Proxy URL if any
+
+=item B<--timeout>
+
+Set HTTP timeout
+
+=back
+
+=head1 DESCRIPTION
+
+B<custom>.
+
+=cut
diff --git a/apps/vtom/restapi/mode/jobstatus.pm b/apps/vtom/restapi/mode/jobstatus.pm
new file mode 100644
index 000000000..0169276b4
--- /dev/null
+++ b/apps/vtom/restapi/mode/jobstatus.pm
@@ -0,0 +1,334 @@
+#
+# Copyright 2016 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::vtom::restapi::mode::jobstatus;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::misc;
+
+my $instance_mode;
+
+sub custom_status_threshold {
+    my ($self, %options) = @_; 
+    my $status = 'ok';
+    my $message;
+    
+    eval {
+        local $SIG{__WARN__} = sub { $message = $_[0]; };
+        local $SIG{__DIE__} = sub { $message = $_[0]; };
+        
+        if (defined($instance_mode->{option_results}->{critical_status}) && $instance_mode->{option_results}->{critical_status} ne '' &&
+            eval "$instance_mode->{option_results}->{critical_status}") {
+            $status = 'critical';
+        } elsif (defined($instance_mode->{option_results}->{warning_status}) && $instance_mode->{option_results}->{warning_status} ne '' &&
+                 eval "$instance_mode->{option_results}->{warning_status}") {
+            $status = 'warning';
+        }
+    };
+    if (defined($message)) {
+        $self->{output}->output_add(long_msg => 'filter status issue: ' . $message);
+    }
+
+    return $status;
+}
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+    my $msg = 'status : ' . $self->{result_values}->{status};
+
+    return $msg;
+}
+
+sub custom_status_calc {
+    my ($self, %options) = @_;
+    
+    $self->{result_values}->{status} = $options{new_datas}->{$self->{instance} . '_status'};
+    $self->{result_values}->{display} = $options{new_datas}->{$self->{instance} . '_display'};
+    $self->{result_values}->{exit_code} = $options{new_datas}->{$self->{instance} . '_exit_code'};
+    return 0;
+}
+
+sub custom_long_threshold {
+    my ($self, %options) = @_; 
+    my $status = 'ok';
+    my $message;
+    
+    eval {
+        local $SIG{__WARN__} = sub { $message = $_[0]; };
+        local $SIG{__DIE__} = sub { $message = $_[0]; };
+        
+        if (defined($instance_mode->{option_results}->{critical_long}) && $instance_mode->{option_results}->{critical_long} ne '' &&
+            eval "$instance_mode->{option_results}->{critical_long}") {
+            $status = 'critical';
+        } elsif (defined($instance_mode->{option_results}->{warning_long}) && $instance_mode->{option_results}->{warning_long} ne '' &&
+                 eval "$instance_mode->{option_results}->{warning_long}") {
+            $status = 'warning';
+        }
+    };
+    if (defined($message)) {
+        $self->{output}->output_add(long_msg => 'filter status issue: ' . $message);
+    }
+
+    return $status;
+}
+
+sub custom_long_output {
+    my ($self, %options) = @_;
+    my $msg = 'started since : ' . centreon::plugins::misc::change_seconds(value => $self->{result_values}->{elapsed});
+
+    return $msg;
+}
+
+sub custom_long_calc {
+    my ($self, %options) = @_;
+    
+    $self->{result_values}->{status} = $options{new_datas}->{$self->{instance} . '_status'};
+    $self->{result_values}->{display} = $options{new_datas}->{$self->{instance} . '_display'};
+    $self->{result_values}->{elapsed} = $options{new_datas}->{$self->{instance} . '_elapsed'};
+    
+    return -11 if ($self->{result_values}->{status} !~ /Running/i);
+
+    return 0;
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'global', type => 0, cb_prefix_output => 'prefix_global_output', },
+        { name => 'job', type => 1, cb_prefix_output => 'prefix_job_output', message_multiple => 'All jobs are ok', , skipped_code => { -11 => 1 } },
+    ];
+    
+    $self->{maps_counters}->{job} = [
+        { label => 'status', threshold => 0, set => {
+                key_values => [ { name => 'status' }, { name => 'display' }, { name => 'exit_code' } ],
+                closure_custom_calc => $self->can('custom_status_calc'),
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => $self->can('custom_status_threshold'),
+            }
+        },
+        { label => 'long', threshold => 0, set => {
+                key_values => [ { name => 'status' }, { name => 'display' }, { name => 'elapsed' } ],
+                closure_custom_calc => $self->can('custom_long_calc'),
+                closure_custom_output => $self->can('custom_long_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => $self->can('custom_long_threshold'),
+            }
+        },
+    ];
+    
+    $self->{maps_counters}->{global} = [
+        { label => 'total-error', set => {
+                key_values => [ { name => 'error' }, { name => 'total' } ],
+                output_template => 'Error : %s',
+                perfdatas => [
+                    { label => 'total_error', value => 'error_absolute', template => '%s',
+                      min => 0, max => 'total_absolute' },
+                ],
+            }
+        },
+        { label => 'total-running', set => {
+                key_values => [ { name => 'running' }, { name => 'total' } ],
+                output_template => 'Running : %s',
+                perfdatas => [
+                    { label => 'total_running', value => 'running_absolute', template => '%s',
+                      min => 0, max => 'total_absolute' },
+                ],
+            }
+        },
+        { label => 'total-unplanned', set => {
+                key_values => [ { name => 'unplanned' }, { name => 'total' } ],
+                output_template => 'Unplanned : %s',
+                perfdatas => [
+                    { label => 'total_unplanned', value => 'unplanned_absolute', template => '%s',
+                      min => 0, max => 'total_absolute' },
+                ],
+            }
+        },
+        { label => 'total-finished', set => {
+                key_values => [ { name => 'finished' }, { name => 'total' } ],
+                output_template => 'Finished : %s',
+                perfdatas => [
+                    { label => 'total_finished', value => 'finished_absolute', template => '%s',
+                      min => 0, max => 'total_absolute' },
+                ],
+            }
+        },
+        { label => 'total-coming', set => {
+                key_values => [ { name => 'coming' }, { name => 'total' } ],
+                output_template => 'Coming : %s',
+                perfdatas => [
+                    { label => 'total_coming', value => 'coming_absolute', template => '%s',
+                      min => 0, max => 'total_absolute' },
+                ],
+            }
+        },
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments =>
+                                {
+                                  "filter-name:s"           => { name => 'filter_name' },
+                                  "warning-status:s"        => { name => 'warning_status' },
+                                  "critical-status:s"       => { name => 'critical_status', default => '%{status} =~ /Error/i' },
+                                  "warning-long:s"          => { name => 'warning_long' },
+                                  "critical-long:s"         => { name => 'critical_long' },
+                                });
+    
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $instance_mode = $self;
+    $self->change_macros();
+}
+
+sub prefix_global_output {
+    my ($self, %options) = @_;
+
+    return "Total Job ";
+}
+
+sub prefix_job_output {
+    my ($self, %options) = @_;
+    
+    return "job '" . $options{instance_value}->{display} . "' ";
+}
+
+sub change_macros {
+    my ($self, %options) = @_;
+    
+    foreach (('warning_status', 'critical_status', 'warning_long', 'critical_long')) {
+        if (defined($self->{option_results}->{$_})) {
+            $self->{option_results}->{$_} =~ s/%\{(.*?)\}/\$self->{result_values}->{$1}/g;
+        }
+    }
+}
+
+my %mapping_job_status = (
+    R => 'Running',
+    U => 'Unplanned',
+    F => 'Finished',
+    W => 'Coming',
+    E => 'Error',
+);
+
+sub manage_selection {
+    my ($self, %options) = @_;
+ 
+    $self->{job} = {};
+    $self->{global} = { total => 0, running => 0, unplanned => 0, finished => 0, coming => 0, error => 0 };
+    my $result = $options{custom}->get(path => '/api/job/getAll');
+    
+    my $current_time = time();
+    if (defined($result->{result})) {
+        foreach my $entry (@{$result->{result}}) {
+            if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
+                $entry->{name} !~ /$self->{option_results}->{filter_name}/) {
+                $self->{output}->output_add(long_msg => "skipping  '" . $entry->{name} . "': no matching filter.", debug => 1);
+                next;
+            }
+            
+            my $elapsed_time = $current_time - $entry->{timeBegin};
+            
+            $self->{global}->{total} += 1;
+            $self->{global}->{lc($mapping_job_status{$entry->{status}})} += 1;
+            $self->{job}->{$entry->{id}} = { 
+                display => $entry->{name}, 
+                status => $mapping_job_status{$entry->{status}},
+                exit_code => $entry->{retcode},
+                elapsed => $elapsed_time
+            };
+        }
+    }
+    
+    if (scalar(keys %{$self->{job}}) <= 0) {
+        $self->{output}->add_option_msg(short_msg => "No job found.");
+        $self->{output}->option_exit();
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check job status.
+
+=over 8
+
+=item B<--filter-name>
+
+Filter name (can be a regexp).
+
+=item B<--filter-counters>
+
+Only display some counters (regexp can be used).
+Example: --filter-counters='^total-error$'
+
+=item B<--warning-*>
+
+Threshold warning.
+Can be: 'total-error', 'total-running', 'total-unplanned',
+'total-finished', 'total-coming'.
+
+=item B<--critical-*>
+
+Threshold critical.
+Can be: 'total-error', 'total-running', 'total-unplanned',
+'total-finished', 'total-coming'.
+
+=item B<--warning-status>
+
+Set warning threshold for status (Default: -)
+Can used special variables like: %{display}, %{status}, %{exit_code}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '%{exit_code} =~ /Error/i').
+Can used special variables like: %{display}, %{status}, %{exit_code}
+
+=item B<--warning-long>
+
+Set warning threshold for long jobs (Default: none)
+Can used special variables like: %{display}, %{status}, %{elapsed}
+
+=item B<--critical-long>
+
+Set critical threshold for long jobs (Default: none).
+Can used special variables like: %{display}, %{status}, %{elapsed}
+
+=back
+
+=cut
diff --git a/apps/vtom/restapi/plugin.pm b/apps/vtom/restapi/plugin.pm
new file mode 100644
index 000000000..5a4bb9f4f
--- /dev/null
+++ b/apps/vtom/restapi/plugin.pm
@@ -0,0 +1,49 @@
+#
+# Copyright 2016 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::vtom::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    %{$self->{modes}} = (
+                         'job-status'   => 'apps::vtom::restapi::mode::jobstatus',
+                         );
+
+    $self->{custom_modes}{api} = 'apps::vtom::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check VTOM software through HTTP/REST API.
+
+=cut