diff --git a/apps/gorgone/restapi/custom/api.pm b/apps/gorgone/restapi/custom/api.pm
new file mode 100644
index 000000000..4a8d04950
--- /dev/null
+++ b/apps/gorgone/restapi/custom/api.pm
@@ -0,0 +1,217 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::gorgone::restapi::custom::api;
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use JSON::XS;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self  = {};
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments => {
+            'api-username:s'         => { name => 'api_username' },
+            'api-password:s'         => { name => 'api_password' },
+            'hostname:s'             => { name => 'hostname' },
+            'port:s'                 => { name => 'port' },
+            'proto:s'                => { name => 'proto' },
+            'timeout:s'              => { name => 'timeout' },
+            'unknown-http-status:s'  => { name => 'unknown_http_status' },
+            'warning-http-status:s'  => { name => 'warning_http_status' },
+            'critical-http-status:s' => { name => 'critical_http_status' }
+        });
+    }
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};
+    $self->{http} = centreon::plugins::http->new(%options);
+    
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : '';
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 8085;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'http';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 10;
+    $self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : '';
+    $self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : '';
+    $self->{unknown_http_status} = (defined($self->{option_results}->{unknown_http_status})) ? $self->{option_results}->{unknown_http_status} : '%{http_code} < 200 or %{http_code} >= 300';
+    $self->{warning_http_status} = (defined($self->{option_results}->{warning_http_status})) ? $self->{option_results}->{warning_http_status} : '';
+    $self->{critical_http_status} = (defined($self->{option_results}->{critical_http_status})) ? $self->{option_results}->{critical_http_status} : '';
+
+    if ($self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if ($self->{api_username} ne '' && $self->{api_password} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-password option.");
+        $self->{output}->option_exit();
+    }
+
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    if ($self->{api_username} ne '') {
+        $self->{option_results}->{credentials} = 1;
+        $self->{option_results}->{basic} = 1;
+        $self->{option_results}->{username} = $self->{api_username};
+        $self->{option_results}->{password} = $self->{api_password};
+    }
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    return if (defined($self->{settings_done}));
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Accept', value => 'application/json');
+    $self->{http}->add_header(key => 'Content-Type', value => 'application/json');
+    $self->{http}->set_options(%{$self->{option_results}});
+    $self->{settings_done} = 1;
+}
+
+sub get_hostname {
+    my ($self, %options) = @_;
+
+    return $self->{hostname};
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    $self->settings();
+
+    my $content = $self->{http}->request(
+        url_path => $options{endpoint},
+        unknown_status => $self->{unknown_http_status},
+        warning_status => $self->{warning_http_status},
+        critical_status => $self->{critical_http_status}
+    );
+    
+    if (!defined($content) || $content eq '') {
+        $self->{output}->add_option_msg(short_msg => "API returns empty content [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
+        $self->{output}->option_exit();
+    }
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($content);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode response (add --debug option to display returned content)");
+        $self->{output}->option_exit();
+    }
+
+    return $decoded;
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Gorgone Rest API
+
+=head1 REST API OPTIONS
+
+Gorgone Rest API
+
+=over 8
+
+=item B<--hostname>
+
+Gorgone hostname.
+
+=item B<--port>
+
+Port used (Default: 8085)
+
+=item B<--proto>
+
+Specify https if needed (Default: 'http')
+
+=item B<--api-username>
+
+Gorgone API username.
+
+=item B<--api-password>
+
+Gorgone API password.
+
+=item B<--timeout>
+
+Set timeout in seconds (Default: 10).
+
+=back
+
+=head1 DESCRIPTION
+
+B<custom>.
+
+=cut
diff --git a/apps/gorgone/restapi/mode/events.pm b/apps/gorgone/restapi/mode/events.pm
new file mode 100644
index 000000000..bb58bf981
--- /dev/null
+++ b/apps/gorgone/restapi/mode/events.pm
@@ -0,0 +1,142 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::gorgone::restapi::mode::events;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use Digest::MD5 qw(md5_hex);
+
+sub prefix_path_output {
+    my ($self, %options) = @_;
+
+    return "Path '" . $options{instance_value}->{display} . "' ";
+}
+
+sub path_long_output {
+    my ($self, %options) = @_;
+
+    return "checking path '" . $options{instance_value}->{display} . "'";
+}
+
+sub prefix_event_output {
+    my ($self, %options) = @_;
+
+    return "event '" . $options{instance_value}->{display} . "' ";
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+
+    $self->{maps_counters_type} = [
+        { name => 'paths', type => 3, cb_prefix_output => 'prefix_path_output', cb_long_output => 'path_long_output', indent_long_output => '    ', message_multiple => 'All paths are ok',
+            group => [
+                { name => 'global', type => 0, skipped_code => { -10 => 1 } },
+                { name => 'events', cb_prefix_output => 'prefix_event_output', message_multiple => 'All events are ok', type => 1, skipped_code => { -10 => 1 } }
+            ]
+        }
+    ];
+
+    $self->{maps_counters}->{global} = [
+        { label => 'events-total', nlabel => 'path.events.total.count', set => {
+                key_values => [ { name => 'total', diff => 1 } ],
+                output_template => 'total events: %s',
+                perfdatas => [
+                    { template => '%s', min => 0, label_extra_instance => 1 }
+                ]
+            }
+        }
+    ];
+
+    $self->{maps_counters}->{events} = [
+         { label => 'event-total', nlabel => 'event.total.count', set => {
+                key_values => [ { name => 'total', diff => 1 } ],
+                output_template => 'total: %s',
+                perfdatas => [
+                    { template => '%s', min => 0, label_extra_instance => 1 }
+                ]
+            }
+        }
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, statefile => 1, force_new_perfdata => 1);
+    bless $self, $class;
+    
+    $options{options}->add_options(arguments => { 
+    });
+    
+    return $self;
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $infos = $options{custom}->request_api(endpoint => '/api/internal/information');
+
+    $self->{paths} = {};
+    foreach my $path (('internal', 'external')) {
+        next if (!defined($infos->{data}->{counters}->{$path}));
+
+        $self->{paths}->{$path} = {
+            display => $path,
+            global => { total => $infos->{data}->{counters}->{$path}->{total} },
+            events => {}
+        };
+        foreach my $event (keys %{$infos->{data}->{counters}->{$path}}) {
+            next if ($event eq 'total');
+            $self->{paths}->{$path}->{events}->{$event} = {
+                display => $event,
+                total => $infos->{data}->{counters}->{$path}->{$event}
+            };
+        }
+    }
+
+    $self->{cache_name} = 'gorgone_' . $self->{mode} . '_' . $options{custom}->get_hostname()  . '_' .
+        (defined($self->{option_results}->{filter_counters}) ? md5_hex($self->{option_results}->{filter_counters}) : md5_hex('all'));
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check events.
+
+=over 8
+
+=item B<--filter-counters>
+
+Only display some counters (regexp can be used).
+Example: --filter-counters='events-total'
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'events-total', 'event-total'.
+
+=back
+
+=cut
diff --git a/apps/gorgone/restapi/mode/nodes.pm b/apps/gorgone/restapi/mode/nodes.pm
new file mode 100644
index 000000000..6e433d974
--- /dev/null
+++ b/apps/gorgone/restapi/mode/nodes.pm
@@ -0,0 +1,107 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::gorgone::restapi::mode::nodes;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+
+sub prefix_node_output {
+    my ($self, %options) = @_;
+
+    return "Node '" . $options{instance_value}->{display} . "' ";
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+
+    $self->{maps_counters_type} = [
+        { name => 'nodes', type => 1, cb_prefix_output => 'prefix_node_output', message_multiple => 'All nodes are ok' }
+    ];
+
+    $self->{maps_counters}->{nodes} = [
+        { label => 'ping-received-lasttime', nlabel => 'node.ping.received.lasttime.seconds', set => {
+                key_values => [ { name => 'last_ping_recv' }, { name => 'display' },  ],
+                output_template => 'last ping received: %s s',
+                perfdatas => [
+                    { template => '%d', min => -1, unit => 's', label_extra_instance => 1 }
+                ]
+            }
+        }
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
+    bless $self, $class;
+    
+    $options{options}->add_options(arguments => { 
+        'filter-node-id:s' => { name => 'filter_node_id' }
+    });
+    
+    return $self;
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $nodes = $options{custom}->request_api(endpoint => '/api/internal/constatus');
+
+    $self->{nodes} = {};
+    foreach my $node_id (keys %{$nodes->{data}}) {
+        if (defined($self->{option_results}->{filter_node_id}) && $self->{option_results}->{filter_node_id} ne '' &&
+            $node_id !~ /$self->{option_results}->{filter_node_id}/) {
+            $self->{output}->output_add(long_msg => "skipping node '" . $node_id . "': no matching filter.", debug => 1);
+            next;
+        }
+
+        $self->{nodes}->{ $node_id } = {
+            display => $node_id,
+            last_ping_recv => defined($nodes->{data}->{$node_id}->{last_ping_recv}) ? 
+                time() - $nodes->{data}->{$node_id}->{last_ping_recv} : -1
+        };
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check nodes.
+
+=over 8
+
+=item B<--filter-node-id>
+
+Filter nodes (can be a regexp).
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'ping-received-lasttime' (s).
+
+=back
+
+=cut
diff --git a/apps/gorgone/restapi/plugin.pm b/apps/gorgone/restapi/plugin.pm
new file mode 100644
index 000000000..aa59687c4
--- /dev/null
+++ b/apps/gorgone/restapi/plugin.pm
@@ -0,0 +1,51 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::gorgone::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ( $class, %options ) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '0.1';
+    $self->{modes} = {
+        'events' => 'apps::gorgone::restapi::mode::events',
+        'nodes'  => 'apps::gorgone::restapi::mode::nodes'
+    };
+
+    $self->{custom_modes}{api} = 'apps::gorgone::restapi::custom::api';
+    return $self;
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check gorgone using Rest API.
+https://github.com/centreon/centreon-gorgone
+
+=cut