From 20405c8933f14c180ca340bafbbb98eb4689e7cd Mon Sep 17 00:00:00 2001
From: garnier-quentin <garnier.quentin@gmail.com>
Date: Wed, 16 Dec 2020 15:57:40 +0100
Subject: [PATCH 1/4] wip hms ewon

---
 .../devices/hms/ewon/snmp/mode/listtags.pm    | 137 ++++++++++++++++++
 hardware/devices/hms/ewon/snmp/plugin.pm      |  48 ++++++
 2 files changed, 185 insertions(+)
 create mode 100644 hardware/devices/hms/ewon/snmp/mode/listtags.pm
 create mode 100644 hardware/devices/hms/ewon/snmp/plugin.pm

diff --git a/hardware/devices/hms/ewon/snmp/mode/listtags.pm b/hardware/devices/hms/ewon/snmp/mode/listtags.pm
new file mode 100644
index 000000000..87bb77bfc
--- /dev/null
+++ b/hardware/devices/hms/ewon/snmp/mode/listtags.pm
@@ -0,0 +1,137 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::devices::hms::ewon::snmp::mode::listtags;
+
+use base qw(centreon::plugins::mode);
+
+use strict;
+use warnings;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $options{options}->add_options(arguments => {
+        'filter-tag-name:s' => { name => 'filter_tag_name' }
+    });
+
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::init(%options);
+}
+
+my $mapping = {
+    name  => { oid => '.1.3.6.1.4.1.8284.2.1.3.1.11.1.3' }, # tagCfgName
+    value => { oid => '.1.3.6.1.4.1.8284.2.1.3.1.11.1.4' }  # tagValue
+};
+my $oid_tagEntry = '.1.3.6.1.4.1.8284.2.1.3.1.11.1';
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $snmp_result = $options{snmp}->get_table(
+        oid => $oid_tagEntry,
+        start => $mapping->{name}->{oid},
+        end => $mapping->{value}->{oid},
+        nothing_quit => 1
+    );
+
+    my $results = {};
+    foreach my $oid (keys %$snmp_result) {
+        next if ($oid !~ /^$mapping->{name}->{oid}\.(.*)$/);
+        my $instance = $1;
+        my $result = $options{snmp}->map_instance(mapping => $mapping, results => $snmp_result, instance => $instance);
+        
+        if (defined($self->{option_results}->{filter_tag_name}) && $self->{option_results}->{filter_tag_name} ne '' &&
+            $result->{name} !~ /$self->{option_results}->{filter_tag_name}/) {
+            $self->{output}->output_add(long_msg => "skipping '" . $result->{name} . "': no matching filter.", debug => 1);
+            next;
+        }
+        
+        $results->{$instance} = $result;
+    }
+
+    return $results;
+}
+
+sub run {
+    my ($self, %options) = @_;
+  
+    my $results = $self->manage_selection(%options);
+    foreach my $index (sort keys %$results) { 
+        $self->{output}->output_add(
+            long_msg => sprintf(
+                '[name: %s][index: %s][value: %s]',
+                $results->{$index}->{name},
+                $index,
+                $results->{$index}->{value}
+            )
+        );
+    }
+    
+    $self->{output}->output_add(
+        severity => 'OK',
+        short_msg => 'List tags:'
+    );
+    $self->{output}->display(nolabel => 1, force_ignore_perfdata => 1, force_long_output => 1);
+    $self->{output}->exit();
+}
+
+sub disco_format {
+    my ($self, %options) = @_;
+    
+    $self->{output}->add_disco_format(elements => ['index', 'name', 'value']);
+}
+
+sub disco_show {
+    my ($self, %options) = @_;
+
+    my $results = $self->manage_selection(%options);
+    foreach my $index (sort keys %$results) {
+        $self->{output}->add_disco_entry(
+            index => $index,
+            %{$results->{$index}}            
+        );
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+List tags.
+
+=over 8
+
+=item B<--filter-tag-name>
+
+Filter tags by name (can be a regexp).
+
+=back
+
+=cut
+    
diff --git a/hardware/devices/hms/ewon/snmp/plugin.pm b/hardware/devices/hms/ewon/snmp/plugin.pm
new file mode 100644
index 000000000..72bf49c5e
--- /dev/null
+++ b/hardware/devices/hms/ewon/snmp/plugin.pm
@@ -0,0 +1,48 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::devices::hms::ewon::snmp::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_snmp);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    %{$self->{modes}} = (
+        'list-tags'  => 'hardware::devices::hms::ewon::snmp::mode::listtags'
+    );
+
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check Ewon in SNMP.
+
+=cut

From beccc5b1997fea0826987d4db37b1285b1a3cbbe Mon Sep 17 00:00:00 2001
From: garnier-quentin <garnier.quentin@gmail.com>
Date: Thu, 17 Dec 2020 08:55:22 +0100
Subject: [PATCH 2/4] wip ewon

---
 hardware/devices/hms/ewon/snmp/plugin.pm | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

diff --git a/hardware/devices/hms/ewon/snmp/plugin.pm b/hardware/devices/hms/ewon/snmp/plugin.pm
index 72bf49c5e..ccad96edb 100644
--- a/hardware/devices/hms/ewon/snmp/plugin.pm
+++ b/hardware/devices/hms/ewon/snmp/plugin.pm
@@ -31,7 +31,8 @@ sub new {
 
     $self->{version} = '1.0';
     %{$self->{modes}} = (
-        'list-tags'  => 'hardware::devices::hms::ewon::snmp::mode::listtags'
+        'list-tags' => 'hardware::devices::hms::ewon::snmp::mode::listtags',
+        'tags'      => 'hardware::devices::hms::ewon::snmp::mode::tags'
     );
 
     return $self;

From 8106e8b71f97ac03f2b9b2612f37c95ddaa2a9c2 Mon Sep 17 00:00:00 2001
From: garnier-quentin <garnier.quentin@gmail.com>
Date: Fri, 18 Dec 2020 14:38:10 +0100
Subject: [PATCH 3/4] wip hms ewon

---
 hardware/devices/hms/ewon/snmp/mode/tags.pm | 301 ++++++++++++++++++++
 1 file changed, 301 insertions(+)
 create mode 100644 hardware/devices/hms/ewon/snmp/mode/tags.pm

diff --git a/hardware/devices/hms/ewon/snmp/mode/tags.pm b/hardware/devices/hms/ewon/snmp/mode/tags.pm
new file mode 100644
index 000000000..36dc80e35
--- /dev/null
+++ b/hardware/devices/hms/ewon/snmp/mode/tags.pm
@@ -0,0 +1,301 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::devices::hms::ewon::snmp::mode::tags;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::statefile;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold_ng);
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+    
+    return 'status: ' . $self->{result_values}->{status};
+}
+
+sub custom_value_perfdata {
+    my ($self, %options) = @_;
+
+    $self->{output}->perfdata_add(
+        nlabel => 'tag.value.count',
+        instances => $self->{result_values}->{name},
+        value => $self->{result_values}->{value},
+        warning => defined($self->{instance_mode}->{warning_instance}) ? $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{instance_mode}->{warning_instance}) : undef,
+        critical => defined($self->{instance_mode}->{critical_instance}) ? $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{instance_mode}->{critical_instance}) : undef
+    );
+}
+
+sub custom_value_threshold {
+    my ($self, %options) = @_;
+
+    $self->{instance_mode}->{warning_instance} = undef;
+    $self->{instance_mode}->{critical_instance} = undef;
+
+    my $thresholds = [];
+    foreach my $th (('critical', 'warning')) {
+        my $i = 0;
+        foreach (@{$self->{instance_mode}->{'tag_threshold_' . $th}}) {
+            if ($self->{result_values}->{name} =~ /$_->{match}/ ||
+                $self->{result_values}->{index} =~ /$_->{match}/) {
+                $self->{instance_mode}->{$th . '_instance'} = $i; 
+                push @$thresholds, { label => $th . '-' . $i, exit_litteral => $th };
+                last;
+            }
+            $i++;
+        }
+    }
+
+    return 'ok' if (scalar(@$thresholds) <= 0);
+
+    return $self->{perfdata}->threshold_check(
+        value => $self->{result_values}->{value}, 
+        threshold => $thresholds
+    );
+}
+
+sub custom_value_output {
+    my ($self, %options) = @_;
+
+    my $output = 'value: %s';
+    foreach (@{$self->{instance_mode}->{tag_output_values}}) {
+        if ($self->{result_values}->{name} =~ /$_->{match}/ ||
+            $self->{result_values}->{index} =~ /$_->{match}/) {
+            $output = $_->{output};
+            last;
+        }
+    }
+    return sprintf(
+        $output,
+        $self->{result_values}->{value}
+    );
+}
+
+sub prefix_tag_output {
+    my ($self, %options) = @_;
+    
+    return "Tag '" . $options{instance_value}->{name} . "' ";
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'tags', type => 1, cb_prefix_output => 'prefix_tag_output', message_multiple => 'All tags are ok' }
+    ];
+    
+    $self->{maps_counters}->{tags} = [
+        { label => 'status', type => 2, critical_default => '%{status} =~ /alarm/', set => {
+                key_values => [ { name => 'status' }, { name => 'name' } ],
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => \&catalog_status_threshold_ng
+            }
+        },
+        { label => 'value', threshold => 0, set => {
+                key_values => [ { name => 'value' }, { name => 'index' }, { name => 'name' } ],
+                closure_custom_output => $self->can('custom_value_output'),
+                closure_custom_perfdata => $self->can('custom_value_perfdata'),
+                closure_custom_threshold_check => $self->can('custom_value_threshold')
+            }
+        }
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
+    bless $self, $class;
+    
+    $options{options}->add_options(arguments => {
+        'filter-tag-index:s'        => { name => 'filter_tag_index' },
+        'filter-tag-name:s'         => { name => 'filter_tag_name' },
+        'cache-expires-in:s'        => { name => 'cache_expires_in' },
+        'tag-output-value:s@'       => { name => 'tag_output_value' },
+        'tag-threshold-warning:s@'  => { name => 'tag_threshold_warning' },
+        'tag-threshold-critical:s@' => { name => 'tag_threshold_critical' }
+    });
+
+    $self->{cache} = centreon::plugins::statefile->new(%options);
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->{option_results}->{cache_expires_in} = (defined($self->{option_results}->{cache_expires_in})) && $self->{option_results}->{cache_expires_in} =~ /(\d+)/ ?
+        $1 : 7200;
+    $self->{cache}->check_options(option_results => $self->{option_results});
+    $self->{tag_output_values} = [];
+    if (defined($self->{option_results}->{tag_output_value})) {
+        foreach (@{$self->{option_results}->{tag_output_value}}) {
+            my ($tag_match, $tag_output) = split /,/;
+            next if (!defined($tag_output) || $tag_output eq '');
+            push @{$self->{tag_output_values}}, { match => $tag_match, output => $tag_output}; 
+        }
+    }
+
+    foreach (('warning', 'critical')) {
+        my $i = 0;
+        $self->{'tag_threshold_' . $_} = [];
+        next if (defined($self->{option_results}->{'tag_threshold_' . $_}));
+        foreach my $option (@{$self->{option_results}->{'tag_threshold_' . $_}}) {
+            my ($tag_match, $tag_threshold) = split /,/;
+            next if (!defined($tag_threshold) || $tag_threshold eq '');
+            if ($self->{perfdata}->threshold_validate(label => $_ . '-' . $i, value => $tag_threshold)) {
+                $self->{output}->add_option_msg(short_msg => "Wrong threshold '" . $tag_threshold . "'.");
+                $self->{output}->option_exit();
+            }
+            $i++;
+        }
+    }
+}
+
+sub get_tags {
+    my ($self, %options) = @_;
+
+    my $has_cache_file = $self->{cache}->read(statefile => 'hms_ewon_' . $options{snmp}->get_hostname()  . '_' . $options{snmp}->get_port() . '_' . $self->{mode});
+    my $updated = $self->{cache}->get(name => 'updated');
+    my $tags = $self->{cache}->get(name => 'tags');
+
+    if ($has_cache_file == 0 || !defined($updated) || (time() > ($updated + $self->{option_results}->{cache_expires_in}))) {
+        my $snmp_result = $options{snmp}->get_table(
+            oid => '.1.3.6.1.4.1.8284.2.1.3.1.11.1.3', # tagCfgName
+            nothing_quit => 1
+        );
+        foreach (keys %$snmp_result) {
+            /\.(\d+)$/;
+            $tags->{$1} = $snmp_result->{$_};
+        }
+
+        $self->{cache}->write(data => {
+            tags => $tags,
+            updated => time()
+        });
+    }
+
+    return $tags;
+}
+
+my $map_status = {
+    0 => 'none', 1 => 'pretrig', 2 => 'alarm',
+    3 => 'ack', 4 => 'rtn'
+};
+my $mapping = {
+    value  => { oid => '.1.3.6.1.4.1.8284.2.1.3.1.11.1.4' }, # tagValue    
+    status => { oid => '.1.3.6.1.4.1.8284.2.1.3.1.11.1.9', map => $map_status } # tagAlStatus
+};
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $tags = $self->get_tags(snmp => $options{snmp});
+
+    $self->{tags} = {};
+    foreach (keys %$tags) {
+        if (defined($self->{option_results}->{filter_tag_index}) && $self->{option_results}->{filter_tag_index} ne '' &&
+            $_ !~ /$self->{option_results}->{filter_tag_index}/) {
+            $self->{output}->output_add(long_msg => "skipping '" . $tags->{$_} . "': no matching 'org' filter.", debug => 1);
+            next;
+        }
+        if (defined($self->{option_results}->{filter_tag_name}) && $self->{option_results}->{filter_tag_name} ne '' &&
+            $tags->{$_} !~ /$self->{option_results}->{filter_tag_name}/) {
+            $self->{output}->output_add(long_msg => "skipping '" . $tags->{$_} . "': no matching 'org' filter.", debug => 1);
+            next;
+        }
+
+        $self->{tags}->{$_} = { name => $tags->{$_}, index => $_ };
+    }
+
+    if (scalar(keys %{$self->{tags}}) <= 0) {
+        $self->{output}->add_option_msg(short_msg => "No tags found.");
+        $self->{output}->option_exit();
+    }
+
+    $options{snmp}->load(
+        oids => [
+            map($_->{oid}, values(%$mapping))
+        ],
+        instances => [keys %{$self->{tags}}],
+        instance_regexp => '^(.*)$'
+    );
+    my $snmp_result = $options{snmp}->get_leef(nothing_quit => 1);
+
+    foreach (keys %{$self->{tags}}) {
+        my $result = $options{snmp}->map_instance(mapping => $mapping, results => $snmp_result, instance => $_);
+
+        $self->{tags}->{$_}->{value} = $result->{value};
+        $self->{tags}->{$_}->{status} = $result->{status};
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check disk usages.
+
+=over 8
+
+=item B<--filter-counters>
+
+Only display some counters (regexp can be used).
+Example: --filter-counters='status'
+
+=item B<--filter-tag-index>
+
+Filter tags by index (can be a regexp).
+
+=item B<--filter-tag-name>
+
+Filter tags by name (can be a regexp).
+
+=item B<--cache-expires-in>
+
+Cache expires each X secondes (Default: 7200)
+
+=item B<--tag-output-value>
+
+Change tag output. By default it's: 'value: %s'.
+E.g: --tag-output-value='tagNameMatch,remaining: %s%%' 
+
+=item B<--warning-status>
+
+Set warning threshold for status.
+Can used special variables like: %{status}, %{name}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '%{status} =~ /alarm/').
+Can used special variables like: %{status}, %{name}
+
+=item B<--warning-*> B<--critical-*>
+
+Threshold warning.
+Can be: 'usage' (B), 'usage-free' (B), 'usage-prct' (%).
+
+=back
+
+=cut

