From e65a8870510179362b83e89d5d5339c5a0afc3b4 Mon Sep 17 00:00:00 2001
From: qgarnier <garnier.quentin@gmail.com>
Date: Thu, 30 Sep 2021 16:17:29 +0200
Subject: [PATCH] add(plugin): cisco esa rest api (#3162)

---
 network/cisco/esa/restapi/custom/api.pm  | 208 +++++++++++++++++++
 network/cisco/esa/restapi/mode/system.pm | 242 +++++++++++++++++++++++
 network/cisco/esa/restapi/plugin.pm      |  49 +++++
 3 files changed, 499 insertions(+)
 create mode 100644 network/cisco/esa/restapi/custom/api.pm
 create mode 100644 network/cisco/esa/restapi/mode/system.pm
 create mode 100644 network/cisco/esa/restapi/plugin.pm

diff --git a/network/cisco/esa/restapi/custom/api.pm b/network/cisco/esa/restapi/custom/api.pm
new file mode 100644
index 000000000..e352fa01d
--- /dev/null
+++ b/network/cisco/esa/restapi/custom/api.pm
@@ -0,0 +1,208 @@
+#
+# Copyright 2021 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package network::cisco::esa::restapi::custom::api;
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use JSON::XS;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self  = {};
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments => {
+            'api-username:s'    => { name => 'api_username' },
+            'api-password:s'    => { name => 'api_password' },
+            'hostname:s'        => { name => 'hostname' },
+            'port:s'            => { name => 'port' },
+            'proto:s'           => { name => 'proto' },
+            'timeout:s'         => { name => 'timeout' },
+            'unknown-http-status:s'  => { name => 'unknown_http_status' },
+            'warning-http-status:s'  => { name => 'warning_http_status' },
+            'critical-http-status:s' => { name => 'critical_http_status' }
+        });
+    }
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{http} = centreon::plugins::http->new(%options);
+
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : '';
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 50;
+    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : '';
+    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : '';
+    $self->{unknown_http_status} = (defined($self->{option_results}->{unknown_http_status})) ? $self->{option_results}->{unknown_http_status} : '%{http_code} < 200 or %{http_code} >= 300';
+    $self->{warning_http_status} = (defined($self->{option_results}->{warning_http_status})) ? $self->{option_results}->{warning_http_status} : '';
+    $self->{critical_http_status} = (defined($self->{option_results}->{critical_http_status})) ? $self->{option_results}->{critical_http_status} : '';
+
+    if ($self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if ($self->{api_username} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-username option.");
+        $self->{output}->option_exit();
+    }
+    if ($self->{api_password} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-password option.");
+        $self->{output}->option_exit();
+    }
+
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{credentials} = 1;
+    $self->{option_results}->{basic} = 1;
+    $self->{option_results}->{username} = $self->{api_username};
+    $self->{option_results}->{password} = $self->{api_password};
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    return if (defined($self->{settings_done}));
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Accept', value => 'application/json');
+    $self->{http}->set_options(%{$self->{option_results}});
+    $self->{settings_done} = 1;
+}
+
+sub get_hostname {
+    my ($self, %options) = @_;
+
+    return $self->{hostname};
+}
+
+sub get_port {
+    my ($self, %options) = @_;
+
+    return $self->{port};
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    $self->settings();
+    my $content = $self->{http}->request(
+        url_path => $options{endpoint},
+        unknown_status => $self->{unknown_http_status},
+        warning_status => $self->{warning_http_status},
+        critical_status => $self->{critical_http_status}
+    );
+
+    if (!defined($content) || $content eq '') {
+        $self->{output}->add_option_msg(short_msg => "API returns empty content [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
+        $self->{output}->option_exit();
+    }
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($content);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode response (add --debug option to display returned content)");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Cisco AsyncOS API
+
+=head1 REST API OPTIONS
+
+Cisco AsyncOS API
+
+=over 8
+
+=item B<--hostname>
+
+Set hostname.
+
+=item B<--port>
+
+Port used (Default: 443)
+
+=item B<--proto>
+
+Specify https if needed (Default: 'https')
+
+=item B<--api-username>
+
+API username.
+
+=item B<--api-password>
+
+API password.
+
+=item B<--timeout>
+
+Set timeout in seconds (Default: 50).
+
+=back
+
+=head1 DESCRIPTION
+
+B<custom>.
+
+=cut
diff --git a/network/cisco/esa/restapi/mode/system.pm b/network/cisco/esa/restapi/mode/system.pm
new file mode 100644
index 000000000..58322c1e0
--- /dev/null
+++ b/network/cisco/esa/restapi/mode/system.pm
@@ -0,0 +1,242 @@
+#
+# Copyright 2021 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package network::cisco::esa::restapi::mode::system;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+
+sub custom_cpu_temp_perfdata {
+    my ($self, %options) = @_;
+
+    $self->{output}->perfdata_add(
+        nlabel => $self->{nlabel},
+        unit => 'C',
+        instances => 'cpu',
+        value => $self->{result_values}->{cpu},
+        warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{thlabel}),
+        critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{thlabel})
+    );
+}
+
+sub custom_pcie_temp_perfdata {
+    my ($self, %options) = @_;
+
+    $self->{output}->perfdata_add(
+        nlabel => $self->{nlabel},
+        unit => 'C',
+        instances => 'pcie',
+        value => $self->{result_values}->{pcie},
+        warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{thlabel}),
+        critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{thlabel})
+    );
+}
+
+sub custom_sio_temp_perfdata {
+    my ($self, %options) = @_;
+
+    $self->{output}->perfdata_add(
+        nlabel => $self->{nlabel},
+        unit => 'C',
+        instances => 'sio',
+        value => $self->{result_values}->{sio},
+        warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{thlabel}),
+        critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{thlabel})
+    );
+}
+
+sub custom_cpu_fan_perfdata {
+    my ($self, %options) = @_;
+
+    $self->{output}->perfdata_add(
+        nlabel => $self->{nlabel},
+        unit => 'rpm',
+        instances => 'cpu',
+        value => $self->{result_values}->{cpu},
+        warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{thlabel}),
+        critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{thlabel})
+    );
+}
+
+sub system_long_output {
+    my ($self, %options) = @_;
+
+    return 'checking system';
+}
+
+sub prefix_message_output {
+    my ($self, %options) = @_;
+
+    return 'messages in ';
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+
+    $self->{maps_counters_type} = [
+        { name => 'system', type => 3, cb_long_output => 'system_long_output', indent_long_output => '    ',
+            group => [
+                { name => 'cpu', type => 0, display_short => 0, skipped_code => { -10 => 1 } },
+                { name => 'memory', type => 0, display_short => 0, skipped_code => { -10 => 1 } },
+                { name => 'rc', type => 0, display_short => 0, skipped_code => { -10 => 1 } },
+                { name => 'message', type => 0, cb_prefix_output => 'prefix_message_output', display_short => 0, skipped_code => { -10 => 1 } },
+                { name => 'queue', type => 0, display_short => 0, skipped_code => { -10 => 1 } }
+            ]
+        }
+    ];
+
+    $self->{maps_counters}->{cpu} = [
+        { label => 'cpu-utilization', nlabel => 'system.cpu.utilization.percentage', set => {
+                key_values => [ { name => 'cpu_util' } ],
+                output_template => 'cpu utilization: %.2f%%',
+                perfdatas => [
+                    { template => '%s', min => 0, max => 100, unit => '%' }
+                ]
+            }
+        }
+    ];
+
+    $self->{maps_counters}->{memory} = [
+        { label => 'memory', nlabel => 'system.memory.usage.percentage', set => {
+                key_values => [ { name => 'ram_utilization' } ],
+                output_template => 'memory usage: %.2f %%',
+                perfdatas => [
+                    { template => '%.2f', unit => '%', min => 0, max => 100 }
+                ]
+            }
+        },
+        { label => 'swap', nlabel => 'system.swap.usage.percentage', set => {
+                key_values => [ { name => 'swap_utilization' } ],
+                output_template => 'swap usage: %.2f %%',
+                perfdatas => [
+                    { template => '%.2f', unit => '%', min => 0, max => 100 }
+                ]
+            }
+        }
+    ];
+
+    $self->{maps_counters}->{rc} = [
+        { label => 'resource-conservation', nlabel => 'system.resource.conservation.current.count', set => {
+                key_values => [ { name => 'resource_conservation' } ],
+                output_template => 'current resource conservation: %s',
+                perfdatas => [
+                    { template => '%s', min => 0 }
+                ]
+            }
+        }
+    ];
+
+    $self->{maps_counters}->{message} = [
+         { label => 'messages-quarantine', nlabel => 'system.queue.messages.quarantine.current.count', set => {
+                key_values => [ { name => 'quarantine' } ],
+                output_template => 'quarantine: %s',
+                perfdatas => [
+                    { template => '%s', min => 0 }
+                ]
+            }
+        },
+        { label => 'messages-workqueue', nlabel => 'system.queue.messages.workqueue.current.count', set => {
+                key_values => [ { name => 'workqueue' } ],
+                output_template => 'workqueue: %s',
+                perfdatas => [
+                    { template => '%s', min => 0 }
+                ]
+            }
+        }
+    ];
+
+    $self->{maps_counters}->{queue} = [
+        { label => 'queue-utilization', nlabel => 'system.queue.utilization.percentage', set => {
+                key_values => [ { name => 'queue_util' } ],
+                output_template => 'queue utilization: %.2f%%',
+                perfdatas => [
+                    { template => '%s', min => 0, max => 100, unit => '%' }
+                ]
+            }
+        }
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
+    bless $self, $class;
+
+    $options{options}->add_options(arguments => {
+    });
+
+    return $self;
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $infos = $options{custom}->request_api(endpoint => '/esa/api/v2.0/health');
+
+    $self->{output}->output_add(short_msg => 'System is ok');
+
+    $self->{system} = {
+        global => {
+            cpu => {
+                cpu_util => $infos->{data}->{percentage_cpu_load}
+            },
+            memory => {
+                ram_utilization => $infos->{data}->{percentage_ram_utilization},
+                swap_utilization => $infos->{data}->{percentage_swap_utilization}
+            },
+            rc => { resource_conservation => $infos->{data}->{resource_conservation} },
+            message => {
+                quarantine => $infos->{data}->{messages_in_pvo_quarantines},
+                workqueue => $infos->{data}->{messages_in_workqueue}
+            },
+            queue => {
+                queue_util => $infos->{data}->{percentage_queue_utilization}
+            }
+        }
+    };
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check system.
+
+=over 8
+
+=item B<--filter-counters>
+
+Only display some counters (regexp can be used).
+Example: --filter-counters='memory'
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'resource-conservation', 'cpu-utilization' (%),
+'messages-quarantine', 'messages-workqueue',
+'queue-utilization' (%), 'memory' (%), 'swap' (%).
+
+=back
+
+=cut
diff --git a/network/cisco/esa/restapi/plugin.pm b/network/cisco/esa/restapi/plugin.pm
new file mode 100644
index 000000000..6b0f2f051
--- /dev/null
+++ b/network/cisco/esa/restapi/plugin.pm
@@ -0,0 +1,49 @@
+#
+# Copyright 2021 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package network::cisco::esa::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ( $class, %options ) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '0.1';
+    $self->{modes} = {
+        'system'   => 'network::cisco::esa::restapi::mode::system'
+    };
+
+    $self->{custom_modes}->{api} = 'network::cisco::esa::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check Cisco ESA (Email Security Appliance) using AsyncOS Rest API.
+
+=cut