diff --git a/cloud/azure/custom/api.pm b/cloud/azure/custom/api.pm
index 997261c3d..4f0770998 100644
--- a/cloud/azure/custom/api.pm
+++ b/cloud/azure/custom/api.pm
@@ -474,6 +474,26 @@ sub azure_list_backup_items {
     return $response->{value};
 }
 
+sub azure_list_expressroute_circuits_set_url {
+    my ($self, %options) = @_;
+
+    my $url = $self->{management_endpoint} . "/subscriptions/" . $self->{subscription};
+    $url .= "/resourceGroups/" . $options{resource_group} if (defined($options{resource_group}) && $options{resource_group} ne '');
+    $url .= "/providers/Microsoft.Network/expressRouteCircuits?api-version=" . $self->{api_version};
+    
+    return $url; 
+}
+
+sub azure_list_expressroute_circuits {
+    my ($self, %options) = @_;
+    
+    my $results = {};
+    my $full_url = $self->azure_list_expressroute_circuits_set_url(%options);
+    my $response = $self->request_api(method => 'GET', full_url => $full_url, hostname => '');
+    
+    return $response->{value};
+}
+
 1;
 
 __END__
diff --git a/cloud/azure/custom/azcli.pm b/cloud/azure/custom/azcli.pm
index 82fb1af45..24f24f5a3 100644
--- a/cloud/azure/custom/azcli.pm
+++ b/cloud/azure/custom/azcli.pm
@@ -536,6 +536,47 @@ sub azure_list_backup_items {
     return $raw_results;
 }
 
+sub azure_list_expressroute_circuits_set_cmd {
+    my ($self, %options) = @_;
+
+    return if (defined($self->{option_results}->{command_options}) && $self->{option_results}->{command_options} ne '');
+        
+    my $cmd_options = "network express-route list --output json";
+    $cmd_options .= " --resource-group '$options{resource_group}'" if (defined($options{resource_group}) && $options{resource_group} ne '');
+    $cmd_options .= " --subscription '$self->{subscription}'" if (defined($self->{subscription}) && $self->{subscription} ne '');
+    
+    return $cmd_options; 
+}
+
+sub azure_list_expressroute_circuits {
+    my ($self, %options) = @_;
+    
+    my $results = {};
+
+    my $cmd_options = $self->azure_list_expressroute_circuits_set_cmd(%options);
+    
+    my ($response) = centreon::plugins::misc::execute(
+        output => $self->{output},
+        options => $self->{option_results},
+        sudo => $self->{option_results}->{sudo},
+        command => $self->{option_results}->{command},
+        command_path => $self->{option_results}->{command_path},
+        command_options => $cmd_options);
+
+    my $raw_results;
+    my $command_line = $self->{option_results}->{command} . " " . $cmd_options;
+    
+    eval {
+        $raw_results = JSON::XS->new->utf8->decode($response);
+    };
+    if ($@) {
+        $self->{output}->add_option_msg(short_msg => "Cannot decode json response: $@");
+        $self->{output}->option_exit();
+    }
+    
+    return $raw_results;
+}
+
 1;
 
 __END__