From 191001aa68147255f2f7c395cefcc77cf46b8d99 Mon Sep 17 00:00:00 2001
From: garnier-quentin <garnier.quentin@gmail.com>
Date: Fri, 18 Dec 2020 14:58:37 +0100
Subject: [PATCH 4/4] wip ewon

---
 hardware/devices/hms/ewon/snmp/mode/tags.pm | 16 +++++++++++-----
 1 file changed, 11 insertions(+), 5 deletions(-)

diff --git a/hardware/devices/hms/ewon/snmp/mode/tags.pm b/hardware/devices/hms/ewon/snmp/mode/tags.pm
index 36dc80e35..c3ad24b04 100644
--- a/hardware/devices/hms/ewon/snmp/mode/tags.pm
+++ b/hardware/devices/hms/ewon/snmp/mode/tags.pm
@@ -55,8 +55,8 @@ sub custom_value_threshold {
     foreach my $th (('critical', 'warning')) {
         my $i = 0;
         foreach (@{$self->{instance_mode}->{'tag_threshold_' . $th}}) {
-            if ($self->{result_values}->{name} =~ /$_->{match}/ ||
-                $self->{result_values}->{index} =~ /$_->{match}/) {
+            if ($self->{result_values}->{name} =~ /$_/ ||
+                $self->{result_values}->{index} =~ /$_/) {
                 $self->{instance_mode}->{$th . '_instance'} = $i; 
                 push @$thresholds, { label => $th . '-' . $i, exit_litteral => $th };
                 last;
@@ -158,14 +158,15 @@ sub check_options {
     foreach (('warning', 'critical')) {
         my $i = 0;
         $self->{'tag_threshold_' . $_} = [];
-        next if (defined($self->{option_results}->{'tag_threshold_' . $_}));
+        next if (!defined($self->{option_results}->{'tag_threshold_' . $_}));
         foreach my $option (@{$self->{option_results}->{'tag_threshold_' . $_}}) {
-            my ($tag_match, $tag_threshold) = split /,/;
+            my ($tag_match, $tag_threshold) = split(/,/, $option);
             next if (!defined($tag_threshold) || $tag_threshold eq '');
-            if ($self->{perfdata}->threshold_validate(label => $_ . '-' . $i, value => $tag_threshold)) {
+            if (($self->{perfdata}->threshold_validate(label => $_ . '-' . $i, value => $tag_threshold)) == 0) {
                 $self->{output}->add_option_msg(short_msg => "Wrong threshold '" . $tag_threshold . "'.");
                 $self->{output}->option_exit();
             }
+            push @{$self->{'tag_threshold_' . $_}}, $tag_match; 
             $i++;
         }
     }
@@ -281,6 +282,11 @@ Cache expires each X secondes (Default: 7200)
 Change tag output. By default it's: 'value: %s'.
 E.g: --tag-output-value='tagNameMatch,remaining: %s%%' 
 
+=item B<--tag-threshold-warning> B<--tag-threshold-critical>
+
+Set tag value threshold.
+E.g: --tag-threshold-warning='tagNameMatch,50' --tag-threshold-critical='tagNameMatch,80'
+
 =item B<--warning-status>
 
 Set warning threshold for status.