add mode for avocent acs 8000

hardware/kvm/avocent/acs/8000/snmp/mode/serialports.pm

@@ -0,0 +1,196 @@
+#
+# Copyright 2020 Centreon (http://www.centreon.com/)
+#
+# Centreon is a full-fledged industry-strength solution that meets
+# the needs in IT infrastructure and application monitoring for
+# service performance.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+
+package hardware::kvm::avocent::acs::8000::snmp::mode::serialports;
+
+use base qw(centreon::plugins::templates::counter);
+
+use strict;
+use warnings;
+use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold catalog_status_calc);
+use Digest::MD5 qw(md5_hex);
+
+sub custom_status_output {
+    my ($self, %options) = @_;
+
+    return sprintf(
+        'status: %s',
+        $self->{result_values}->{status}
+    );
+}
+
+sub set_counters {
+    my ($self, %options) = @_;
+
+    $self->{maps_counters_type} = [
+        { name => 'serials', type => 1, cb_prefix_output => 'prefix_serial_output', message_multiple => 'All serial ports are ok' }
+    ];
+
+    $self->{maps_counters}->{serials} = [
+        { label => 'status', threshold => 0, set => {
+                key_values => [ { name => 'status' }, { name => 'display' } ],
+                closure_custom_calc => \&catalog_status_calc,
+                closure_custom_output => $self->can('custom_status_output'),
+                closure_custom_perfdata => sub { return 0; },
+                closure_custom_threshold_check => \&catalog_status_threshold
+            }
+        },
+        { label => 'traffic-in', nlabel => 'serialport.traffic.in.bitspersecond', set => {
+                key_values => [ { name => 'traffic_in', diff => 1 }, { name => 'display' } ],
+                output_template => 'traffic in: %s%s/s',
+                per_second => 1, output_change_bytes => 2,
+                perfdatas => [
+                    { value => 'traffic_in_per_second', template => '%s',
+                      min => 0, unit => 'b/s', label_extra_instance => 1, instance_use => 'display_absolute' }
+                ]
+            }
+        },
+        { label => 'traffic-out', nlabel => 'serialport.traffic.out.bitspersecond', set => {
+                key_values => [ { name => 'traffic_out', diff => 1 }, { name => 'display' } ],
+                output_template => 'traffic out: %s%s/s',
+                per_second => 1, output_change_bytes => 2,
+                perfdatas => [
+                    { value => 'traffic_out_per_second', template => '%s',
+                      min => 0, unit => 'b/s', label_extra_instance => 1, instance_use => 'display_absolute' }
+                ]
+            }
+        }
+    ];
+}
+
+sub prefix_serial_output {
+    my ($self, %options) = @_;
+
+    return "Serial port '" . $options{instance_value}->{display} . "' ";
+}
+
+sub new {
+    my ($class, %options) = @_;
+    my $self = $class->SUPER::new(package => __PACKAGE__, %options, statefile => 1, force_new_perfdata => 1);
+    bless $self, $class;
+
+    $options{options}->add_options(arguments => {
+        'filter-name:s'     => { name => 'filter_name' },
+        'unknown-status:s'  => { name => 'unknown_status', default => '' },
+        'warning-status:s'  => { name => 'warning_status', default => '' },
+        'critical-status:s' => { name => 'critical_status', default => '' }
+    });
+
+    return $self;
+}
+
+sub check_options {
+    my ($self, %options) = @_;
+    $self->SUPER::check_options(%options);
+
+    $self->change_macros(
+        macros => [
+            'unknown_status', 'warning_status', 'critical_status'
+        ]
+    );
+}
+
+my $map_status = { 1 => 'disabled', 2 => 'idle', 3 => 'inUse' };
+
+my $mapping = {
+    status      => { oid => '.1.3.6.1.4.1.10418.26.2.3.2.1.3', map => $map_status }, # acsSerialPortTableStatus
+    traffic_out => { oid => '.1.3.6.1.4.1.10418.26.2.3.2.1.16' }, # acsSerialPortTableTxBytes
+    traffic_in  => { oid => '.1.3.6.1.4.1.10418.26.2.3.2.1.17' } # acsSerialPortTableRxBytes
+};
+
+sub manage_selection {
+    my ($self, %options) = @_;
+
+    my $oid_acsSerialPortTableDeviceName = '.1.3.6.1.4.1.10418.26.2.3.2.1.2';
+    my $snmp_result = $options{snmp}->get_table(
+        oid => $oid_acsSerialPortTableDeviceName,
+        nothing_quit => 1
+    );
+
+    $self->{serials} = {};
+    foreach (keys %$snmp_result) {
+        /\.(\d+)$/;
+        my $instance = $1;
+        my $name = $snmp_result->{$_};
+
+        if (defined($self->{option_results}->{filter_name}) && $self->{option_results}->{filter_name} ne '' &&
+            $name !~ /$self->{option_results}->{filter_name}/) {
+            $self->{output}->output_add(long_msg => "skipping port '" . $name . "'.", debug => 1);
+            next;
+        }
+
+        $self->{serials}->{$instance} = { display => $name };
+    }
+
+    return if (scalar(keys %{$self->{serials}}) <= 0);
+
+    $options{snmp}->load(
+        oids => [ map($_->{oid}, values(%$mapping)) ],
+        instances => [ keys %{$self->{serials}} ],
+        instance_regexp => '^(.*)$'
+    );
+    $snmp_result = $options{snmp}->get_leef();
+    foreach (keys %{$self->{serials}}) {
+        my $result = $options{snmp}->map_instance(mapping => $mapping, results => $snmp_result, instance => $_);
+        $self->{serials}->{$_} = { %{$self->{serials}->{$_}}, %$result };
+    }
+
+    $self->{cache_name} = 'avocent_acs_8000_' . $options{snmp}->get_hostname()  . '_' . $options{snmp}->get_port() . '_' . $self->{mode} . '_' .
+        (defined($self->{option_results}->{filter_counters}) ? md5_hex($self->{option_results}->{filter_counters}) : md5_hex('all')) . '_' .
+        (defined($self->{option_results}->{filter_name}) ? md5_hex($self->{option_results}->{filter_name}) : md5_hex('all'));
+}
+
+1;
+
+__END__
+
+=head1 MODE
+
+Check serial ports.
+
+=over 8
+
+=item B<--filter-name>
+
+Filter by serial device name (can be a regexp).
+
+=item B<--unknown-status>
+
+Set unknown threshold for status.
+Can used special variables like: %{status}, %{display}
+
+=item B<--warning-status>
+
+Set warning threshold for status.
+Can used special variables like: %{status}, %{display}
+
+=item B<--critical-status>
+
+Set critical threshold for status.
+Can used special variables like: %{status}, %{display}
+
+=item B<--warning-*> B<--critical-*>
+
+Thresholds.
+Can be: 'traffic-in', 'traffic-out'.
+
+=back
+
+=cut

hardware/kvm/avocent/acs/8000/snmp/plugin.pm

@@ -35,6 +35,7 @@ sub new {
         'hardware'      => 'hardware::kvm::avocent::acs::8000::snmp::mode::hardware',
         'load'          => 'snmp_standard::mode::loadaverage',
         'memory'        => 'snmp_standard::mode::memory',
+        'serial-ports'  => 'hardware::kvm::avocent::acs::8000::snmp::mode::serialports'
     );
 
     return $self;