diff --git a/cloud/azure/network/expressroute/mode/circuitstatus.pm b/cloud/azure/network/expressroute/mode/circuitstatus.pm
new file mode 100644
index 000000000..c5b2355d1
--- /dev/null
+++ b/cloud/azure/network/expressroute/mode/circuitstatus.pm
@@ -0,0 +1,166 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package cloud::azure::network::expressroute::mode::circuitstatus;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold);
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+    
+    my $msg = sprintf("Status '%s', Provider Status '%s' [Name: %s] [Location: %s]",
+        $self->{result_values}->{circuit_status},
+        $self->{result_values}->{provider_status},
+        $self->{result_values}->{provider_name},
+        $self->{result_values}->{provider_location});
+    return $msg;
+}
+
+sub custom_status_calc {
+    my ($self, %options) = @_;
+    
+    $self->{result_values}->{circuit_status} = $options{new_datas}->{$self->{instance} . '_circuit_status'};
+    $self->{result_values}->{provider_status} = $options{new_datas}->{$self->{instance} . '_provider_status'};
+    $self->{result_values}->{provider_name} = $options{new_datas}->{$self->{instance} . '_provider_name'};
+    $self->{result_values}->{provider_location} = $options{new_datas}->{$self->{instance} . '_provider_location'};
+    $self->{result_values}->{display} = $options{new_datas}->{$self->{instance} . '_display'};
+    return 0;
+}
+
+sub prefix_circuit_output {
+    my ($self, %options) = @_;
+    
+    return "Circuit '" . $options{instance_value}->{display} . "' ";
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'circuits', type => 1, cb_prefix_output => 'prefix_circuit_output', message_multiple => 'All circuits are ok' },
+    ];
+
+    $self->{maps_counters}->{circuits} = [
+        { label => 'status', threshold => 0, set => {
+                key_values => [ { name => 'circuit_status' }, { name => 'provider_status' }, { name => 'provider_name' },
+                                { name => 'provider_location' }, { name => 'display' } ],
+                closure_custom_calc => $self->can('custom_status_calc'),
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => \&catalog_status_threshold,
+            }
+        },
+    ];
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments =>
+                                {
+                                    "resource-group:s"      => { name => 'resource_group' },
+                                    "location:s"            => { name => 'location' },
+                                    "filter-name:s"         => { name => 'filter_name' },
+                                    "warning-status:s"      => { name => 'warning_status', default => '' },
+                                    "critical-status:s"     => { name => 'critical_status', default => '%{circuit_status} ne "Enabled" || %{provider_status} ne "Provisioned"' },
+                                });
+    
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->change_macros(macros => ['warning_status', 'critical_status']);
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    $self->{circuits} = {};
+    my $circuits = $options{custom}->azure_list_expressroute_circuits(resource_group => $self->{option_results}->{resource_group});
+    foreach my $circuit (@{$circuits}) {
+        next if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne ''
+            && $circuit->{properties}->{entityFriendlyName} !~ /$self->{option_results}->{filter_name}/);
+        next if (defined($self->{option_results}->{location}) && $self->{option_results}->{location} ne ''
+            && $circuit->{location} !~ /$self->{option_results}->{location}/);
+        
+        $self->{circuits}->{$circuit->{id}} = {
+            display => $circuit->{name},
+            circuit_status => ($circuit->{circuitProvisioningState}) ? $circuit->{circuitProvisioningState} : $circuit->{properties}->{circuitProvisioningState},
+            provider_status => ($circuit->{serviceProviderProvisioningState}) ? $circuit->{serviceProviderProvisioningState} : $circuit->{properties}->{serviceProviderProvisioningState},
+            provider_name => ($circuit->{serviceProviderProperties}->{serviceProviderName}) ? $circuit->{serviceProviderProperties}->{serviceProviderName} : $circuit->{properties}->{serviceProviderProperties}->{serviceProviderName},
+            provider_location => ($circuit->{serviceProviderProperties}->{peeringLocation}) ? $circuit->{serviceProviderProperties}->{peeringLocation} : $circuit->{properties}->{serviceProviderProperties}->{peeringLocation},
+        };
+    }
+    
+    if (scalar(keys %{$self->{circuits}}) <= 0) {
+        $self->{output}->add_option_msg(short_msg => "No ExpressRoute circuits found.");
+        $self->{output}->option_exit();
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check ExpressRoute circuits status.
+
+Example: 
+perl centreon_plugins.pl --plugin=cloud::azure::network::expressroute::plugin --custommode=azcli --mode=circuit-status
+--resource-group='MYRESOURCEGROUP' --verbose
+
+=over 8
+
+=item B<--resource-group>
+
+Set resource group.
+
+=item B<--location>
+
+Set resource location.
+
+=item B<--filter-name>
+
+Filter circuit name (Can be a regexp).
+
+=item B<--warning-status>
+
+Set warning threshold for status (Default: '').
+Can used special variables like: %{circuit_status}, %{provider_status}, %{display}
+
+=item B<--critical-status>
+
+Set critical threshold for status (Default: '%{circuit_status} ne "Enabled" || %{provider_status} ne "Provisioned"').
+Can used special variables like: %{circuit_status}, %{provider_status}, %{display}
+
+=back
+
+=cut
diff --git a/cloud/azure/network/expressroute/mode/listcircuits.pm b/cloud/azure/network/expressroute/mode/listcircuits.pm
new file mode 100644
index 000000000..80682e05d
--- /dev/null
+++ b/cloud/azure/network/expressroute/mode/listcircuits.pm
@@ -0,0 +1,144 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package cloud::azure::network::expressroute::mode::listcircuits;
+
+use base qw(centreon::plugins::mode);
+
+use strict;
+use warnings;
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments =>
+                                {
+                                    "resource-group:s"      => { name => 'resource_group' },
+                                    "location:s"            => { name => 'location' },
+                                    "filter-name:s"         => { name => 'filter_name' },
+                                });
+
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::init(%options);
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    $self->{circuits} = $options{custom}->azure_list_expressroute_circuits(
+        resource_group => $self->{option_results}->{resource_group}
+    );
+}
+
+sub run {
+    my ($self, %options) = @_;
+
+    $self->manage_selection(%options);
+    foreach my $circuit (@{$self->{circuits}}) {
+        next if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne ''
+            && $circuit->{name} !~ /$self->{option_results}->{filter_name}/);
+        next if (defined($self->{option_results}->{location}) && $self->{option_results}->{location} ne ''
+            && $circuit->{location} !~ /$self->{option_results}->{location}/);
+        my $resource_group = '-';
+        $resource_group = $circuit->{resourceGroup} if (defined($circuit->{resourceGroup}));
+        $resource_group = $1 if ($resource_group eq '-' && defined($circuit->{id}) && $circuit->{id} =~ /resourceGroups\/(.*)\/providers/);
+        
+        my @tags;
+        foreach my $tag (keys %{$circuit->{tags}}) {
+            push @tags, $tag . ':' . $circuit->{tags}->{$tag};
+        }
+
+        $self->{output}->output_add(long_msg => sprintf("[name = %s][resourcegroup = %s][location = %s][id = %s][tags = %s]",
+            $circuit->{name},
+            $resource_group,
+            $circuit->{location},
+            $circuit->{id},
+            join(',', @tags),
+        ));
+    }
+    
+    $self->{output}->output_add(severity => 'OK',
+                                short_msg => 'List network interfaces:');
+    $self->{output}->display(nolabel => 1, force_ignore_perfdata => 1, force_long_output => 1);
+    $self->{output}->exit();
+}
+
+sub disco_format {
+    my ($self, %options) = @_;
+    
+    $self->{output}->add_disco_format(elements => ['name', 'resourcegroup', 'location', 'id', 'tags']);
+}
+
+sub disco_show {
+    my ($self, %options) = @_;
+
+    $self->manage_selection(%options);
+    foreach my $circuit (@{$self->{circuits}}) {
+        my $resource_group = '-';
+        $resource_group = $circuit->{resourceGroup} if (defined($circuit->{resourceGroup}));
+        $resource_group = $1 if ($resource_group eq '-' && defined($circuit->{id}) && $circuit->{id} =~ /resourceGroups\/(.*)\/providers/);
+        
+        my @tags;
+        foreach my $tag (keys %{$circuit->{tags}}) {
+            push @tags, $tag . ':' . $circuit->{tags}->{$tag};
+        }
+
+        $self->{output}->add_disco_entry(
+            name => $circuit->{name},
+            resourcegroup => $resource_group,
+            location => $circuit->{location},
+            id => $circuit->{id},
+            tags => join(',', @tags),
+        );
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+List ExpressRoute circuits.
+
+=over 8
+
+=item B<--resource-group>
+
+Set resource group.
+
+=item B<--location>
+
+Set resource location.
+
+=item B<--filter-name>
+
+Filter resource name (Can be a regexp).
+
+=back
+
+=cut
diff --git a/cloud/azure/network/expressroute/mode/traffic.pm b/cloud/azure/network/expressroute/mode/traffic.pm
new file mode 100644
index 000000000..502cb1d18
--- /dev/null
+++ b/cloud/azure/network/expressroute/mode/traffic.pm
@@ -0,0 +1,254 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package cloud::azure::network::expressroute::mode::traffic;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+
+my $instance_mode;
+
+sub prefix_traffic_output {
+    my ($self, %options) = @_;
+    
+    return "Circuit '" . $options{instance_value}->{display} . "' " . $options{instance_value}->{stat} . " ";
+}
+
+sub custom_traffic_calc {
+    my ($self, %options) = @_;
+    
+    $self->{result_values}->{stat} = $options{new_datas}->{$self->{instance} . '_stat'};
+    $self->{result_values}->{metric_perf} = lc($options{extra_options}->{metric_perf});
+    $self->{result_values}->{metric_label} = lc($options{extra_options}->{metric_label});
+    $self->{result_values}->{metric_name} = $options{extra_options}->{metric_name};
+    $self->{result_values}->{timeframe} = $options{new_datas}->{$self->{instance} . '_timeframe'};
+    $self->{result_values}->{value} = $options{new_datas}->{$self->{instance} . '_' . $self->{result_values}->{metric_perf} . '_' . $self->{result_values}->{stat}};
+    $self->{result_values}->{display} = $options{new_datas}->{$self->{instance} . '_display'};
+    return 0;
+}
+
+sub custom_metric_threshold {
+    my ($self, %options) = @_;
+
+    my $exit = $self->{perfdata}->threshold_check(value => $self->{result_values}->{value},
+                                                  threshold => [ { label => 'critical-' . $self->{result_values}->{metric_label} . "-" . $self->{result_values}->{stat}, exit_litteral => 'critical' },
+                                                                 { label => 'warning-' . $self->{result_values}->{metric_label} . "-" . $self->{result_values}->{stat}, exit_litteral => 'warning' } ]);
+    return $exit;
+}
+
+sub custom_traffic_perfdata {
+    my ($self, %options) = @_;
+
+    my $extra_label = '';
+    $extra_label = '_' . lc($self->{result_values}->{display}) if (!defined($options{extra_instance}) || $options{extra_instance} != 0);
+
+    $self->{output}->perfdata_add(label => $self->{result_values}->{metric_perf} . "_" . $self->{result_values}->{stat} . $extra_label,
+				                  unit => 'b/s',
+                                  value => sprintf("%d", $self->{result_values}->{value}),
+                                  warning => $self->{perfdata}->get_perfdata_for_output(label => 'warning-' . $self->{result_values}->{metric_label} . "-" . $self->{result_values}->{stat}),
+                                  critical => $self->{perfdata}->get_perfdata_for_output(label => 'critical-' . $self->{result_values}->{metric_label} . "-" . $self->{result_values}->{stat}),
+                                  min => 0
+                                 );
+}
+
+sub custom_traffic_output {
+    my ($self, %options) = @_;
+
+    my ($value, $unit) = $self->{perfdata}->change_bytes(value => $self->{result_values}->{value}, network => 1);
+    my $msg = $self->{result_values}->{metric_name}  . ": " . $value . $unit . "/s";
+    return $msg;
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+    
+    $self->{maps_counters_type} = [
+        { name => 'metric', type => 1, cb_prefix_output => 'prefix_traffic_output', message_multiple => "All traffic metrics are ok", skipped_code => { -10 => 1 } },
+    ];
+
+    foreach my $aggregation ('minimum', 'maximum', 'average', 'total') {
+        foreach my $metric ('BitsInPerSecond', 'BitsOutPerSecond') {
+            my $metric_perf = lc($metric);
+            my $metric_label = lc($metric);
+            $metric_perf =~ s/ /_/g;
+            $metric_label =~ s/ /-/g;
+            my $entry = { label => $metric_label . '-' . $aggregation, set => {
+                                key_values => [ { name => $metric_perf . '_' . $aggregation }, { name => 'display' },
+                                    { name => 'stat' }, { name => 'timeframe' } ],
+                                closure_custom_calc => $self->can('custom_traffic_calc'),
+                                closure_custom_calc_extra_options => { metric_perf => $metric_perf,
+                                    metric_label => $metric_label, metric_name => $metric },
+                                closure_custom_output => $self->can('custom_traffic_output'),
+                                closure_custom_perfdata => $self->can('custom_traffic_perfdata'),
+                                closure_custom_threshold_check => $self->can('custom_traffic_threshold'),
+                            }
+                        };
+            push @{$self->{maps_counters}->{metric}}, $entry;
+        }
+    }
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options);
+    bless $self, $class;
+    
+    $self->{version} = '1.0';
+    $options{options}->add_options(arguments =>
+                                {
+                                    "resource:s@"           => { name => 'resource' },
+                                    "resource-group:s"      => { name => 'resource_group' },
+                                    "filter-metric:s"       => { name => 'filter_metric' },
+                                });
+    
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    if (!defined($self->{option_results}->{resource})) {
+        $self->{output}->add_option_msg(short_msg => "Need to specify either --resource <name> with --resource-group option or --resource <id>.");
+        $self->{output}->option_exit();
+    }
+    
+    $self->{az_resource} = $self->{option_results}->{resource};
+    $self->{az_resource_group} = $self->{option_results}->{resource_group} if (defined($self->{option_results}->{resource_group}));
+    $self->{az_resource_type} = 'expressRouteCircuits';
+    $self->{az_resource_namespace} = 'Microsoft.Network';
+    $self->{az_timeframe} = defined($self->{option_results}->{timeframe}) ? $self->{option_results}->{timeframe} : 900;
+    $self->{az_interval} = defined($self->{option_results}->{interval}) ? $self->{option_results}->{interval} : "PT5M";
+    $self->{az_aggregations} = ['Average'];
+    if (defined($self->{option_results}->{aggregation})) {
+        $self->{az_aggregations} = [];
+        foreach my $stat (@{$self->{option_results}->{aggregation}}) {
+            if ($stat ne '') {
+                push @{$self->{az_aggregations}}, ucfirst(lc($stat));
+            }
+        }
+    }
+
+    foreach my $metric ('BitsInPerSecond', 'BitsOutPerSecond') {
+        next if (defined($self->{option_results}->{filter_metric}) && $self->{option_results}->{filter_metric} ne ''
+            && $metric !~ /$self->{option_results}->{filter_metric}/);
+
+        push @{$self->{az_metrics}}, $metric;
+    }
+
+    $instance_mode = $self;
+}
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my %metric_results;
+    foreach my $resource (@{$self->{az_resource}}) {
+        my $resource_group = $self->{az_resource_group};
+        my $resource_name = $resource;
+        if ($resource =~ /^\/subscriptions\/.*\/resourceGroups\/(.*)\/providers\/Microsoft\.Network\/expressRouteCircuits\/(.*)$/) {
+            $resource_group = $1;
+            $resource_name = $2;
+        }
+
+        ($metric_results{$resource_name}, undef, undef) = $options{custom}->azure_get_metrics(
+            resource => $resource_name,
+            resource_group => $resource_group,
+            resource_type => $self->{az_resource_type},
+            resource_namespace => $self->{az_resource_namespace},
+            metrics => $self->{az_metrics},
+            aggregations => $self->{az_aggregations},
+            timeframe => $self->{az_timeframe},
+            interval => $self->{az_interval},
+        );
+        
+        foreach my $metric (@{$self->{az_metrics}}) {
+            my $metric_name = lc($metric);
+            $metric_name =~ s/ /_/g;
+            foreach my $aggregation (@{$self->{az_aggregations}}) {
+                next if (!defined($metric_results{$resource_name}->{$metric_name}->{lc($aggregation)}) && !defined($self->{option_results}->{zeroed}));
+
+                $self->{metric}->{$resource_name . "_" . lc($aggregation)}->{display} = $resource_name;
+                $self->{metric}->{$resource_name . "_" . lc($aggregation)}->{timeframe} = $self->{az_timeframe};
+                $self->{metric}->{$resource_name . "_" . lc($aggregation)}->{stat} = lc($aggregation);
+                $self->{metric}->{$resource_name . "_" . lc($aggregation)}->{$metric_name . "_" . lc($aggregation)} = defined($metric_results{$resource_name}->{$metric_name}->{lc($aggregation)}) ? $metric_results{$resource_name}->{$metric_name}->{lc($aggregation)} : 0;
+            }
+        }
+    }
+
+    if (scalar(keys %{$self->{metric}}) <= 0) {
+        $self->{output}->add_option_msg(short_msg => 'No metrics. Check your options or use --zeroed option to set 0 on undefined values');
+        $self->{output}->option_exit();
+    }
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check circuit traffic metrics.
+
+Example:
+
+Using resource name :
+
+perl centreon_plugins.pl --plugin=cloud::azure::network::expressroute::plugin --custommode=azcli --mode=traffic
+--resource=MYCIRCUIT --resource-group=MYHOSTGROUP --aggregation='average' --critical-bitsinpersecond-average='10'
+--verbose
+
+Using resource id :
+
+perl centreon_plugins.pl --plugin=cloud::azure::network::expressroute::plugin --custommode=azcli --mode=traffic
+--resource='/subscriptions/xxx/resourceGroups/xxx/providers/Microsoft.Network/expressRouteCircuits/xxx'
+--aggregation='average' --critical-bitsinpersecond-average='10' --verbose
+
+Default aggregation: 'average' / 'average', 'minimum' and 'maximum' are valid.
+
+=over 8
+
+=item B<--resource>
+
+Set resource name or id (Required).
+
+=item B<--resource-group>
+
+Set resource group (Required if resource's name is used).
+
+=item B<--filter-metric>
+
+Filter metrics (Can be: 'BitsInPerSecond', 'BitsOutPerSecond') (Can be a regexp).
+
+=item B<--warning-$metric$-$aggregation$>
+
+Thresholds warning ($metric$ can be: 'bitsinpersecond', 'bitsoutpersecond',
+$aggregation$ can be: 'minimum', 'maximum', 'average').
+
+=item B<--critical-$metric$-$aggregation$>
+
+Thresholds critical ($metric$ can be: 'bitsinpersecond', 'bitsoutpersecond',
+$aggregation$ can be: 'minimum', 'maximum', 'average').
+
+=back
+
+=cut
diff --git a/cloud/azure/network/expressroute/plugin.pm b/cloud/azure/network/expressroute/plugin.pm
new file mode 100644
index 000000000..1a7d2f3bd
--- /dev/null
+++ b/cloud/azure/network/expressroute/plugin.pm
@@ -0,0 +1,63 @@
+#
+# Copyright 2019 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package cloud::azure::network::expressroute::plugin;
+
+use strict;
+use warnings;
+use base qw(centreon::plugins::script_custom);
+
+sub new {
+    my ( $class, %options ) = @_;
+    my $self = $class->SUPER::new( package => __PACKAGE__, %options );
+    bless $self, $class;
+
+    $self->{version} = '0.1';
+    %{ $self->{modes} } = (
+        'circuit-status'            => 'cloud::azure::network::expressroute::mode::circuitstatus',
+        'list-circuits'             => 'cloud::azure::network::expressroute::mode::listcircuits',
+        'traffic'                   => 'cloud::azure::network::expressroute::mode::traffic',
+    );
+
+    $self->{custom_modes}{azcli} = 'cloud::azure::custom::azcli';
+    $self->{custom_modes}{api} = 'cloud::azure::custom::api';
+    return $self;
+}
+
+sub init {
+    my ($self, %options) = @_;
+
+    $self->{options}->add_options(arguments =>
+                                    {
+                                        'api-version:s'  => { name => 'api_version', default => '2018-01-01' },
+                                    });
+
+    $self->SUPER::init(%options);
+}
+
+1;
+
+__END__
+
+=head1 PLUGIN DESCRIPTION
+
+Check Microsoft Azure ExpressRoute.
+
+=cut