From e8cb84b41e5cfb8bebb7342712a51949daa794c6 Mon Sep 17 00:00:00 2001
From: garnier-quentin <garnier.quentin@gmail.com>
Date: Mon, 23 Sep 2019 13:23:23 +0200
Subject: [PATCH] add hp oneview rest api

---
 .../server/hp/oneview/restapi/custom/api.pm   | 278 ++++++++++++++++++
 .../hp/oneview/restapi/mode/storagepools.pm   | 195 ++++++++++++
 .../server/hp/oneview/restapi/plugin.pm       |  54 ++++
 3 files changed, 527 insertions(+)
 create mode 100644 centreon-plugins/hardware/server/hp/oneview/restapi/custom/api.pm
 create mode 100644 centreon-plugins/hardware/server/hp/oneview/restapi/mode/storagepools.pm
 create mode 100644 centreon-plugins/hardware/server/hp/oneview/restapi/plugin.pm

diff --git a/centreon-plugins/hardware/server/hp/oneview/restapi/custom/api.pm b/centreon-plugins/hardware/server/hp/oneview/restapi/custom/api.pm
new file mode 100644
index 000000000..9568c7cdc
--- /dev/null
+++ b/centreon-plugins/hardware/server/hp/oneview/restapi/custom/api.pm
@@ -0,0 +1,278 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::server::hp::oneview::restapi::custom::api;
+
+use base qw(centreon::plugins::mode);
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use centreon::plugins::statefile;
+use JSON::XS;
+use Digest::MD5 qw(md5_hex);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments =>  {
+            'hostname:s'        => { name => 'hostname' },
+            'port:s'            => { name => 'port'},
+            'proto:s'           => { name => 'proto' },
+            'api-username:s'    => { name => 'api_username' },
+            'api-password:s'    => { name => 'api_password' },
+            'timeout:s'         => { name => 'timeout', default => 30 },
+        });
+    }
+    
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};
+    $self->{http} = centreon::plugins::http->new(%options);
+    $self->{cache} = centreon::plugins::statefile->new(%options);
+
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : undef;
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 30;
+    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : undef;
+    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : undef;
+
+    if (!defined($self->{hostname}) || $self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_username}) || $self->{api_username} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-username option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_password}) || $self->{api_password} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-password option.");
+        $self->{output}->option_exit();
+    }
+
+    $self->{cache}->check_options(option_results => $self->{option_results});
+
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{timeout} = $self->{timeout};
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Content-Type', value => 'application/json;charset=UTF-8');
+    $self->{http}->add_header(key => 'Accept', value => 'application/json;charset=UTF-8');
+    if (defined($self->{session_id})) {
+        $self->{http}->add_header(key => 'Auth', value => $self->{session_id});
+    }
+    $self->{http}->set_options(%{$self->{option_results}});
+}
+
+sub json_decode {
+    my ($self, %options) = @_;
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($options{content});
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response: $@");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+sub clean_session_id {
+    my ($self, %options) = @_;
+
+    my $datas = { last_timestamp => time() };
+    $options{statefile}->write(data => $datas);
+    $self->{session_id} = undef;
+}
+
+sub authenticate {
+    my ($self, %options) = @_;
+
+    my $has_cache_file = $options{statefile}->read(statefile => 'hp_oneview_' . md5_hex($self->{option_results}->{hostname}) . '_' . md5_hex($self->{option_results}->{api_username}));
+    my $session_id = $options{statefile}->get(name => 'session_id');
+    
+    if ($has_cache_file == 0 || !defined($session_id)) {
+        my $json_request = { userName => $self->{api_username}, password => $self->{api_password} };
+        my $encoded;
+        eval {
+            $encoded = encode_json($json_request);
+        };
+        if ($@) {
+            $self->{output}->add_option_msg(short_msg => "Cannot encode json request");
+            $self->{output}->option_exit();
+        }
+
+        my $content = $self->{http}->request(
+            method => 'POST',
+            url_path => '/rest/login-sessions',
+            query_form_post => $encoded,
+            warning_status => '', unknown_status => '', critical_status => '',
+        );
+        if ($self->{http}->get_code() != 200) {
+            $self->{output}->add_option_msg(short_msg => "Login error [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
+            $self->{output}->option_exit();
+        }
+
+        my $decoded = $self->json_decode(content => $content);
+
+        if (defined($decoded) && defined($decoded->{sessionID})) {
+            $session_id = $decoded->{sessionID};
+        } else {
+            $self->{output}->add_option_msg(short_msg => "Error retrieving session_id");
+            $self->{output}->option_exit();
+        }
+
+        my $datas = { last_timestamp => time(), session_id => $session_id };
+        $options{statefile}->write(data => $datas);
+    }
+
+    $self->{session_id} = $session_id;
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    $self->settings();
+    if (!defined($self->{session_id})) {
+        $self->authenticate(statefile => $self->{cache});
+    }
+    my $content = $self->{http}->request(
+        %options, 
+        warning_status => '', unknown_status => '', critical_status => ''
+    );
+
+    # Maybe there is an issue with the session_id. So we retry.
+    if ($self->{http}->get_code() != 200) {
+        $self->clean_session_id();
+        $self->authenticate(statefile => $self->{cache});
+        $content = $self->{http}->request(%options, 
+            warning_status => '', unknown_status => '', critical_status => ''
+        );
+    }
+
+    my $decoded = $self->json_decode(content => $content);
+    if (!defined($decoded)) {
+        $self->{output}->add_option_msg(short_msg => "Error while retrieving data (add --debug option for detailed message)");
+        $self->{output}->option_exit();
+    }
+    if (defined($decoded->{errorCode})) {
+        $self->clean_session_id();
+        $self->{output}->add_option_msg(short_msg => 'api error: ' . $decoded->{message});
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+HP OneView Rest API
+
+=head1 REST API OPTIONS
+
+=over 8
+
+=item B<--hostname>
+
+Set hostname or IP of vsca.
+
+=item B<--port>
+
+Set port (Default: '443').
+
+=item B<--proto>
+
+Specify https if needed (Default: 'https').
+
+=item B<--api-username>
+
+Set username.
+
+=item B<--api-password>
+
+Set password.
+
+=item B<--timeout>
+
+Threshold for HTTP timeout (Default: '30').
+
+=back
+
+=cut
diff --git a/centreon-plugins/hardware/server/hp/oneview/restapi/mode/storagepools.pm b/centreon-plugins/hardware/server/hp/oneview/restapi/mode/storagepools.pm
new file mode 100644
index 000000000..ca3c8dfaa
--- /dev/null
+++ b/centreon-plugins/hardware/server/hp/oneview/restapi/mode/storagepools.pm
@@ -0,0 +1,195 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::server::hp::oneview::restapi::mode::storagepools;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold catalog_status_calc);
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+
+    my $msg = 'status : ' . $self->{result_values}->{status};
+    return $msg;
+}
+
+sub custom_usage_output {
+    my ($self, %options) = @_;
+    
+    my ($total_size_value, $total_size_unit) = $self->{perfdata}->change_bytes(value => $self->{result_values}->{total_space_absolute});
+    my ($total_used_value, $total_used_unit) = $self->{perfdata}->change_bytes(value => $self->{result_values}->{used_space_absolute});
+    my ($total_free_value, $total_free_unit) = $self->{perfdata}->change_bytes(value => $self->{result_values}->{free_space_absolute});
+    my $msg = sprintf('space usage total: %s used: %s (%.2f%%) free: %s (%.2f%%)',
+        $total_size_value . " " . $total_size_unit,
+        $total_used_value . " " . $total_used_unit, $self->{result_values}->{prct_used_space_absolute},
+        $total_free_value . " " . $total_free_unit, $self->{result_values}->{prct_free_space_absolute}
+    );
+    return $msg;
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'pool', type => 1, cb_prefix_output => 'prefix_pool_output', message_multiple => 'All storage pools are ok' },
+    ];
+    
+    $self->{maps_counters}->{pool} = [
+        { label => 'status', threshold => 0, set => {
+                key_values => [ { name => 'status' }, { name => 'display' } ],
+                closure_custom_calc => \&catalog_status_calc,
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => \&catalog_status_threshold,
+            }
+        },
+        { label => 'usage', nlabel => 'pool.space.usage.bytes', set => {
+                key_values => [ { name => 'used_space' }, { name => 'free_space' }, { name => 'prct_used_space' }, { name => 'prct_free_space' }, { name => 'total_space' }, { name => 'display' },  ],
+                closure_custom_output => $self->can('custom_usage_output'),
+                perfdatas => [
+                    { value => 'used_space_absolute', template => '%d', min => 0, max => 'total_space_absolute',
+                      unit => 'B', cast_int => 1, label_extra_instance => 1, instance_use => 'display_absolute' },
+                ],
+            }
+        },
+        { label => 'usage-free', nlabel => 'pool.space.free.bytes', display_ok => 0, set => {
+                key_values => [ { name => 'free_space' }, { name => 'used_space' }, { name => 'prct_used_space' }, { name => 'prct_free_space' }, { name => 'total_space' }, { name => 'display' },  ],
+                closure_custom_output => $self->can('custom_usage_output'),
+                perfdatas => [
+                    { value => 'free_space_absolute', template => '%d', min => 0, max => 'total_space_absolute',
+                      unit => 'B', cast_int => 1, label_extra_instance => 1, instance_use => 'display_absolute' },
+                ],
+            }
+        },
+        { label => 'usage-prct', nlabel => 'pool.space.usage.percentage', display_ok => 0, set => {
+                key_values => [ { name => 'prct_used_space' }, { name => 'display' } ],
+                output_template => 'used : %.2f %%',
+                perfdatas => [
+                    { value => 'prct_used_space_absolute', template => '%.2f', min => 0, max => 100,
+                      unit => '%', label_extra_instance => 1, instance_use => 'display_absolute' },
+                ],
+            }
+        },
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
+    bless $self, $class;
+    
+    $options{options}->add_options(arguments => { 
+        'filter-name:s'     => { name => 'filter_name' },
+        'unknown-status:s'  => { name => 'unknown_status', default => '%{status} =~ /unknown/i' },
+        'warning-status:s'  => { name => 'warning_status', default => '%{status} =~ /warning/i' },
+        'critical-status:s' => { name => 'critical_status', default => '%{status} =~ /critical/i' },
+    });
+    
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->change_macros(macros => ['warning_status', 'critical_status', 'unknown_status']);
+}
+
+sub prefix_pool_output {
+    my ($self, %options) = @_;
+    
+    return "Storage pool '" . $options{instance_value}->{display} . "' ";
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $results = $options{custom}->request_api(url_path => '/rest/storage-pools?start=0&count=-1');
+
+    $self->{pool} = {};
+    foreach (@{$results->{members}}) {
+        if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
+            $_->{name} !~ /$self->{option_results}->{filter_name}/) {
+            $self->{output}->output_add(long_msg => "skipping storage pool '" . $_->{name} . "': no matching filter.", debug => 1);
+            next;
+        }
+
+        $self->{pool}->{$_->{name}} = {
+            display => $_->{name},
+            status => $_->{status},
+            total_space => $_->{totalCapacity},
+            used_space => $_->{totalCapacity} - $_->{freeCapacity},
+            free_space => $_->{freeCapacity},
+            prct_used_space => ($_->{totalCapacity} - $_->{freeCapacity}) * 100 / $_->{totalCapacity},
+            prct_free_space => $_->{freeCapacity} * 100 / $_->{totalCapacity},
+        };
+    }
+    
+    if (scalar(keys %{$self->{pool}}) <= 0) {
+        $self->{output}->add_option_msg(short_msg => "No storage pool found");
+        $self->{output}->option_exit();
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check storage pool usages.
+
+=over 8
+
+=item B<--filter-counters>
+
+Only display some counters (regexp can be used).
+Example: --filter-counters='^usage$'
+
+=item B<--filter-name>
+
+Filter pool name (can be a regexp).
+
+=item B<--unknown-status>
+
+Set warning threshold for status (Default: '%{status} =~ /unknown/i').
+Can used special variables like: %{status}, %{display}
+
+=item B<--warning-status>
+
+Set warning threshold for status (Default: '%{status} =~ /warning/i').
+Can used special variables like: %{status}, %{display}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '%{status} =~ /critical/i').
+Can used special variables like: %{status}, %{display}
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'usage' (B), 'usage-free' (B), 'usage-prct' (%).
+
+=back
+
+=cut
diff --git a/centreon-plugins/hardware/server/hp/oneview/restapi/plugin.pm b/centreon-plugins/hardware/server/hp/oneview/restapi/plugin.pm
new file mode 100644
index 000000000..007af0823
--- /dev/null
+++ b/centreon-plugins/hardware/server/hp/oneview/restapi/plugin.pm
@@ -0,0 +1,54 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::server::hp::oneview::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ($class, %options) = @_;
+
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '1.0';
+    %{$self->{modes}} = (
+        'storage-pools' => 'hardware::server::hp::oneview::restapi::mode::storagepools',
+    );
+
+    $self->{custom_modes}{api} = 'hardware::server::hp::oneview::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check HP OneView through HTTP/REST API.
+
+=over 8
+
+=back
+
+=cut