From f76b91bb5fa768d84412efc3e846a89512f0f59c Mon Sep 17 00:00:00 2001
From: Colin Gagnaire <cgagnaire@centreon.com>
Date: Thu, 28 Feb 2019 18:25:12 +0100
Subject: [PATCH] add rudder plugin (wip)

---
 apps/rudder/restapi/custom/api.pm            | 240 +++++++++++++++++++
 apps/rudder/restapi/mode/globalcompliance.pm | 166 +++++++++++++
 apps/rudder/restapi/mode/listnodes.pm        | 146 +++++++++++
 apps/rudder/restapi/plugin.pm                |  56 +++++
 4 files changed, 608 insertions(+)
 create mode 100644 apps/rudder/restapi/custom/api.pm
 create mode 100644 apps/rudder/restapi/mode/globalcompliance.pm
 create mode 100644 apps/rudder/restapi/mode/listnodes.pm
 create mode 100644 apps/rudder/restapi/plugin.pm

diff --git a/apps/rudder/restapi/custom/api.pm b/apps/rudder/restapi/custom/api.pm
new file mode 100644
index 000000000..d79dd40fe
--- /dev/null
+++ b/apps/rudder/restapi/custom/api.pm
@@ -0,0 +1,240 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::rudder::restapi::custom::api;
+
+use strict;
+use warnings;
+use centreon::plugins::http;
+use DateTime;
+use JSON::XS;
+use URI::Encode;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self  = {};
+    bless $self, $class;
+
+    if (!defined($options{output})) {
+        print "Class Custom: Need to specify 'output' argument.\n";
+        exit 3;
+    }
+    if (!defined($options{options})) {
+        $options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
+        $options{output}->option_exit();
+    }
+    
+    if (!defined($options{noptions})) {
+        $options{options}->add_options(arguments => {
+            "hostname:s"        => { name => 'hostname' },
+            "url-path:s"        => { name => 'url_path' },
+            "port:s"            => { name => 'port' },
+            "proto:s"           => { name => 'proto' },
+            "api-token:s"       => { name => 'api_token' },
+            "proxyurl:s"        => { name => 'proxyurl' },
+            "timeout:s"         => { name => 'timeout' },
+            "ssl-opt:s@"        => { name => 'ssl_opt' },
+        });
+    }
+    $options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
+
+    $self->{output} = $options{output};
+    $self->{mode} = $options{mode};    
+    $self->{http} = centreon::plugins::http->new(output => $self->{output});
+
+    return $self;
+}
+
+sub set_options {
+    my ($self, %options) = @_;
+
+    $self->{option_results} = $options{option_results};
+}
+
+sub set_defaults {
+    my ($self, %options) = @_;
+
+    foreach (keys %{$options{default}}) {
+        if ($_ eq $self->{mode}) {
+            for (my $i = 0; $i < scalar(@{$options{default}->{$_}}); $i++) {
+                foreach my $opt (keys %{$options{default}->{$_}[$i]}) {
+                    if (!defined($self->{option_results}->{$opt}[$i])) {
+                        $self->{option_results}->{$opt}[$i] = $options{default}->{$_}[$i]->{$opt};
+                    }
+                }
+            }
+        }
+    }
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+
+    $self->{hostname} = (defined($self->{option_results}->{hostname})) ? $self->{option_results}->{hostname} : undef;
+    $self->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
+    $self->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
+    $self->{url_path} = (defined($self->{option_results}->{url_path})) ? $self->{option_results}->{url_path} : '/rudder/api/latest';
+    $self->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 10;
+    $self->{api_token} = (defined($self->{option_results}->{api_token})) ? $self->{option_results}->{api_token} : '';
+ 
+    if (!defined($self->{hostname}) || $self->{hostname} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --hostname option.");
+        $self->{output}->option_exit();
+    }
+    if (!defined($self->{api_token}) || $self->{api_token} eq '') {
+        $self->{output}->add_option_msg(short_msg => "Need to specify --api-token option.");
+        $self->{output}->option_exit();
+    }
+    
+    return 0;
+}
+
+sub build_options_for_httplib {
+    my ($self, %options) = @_;
+
+    $self->{option_results}->{hostname} = $self->{hostname};
+    $self->{option_results}->{timeout} = $self->{timeout};
+    $self->{option_results}->{port} = $self->{port};
+    $self->{option_results}->{proto} = $self->{proto};
+    $self->{option_results}->{url_path} = $self->{url_path};
+    $self->{option_results}->{warning_status} = '';
+    $self->{option_results}->{critical_status} = '';
+}
+
+sub settings {
+    my ($self, %options) = @_;
+
+    $self->build_options_for_httplib();
+    $self->{http}->add_header(key => 'Accept', value => 'application/json');
+    if (defined($self->{access_token})) {
+        $self->{http}->add_header(key => 'X-API-Token', value => $self->{access_token});
+    }
+    $self->{http}->set_options(%{$self->{option_results}});
+}
+
+sub get_connection_info {
+    my ($self, %options) = @_;
+    
+    return $self->{hostname} . ":" . $self->{port};
+}
+
+sub get_hostname {
+    my ($self, %options) = @_;
+    
+    return $self->{hostname};
+}
+
+sub get_port {
+    my ($self, %options) = @_;
+    
+    return $self->{port};
+}
+
+sub get_token {
+    my ($self, %options) = @_;
+
+    return $self->{option_results}->{api_token};
+}
+
+sub request_api {
+    my ($self, %options) = @_;
+
+    if (!defined($self->{access_token})) {
+        $self->{access_token} = $self->get_token();
+    }
+
+    $self->settings;
+    
+    $self->{output}->output_add(long_msg => "Query URL: '" . $self->{proto} . "://" . $self->{hostname} .
+        $self->{url_path} . $options{url_path} . "'", debug => 1);
+
+    my $content = $self->{http}->request(url_path => $self->{url_path} . $options{url_path});
+    my $response = $self->{http}->get_response(); 
+
+    my $decoded;
+    eval {
+        $decoded = JSON::XS->new->utf8->decode($content);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response: $@");
+        $self->{output}->option_exit();
+    }
+    if (!defined($decoded->{result}) || $decoded->{result} ne "success") {
+        $self->{output}->output_add(long_msg => "Error message : " . $decoded->{errorDetails}, debug => 1);
+        $self->{output}->add_option_msg(short_msg => "API return error code '" . $decoded->{result} . "' (add --debug option for detailed message)");
+        $self->{output}->option_exit();
+    }
+    
+    return $decoded->{data};
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Rudder Rest API
+
+=head1 SYNOPSIS
+
+Rudder Rest API custom mode
+
+=head1 REST API OPTIONS
+
+Rudder Rest API
+
+=over 8
+
+=item B<--hostname>
+
+Rudder API hostname.
+
+=item B<--port>
+
+API port (Default: 443)
+
+=item B<--proto>
+
+Specify https if needed (Default: 'https')
+
+=item B<--url-path>
+
+API URL path (Default: '/rudder/api/latest')
+
+=item B<--proxyurl>
+
+Proxy URL if any
+
+=item B<--timeout>
+
+Set HTTP timeout
+
+=item B<--ssl-opt>
+
+Set SSL option (--ssl-opt="SSL_version => TLSv1" --ssl-opt="SSL_verify_mode => SSL_VERIFY_NONE").
+
+=back
+
+=head1 DESCRIPTION
+
+B<custom>.
+
+=cut
diff --git a/apps/rudder/restapi/mode/globalcompliance.pm b/apps/rudder/restapi/mode/globalcompliance.pm
new file mode 100644
index 000000000..4b30e2012
--- /dev/null
+++ b/apps/rudder/restapi/mode/globalcompliance.pm
@@ -0,0 +1,166 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::rudder::restapi::mode::globalcompliance;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold);
+
+sub custom_status_perfdata {
+    my ($self, %options) = @_;
+    
+    my $extra_label = '';
+    if (!defined($options{extra_instance}) || $options{extra_instance} != 0) {
+        $extra_label .= '_' . $self->{result_values}->{detail};
+    }
+    
+    $self->{output}->perfdata_add(label => 'value' . $extra_label,
+                                  value => $self->{result_values}->{value},
+                                  min => 0, max => 100, unit => '%');
+}
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+
+    return sprintf("value is '%.2f%%'", $self->{result_values}->{value});
+}
+
+sub custom_status_calc {
+    my ($self, %options) = @_;
+
+    $self->{result_values}->{detail} = $options{new_datas}->{$self->{instance} . '_detail'};
+    $self->{result_values}->{value} = $options{new_datas}->{$self->{instance} . '_value'};
+
+    return 0;
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'global', type => 0 },
+        { name => 'compliances', type => 1, cb_prefix_output => 'prefix_compliances_output',
+            message_multiple => 'All detailed compliances are ok' },
+    ];
+
+    $self->{maps_counters}->{global} = [
+        { label => 'global-compliance', set => {
+                key_values => [ { name => 'compliance' } ],
+                output_template => 'Global Compliance: %.2f%%',
+                perfdatas => [
+                    { label => 'global_compliance', value => 'compliance_absolute', template => '%.2f',
+                      min => 0, max => 100, unit => '%' },
+                ],
+            }
+        },
+    ];
+    $self->{maps_counters}->{compliances} = [
+        { label => 'status', set => {
+                key_values => [ { name => 'value' }, { name => 'detail' } ],
+                closure_custom_calc => $self->can('custom_status_calc'),
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => $self->can('custom_status_perfdata'),
+                closure_custom_threshold_check => \&catalog_status_threshold,
+            }
+        },
+    ];
+}
+
+sub prefix_compliances_output {
+    my ($self, %options) = @_;
+
+    return "Compliance Detail '" . $options{instance_value}->{detail} . "' ";
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments => {
+        "warning-status:s"      => { name => 'warning_status', default => '' },
+        "critical-status:s"     => { name => 'critical_status', default => '' },
+    });
+   
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->change_macros(macros => ['warning_status', 'critical_status']);
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    $self->{compliances} = {};
+
+    my $results = $options{custom}->request_api(url_path => '/compliance');
+
+    $self->{global}->{compliance} = $results->{globalCompliance}->{compliance};
+    
+    foreach my $detail (keys %{$results->{globalCompliance}->{complianceDetails}}) {
+        $self->{compliances}->{$detail} = {
+            detail => $detail,
+            value => $results->{globalCompliance}->{complianceDetails}->{$detail},
+        }            
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check global compliance and compliance details.
+
+=over 8
+
+=item B<--warning-global-compliance>
+
+Set warning threshold on global compliance.
+
+=item B<--critical-global-compliance>
+
+Set critical threshold on global compliance.
+
+=item B<--warning-status>
+
+Set warning threshold for status (Default: '').
+Can used special variables like: %{detail}, %{value}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '').
+Can used special variables like: %{detail}, %{value}
+
+Example :
+  --critical-status='%{detail} eq "error" && %{value} > 5'
+
+=back
+
+=cut
diff --git a/apps/rudder/restapi/mode/listnodes.pm b/apps/rudder/restapi/mode/listnodes.pm
new file mode 100644
index 000000000..3eeb47809
--- /dev/null
+++ b/apps/rudder/restapi/mode/listnodes.pm
@@ -0,0 +1,146 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::rudder::restapi::mode::listnodes;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments => {
+        "filter-name:s" => { name => 'filter_name' },
+    });
+   
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $results = $options{custom}->request_api(url_path => '/nodes');
+    
+    foreach my $node (@{$results->{nodes}}) {
+        if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
+            $node->{hostname} !~ /$self->{option_results}->{filter_name}/) {
+            $self->{output}->output_add(long_msg => "skipping '" . $node->{hostname} . "': no matching filter name.", debug => 1);
+            next;
+        }
+
+        $self->{nodes}->{$node->{id}} = {
+            name => $node->{hostname},
+            type => $node->{machine}->{type},
+            os => $node->{os}->{name},
+            version => $node->{os}->{version},
+            status => $node->{status},
+            id => $node->{id},
+        }            
+    }
+
+    $results = $options{custom}->request_api(url_path => '/nodes/pending');
+    
+    foreach my $node (@{$results->{nodes}}) {
+        if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
+            $node->{hostname} !~ /$self->{option_results}->{filter_name}/) {
+            $self->{output}->output_add(long_msg => "skipping '" . $node->{hostname} . "': no matching filter name.", debug => 1);
+            next;
+        }
+
+        $self->{nodes}->{$node->{id}} = {
+            name => $node->{hostname},
+            type => $node->{machine}->{type},
+            os => $node->{os}->{name},
+            version => $node->{os}->{version},
+            status => $node->{status},
+            id => $node->{id},
+        }            
+    }
+}
+
+sub run {
+    my ($self, %options) = @_;
+  
+    $self->manage_selection(%options);
+    foreach my $node (sort keys %{$self->{nodes}}) { 
+        $self->{output}->output_add(long_msg => sprintf("[name = %s] [type = %s] [os = %s] [version = %s] [status = %s] [id = %s]",
+                                                         $self->{nodes}->{$node}->{name},
+                                                         $self->{nodes}->{$node}->{type},
+                                                         $self->{nodes}->{$node}->{os},
+                                                         $self->{nodes}->{$node}->{version},
+                                                         $self->{nodes}->{$node}->{status},
+                                                         $self->{nodes}->{$node}->{id}));
+    }
+    
+    $self->{output}->output_add(severity => 'OK',
+                                short_msg => 'List nodes:');
+    $self->{output}->display(nolabel => 1, force_ignore_perfdata => 1, force_long_output => 1);
+    $self->{output}->exit();
+}
+
+sub disco_format {
+    my ($self, %options) = @_;  
+    
+    $self->{output}->add_disco_format(elements => ['name', 'type', 'os', 'version', 'id']);
+}
+
+sub disco_show {
+    my ($self, %options) = @_;
+
+    $self->manage_selection(%options);
+    foreach my $node (sort keys %{$self->{nodes}}) {             
+        $self->{output}->add_disco_entry(
+            name => $self->{nodes}->{$node}->{name},
+            type => $self->{nodes}->{$node}->{type},
+            os => $self->{nodes}->{$node}->{os},
+            version => $self->{nodes}->{$node}->{version},
+            status => $self->{nodes}->{$node}->{status},
+            id => $self->{nodes}->{$node}->{id},
+        );
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+List nodes.
+
+=over 8
+
+=item B<--filter-name>
+
+Filter node name (can be a regexp).
+
+=back
+
+=cut
diff --git a/apps/rudder/restapi/plugin.pm b/apps/rudder/restapi/plugin.pm
new file mode 100644
index 000000000..184ce1f31
--- /dev/null
+++ b/apps/rudder/restapi/plugin.pm
@@ -0,0 +1,56 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package apps::rudder::restapi::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+
+    $self->{version} = '0.1';
+    %{$self->{modes}} = (
+        'global-compliance' => 'apps::rudder::restapi::mode::globalcompliance',
+        'list-nodes'        => 'apps::rudder::restapi::mode::listnodes',
+    );
+
+    $self->{custom_modes}{api} = 'apps::rudder::restapi::custom::api';
+    return $self;
+}
+
+sub init {
+    my ( $self, %options ) = @_;
+
+    $self->SUPER::init(%options);
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check Rudder.
+
+=cut