tyler.durden
/
centreon-plugins
mirror of https://github.com/centreon/centreon-plugins.git
1
0
Fork 0
Code Issues Packages Projects Releases Wiki Activity

(plugin) cloud::iics::restapi - new (#3870)

This commit is contained in:
qgarnier 2022-08-30 11:28:11 +02:00 committed by GitHub
parent 195d364b2a
commit ff302539f0
4 changed files with 698 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

277
centreon-plugins/cloud/iics/restapi/custom/api.pm Normal file
View File

@ -0,0 +1,277 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package cloud::iics::restapi::custom::api;
use strict;
use warnings;
use centreon::plugins::http;
use centreon::plugins::statefile;
use JSON::XS;
use Digest::MD5 qw(md5_hex);
sub new {
my ($class, %options) = @_;
my $self = {};
bless $self, $class;
if (!defined($options{output})) {
print "Class Custom: Need to specify 'output' argument.\n";
exit 3;
}
if (!defined($options{options})) {
$options{output}->add_option_msg(short_msg => "Class Custom: Need to specify 'options' argument.");
$options{output}->option_exit();
}
if (!defined($options{noptions})) {
$options{options}->add_options(arguments => {
'api-username:s' => { name => 'api_username' },
'api-password:s' => { name => 'api_password' },
'region:s' => { name => 'region' },
'port:s' => { name => 'port' },
'proto:s' => { name => 'proto' },
'timeout:s' => { name => 'timeout' },
'unknown-http-status:s' => { name => 'unknown_http_status' },
'warning-http-status:s' => { name => 'warning_http_status' },
'critical-http-status:s' => { name => 'critical_http_status' }
});
}
$options{options}->add_help(package => __PACKAGE__, sections => 'REST API OPTIONS', once => 1);
$self->{output} = $options{output};
$self->{http} = centreon::plugins::http->new(%options, default_backend => 'curl');
$self->{cache} = centreon::plugins::statefile->new(%options);
return $self;
}
sub set_options {
my ($self, %options) = @_;
$self->{option_results} = $options{option_results};
}
sub set_defaults {}
sub check_options {
my ($self, %options) = @_;
$self->{option_results}->{region} = (defined($self->{option_results}->{region}) && $self->{option_results}->{region} =~ /^eu|us|asia$/i) ? lc($self->{option_results}->{region}) : 'eu';
$self->{option_results}->{port} = (defined($self->{option_results}->{port})) ? $self->{option_results}->{port} : 443;
$self->{option_results}->{proto} = (defined($self->{option_results}->{proto})) ? $self->{option_results}->{proto} : 'https';
$self->{option_results}->{timeout} = (defined($self->{option_results}->{timeout})) ? $self->{option_results}->{timeout} : 30;
$self->{api_username} = (defined($self->{option_results}->{api_username})) ? $self->{option_results}->{api_username} : '';
$self->{api_password} = (defined($self->{option_results}->{api_password})) ? $self->{option_results}->{api_password} : '';
$self->{unknown_http_status} = (defined($self->{option_results}->{unknown_http_status})) ? $self->{option_results}->{unknown_http_status} : '%{http_code} < 200 or %{http_code} >= 300';
$self->{warning_http_status} = (defined($self->{option_results}->{warning_http_status})) ? $self->{option_results}->{warning_http_status} : '';
$self->{critical_http_status} = (defined($self->{option_results}->{critical_http_status})) ? $self->{option_results}->{critical_http_status} : '';
if ($self->{api_username} eq '') {
$self->{output}->add_option_msg(short_msg => 'Need to specify --api-username option.');
$self->{output}->option_exit();
}
if ($self->{api_password} eq '') {
$self->{output}->add_option_msg(short_msg => 'Need to specify --api-password option.');
$self->{output}->option_exit();
}
$self->{cache}->check_options(option_results => $self->{option_results});
return 0;
}
sub settings {
my ($self, %options) = @_;
return if (defined($self->{settings_done}));
$self->{http}->set_options(%{$self->{option_results}});
$self->{http}->add_header(key => 'Accept', value => 'application/json');
$self->{http}->add_header(key => 'Content-Type', value => 'application/json');
$self->{settings_done} = 1;
}
sub get_token {
my ($self, %options) = @_;
my $regions = {
asia => 'https://dm-ap.informaticacloud.com/ma/api/v2/user/login',
eu => 'https://dm-em.informaticacloud.com/ma/api/v2/user/login',
us => 'https://dm-us.informaticacloud.com/ma/api/v2/user/login'
};
my $has_cache_file = $self->{cache}->read(statefile => 'iics_' . md5_hex($self->{option_results}->{region} . '_' . $self->{api_username}));
my $token = $self->{cache}->get(name => 'token');
my $url = $self->{cache}->get(name => 'url');
my $md5_secret_cache = $self->{cache}->get(name => 'md5_secret');
my $md5_secret = md5_hex($self->{api_username} . $self->{api_password});
if ($has_cache_file == 0 ||
!defined($token) ||
(defined($md5_secret_cache) && $md5_secret_cache ne $md5_secret)
) {
my $json_request = {
'@type' => 'login',
username => $self->{api_username},
password => $self->{api_password}
};
my $encoded;
eval {
$encoded = encode_json($json_request);
};
if ($@) {
$self->{output}->add_option_msg(short_msg => 'cannot encode json request');
$self->{output}->option_exit();
}
$self->settings();
my $content = $self->{http}->request(
method => 'POST',
hostname => '',
full_url => $regions->{ $self->{option_results}->{region} },
query_form_post => $encoded,
unknown_status => $self->{unknown_http_status},
warning_status => $self->{warning_http_status},
critical_status => $self->{critical_http_status}
);
my $decoded;
eval {
$decoded = JSON::XS->new->utf8->decode($content);
};
if ($@) {
$self->{output}->add_option_msg(short_msg => "Cannot decode json response");
$self->{output}->option_exit();
}
if (!defined($decoded->{icSessionId})) {
$self->{output}->add_option_msg(short_msg => 'Cannot get token');
$self->{output}->option_exit();
}
$token = $decoded->{icSessionId};
$url = $decoded->{serverUrl};
my $datas = {
updated => time(),
token => $token,
url => $url,
md5_secret => $md5_secret
};
$self->{cache}->write(data => $datas);
}
return ($token, $url);
}
sub clean_token {
my ($self, %options) = @_;
my $datas = { updated => time() };
$self->{cache}->write(data => $datas);
}
sub request_api {
my ($self, %options) = @_;
$self->settings();
my ($token, $url) = $self->get_token();
my ($content) = $self->{http}->request(
hostname => '',
full_url => $url . $options{endpoint},
get_param => $options{get_param},
header => ['icSessionId: ' . $token]
);
# Maybe token is invalid. so we retry
if ($self->{http}->get_code() < 200 || $self->{http}->get_code() >= 300) {
$self->clean_token();
($token, $url) = $self->get_token();
$content = $self->{http}->request(
hostname => '',
full_url => $url . $options{endpoint},
get_param => $options{get_param},
header => ['icSessionId: ' . $token],
unknown_status => $self->{unknown_http_status},
warning_status => $self->{warning_http_status},
critical_status => $self->{critical_http_status}
);
}
if (!defined($content) || $content eq '') {
$self->{output}->add_option_msg(short_msg => "API returns empty content [code: '" . $self->{http}->get_code() . "'] [message: '" . $self->{http}->get_message() . "']");
$self->{output}->option_exit();
}
my $decoded;
eval {
$decoded = JSON::XS->new->allow_nonref(1)->utf8->decode($content);
};
if ($@) {
$self->{output}->add_option_msg(short_msg => "Cannot decode response (add --debug option to display returned content)");
$self->{output}->option_exit();
}
return $decoded;
}
1;
__END__
=head1 NAME
Informatica Intelligent Cloud Services API
=head1 REST API OPTIONS
Informatica Intelligent Cloud Services API
=over 8
=item B<--region>
Set region (default: 'eu'). Can be: asia, eu, us.
=item B<--port>
Port used (Default: 443)
=item B<--proto>
Specify https if needed (Default: 'https')
=item B<--api-username>
API username.
=item B<--api-password>
API password.
=item B<--timeout>
Set timeout in seconds (Default: 30).
=back
=head1 DESCRIPTION
B<custom>.
=cut

261
centreon-plugins/cloud/iics/restapi/mode/agents.pm Normal file
View File

@ -0,0 +1,261 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package cloud::iics::restapi::mode::agents;
use base qw(centreon::plugins::templates::counter);
use strict;
use warnings;
use centreon::plugins::templates::catalog_functions qw(catalog_status_threshold_ng);
sub custom_agent_status_output {
my ($self, %options) = @_;
return sprintf(
'readyToRun: %s [active: %s]',
$self->{result_values}->{readyToRun},
$self->{result_values}->{active}
);
}
sub custom_engine_status_output {
my ($self, %options) = @_;
return sprintf(
'status: %s [desired: %s]',
$self->{result_values}->{status},
$self->{result_values}->{desiredStatus}
);
}
sub agent_long_output {
my ($self, %options) = @_;
return sprintf(
"checking agent '%s'",
$options{instance_value}->{name}
);
}
sub prefix_agent_output {
my ($self, %options) = @_;
return sprintf(
"agent '%s' ",
$options{instance_value}->{name}
);
}
sub prefix_global_output {
my ($self, %options) = @_;
return 'Number of agents ';
}
sub prefix_engine_output {
my ($self, %options) = @_;
return sprintf(
"engine application '%s' ",
$options{instance_value}->{appDisplayName}
);
}
sub set_counters {
my ($self, %options) = @_;
$self->{maps_counters_type} = [
{ name => 'global', type => 0, cb_prefix_output => 'prefix_global_output' },
{
name => 'agents', type => 3, cb_prefix_output => 'prefix_agent_output', cb_long_output => 'agent_long_output', indent_long_output => ' ', message_multiple => 'All agents are ok',
group => [
{ name => 'agent_status', type => 0 },
{ name => 'engines', type => 1, cb_prefix_output => 'prefix_engine_output', message_multiple => 'engines are ok', display_long => 1, skipped_code => { -10 => 1 } }
]
}
];
$self->{maps_counters}->{global} = [
{ label => 'agents-detected', display_ok => 0, nlabel => 'agents.detected.count', set => {
key_values => [ { name => 'detected' } ],
output_template => 'detected: %s',
perfdatas => [
{ template => '%s', min => 0 }
]
}
}
];
$self->{maps_counters}->{agent_status} = [
{
label => 'agent-status',
type => 2,
critical_default => '%{active} eq "yes" and %{readyToRun} eq "no"',
set => {
key_values => [
{ name => 'id' }, { name => 'name' },
{ name => 'readyToRun' }, { name => 'active' }
],
closure_custom_output => $self->can('custom_agent_status_output'),
closure_custom_perfdata => sub { return 0; },
closure_custom_threshold_check => \&catalog_status_threshold_ng
}
}
];
$self->{maps_counters}->{engines} = [
{
label => 'engine-status',
type => 2,
set => {
key_values => [
{ name => 'status' }, { name => 'desiredStatus' },
{ name => 'agentName'}, { name => 'appDisplayName' }
],
closure_custom_output => $self->can('custom_engine_status_output'),
closure_custom_perfdata => sub { return 0; },
closure_custom_threshold_check => \&catalog_status_threshold_ng
}
}
];
}
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
bless $self, $class;
$options{options}->add_options(arguments => {
'filter-agent-id:s' => { name => 'filter_agent_id' },
'filter-agent-name:s' => { name => 'filter_agent_name' },
'filter-agent-active:s' => { name => 'filter_agent_active' }
});
return $self;
}
sub manage_selection {
my ($self, %options) = @_;
my $agents = $options{custom}->request_api(endpoint => '/api/v2/agent');
my $agentDetails = $options{custom}->request_api(endpoint => '/api/v2/agent/details/');
$self->{global} = { detected => 0 };
$self->{agents} = {};
foreach my $agent (@$agents) {
$agent->{active} = ($agent->{active} =~ /true|1/i ? 'yes' : 'no');
next if (defined($self->{option_results}->{filter_agent_active}) && $self->{option_results}->{filter_agent_active} ne '' &&
$agent->{active} !~ /$self->{option_results}->{filter_agent_active}/);
next if (defined($self->{option_results}->{filter_agent_id}) && $self->{option_results}->{filter_agent_id} ne '' &&
$agent->{id} !~ /$self->{option_results}->{filter_agent_id}/);
next if (defined($self->{option_results}->{filter_agent_name}) && $self->{option_results}->{filter_agent_name} ne '' &&
$agent->{name} !~ /$self->{option_results}->{filter_agent_name}/);
$self->{global}->{detected}++;
$self->{agents}->{ $agent->{id} } = {
name => $agent->{name},
agent_status => {
id => $agent->{id},
name => $agent->{name},
active => $agent->{active},
readyToRun => $agent->{readyToRun} =~ /true|1/i ? 'yes' : 'no'
},
engines => {}
};
foreach my $agentDetail (@$agentDetails) {
next if ($agentDetail->{id} ne $agent->{id});
foreach my $engine (@{$agentDetail->{agentEngines}}) {
$self->{agents}->{ $agent->{id} }->{engines}->{ $engine->{agentEngineStatus}->{appname} } = {
agentName => $agent->{name},
appDisplayName => $engine->{agentEngineStatus}->{appDisplayName},
desiredStatus => lc($engine->{agentEngineStatus}->{desiredStatus}),
status => lc($engine->{agentEngineStatus}->{status})
};
}
}
}
}
1;
__END__
=head1 MODE
Check agents.
=over 8
=item B<--filter-agent-id>
Filter agents by id.
=item B<--filter-agent-name>
Filter agents by name.
=item B<--filter-agent-active>
Filter agents if active or not.
=item B<--unknown-agent-status>
Set unknown threshold for status.
Can used special variables like: %{active}, %{readyToRun}, %{id}, %{name}
=item B<--warning-agent-status>
Set warning threshold for status.
Can used special variables like: %{active}, %{readyToRun}, %{id}, %{name}
=item B<--critical-agent-status>
Set critical threshold for status (Default: '%{active} eq "yes" and %{readyToRun} eq "no"').
Can used special variables like: %{active}, %{readyToRun}, %{id}, %{name}
=item B<--unknown-engine-status>
Set unknown threshold for status.
Can used special variables like: %{agentName}, %{appDisplayName}, %{status}, %{desiredStatus}
=item B<--warning-engine-status>
Set warning threshold for status.
Can used special variables like: %{agentName}, %{appDisplayName}, %{status}, %{desiredStatus}
=item B<--critical-engine-status>
Set critical threshold for status.
Can used special variables like: %{agentName}, %{appDisplayName}, %{status}, %{desiredStatus}
=item B<--warning-*> B<--critical-*>
Thresholds.
Can be: 'agents-detected'.
=back
=cut

111
centreon-plugins/cloud/iics/restapi/mode/listagents.pm Normal file
View File

@ -0,0 +1,111 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package cloud::iics::restapi::mode::listagents;
use base qw(centreon::plugins::mode);
use strict;
use warnings;
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options);
bless $self, $class;
$options{options}->add_options(arguments => {});
return $self;
}
sub check_options {
my ($self, %options) = @_;
$self->SUPER::init(%options);
}
sub manage_selection {
my ($self, %options) = @_;
my $agents = $options{custom}->request_api(endpoint => '/api/v2/agent');
my $results = [];
foreach my $agent (@$agents) {
$agent->{active} = ($agent->{active} =~ /true|1/i ? 'yes' : 'no');
push @$results, $agent;
}
return $results;
}
sub run {
my ($self, %options) = @_;
my $results = $self->manage_selection(%options);
foreach (@$results) {
$self->{output}->output_add(
long_msg => sprintf(
'[id: %s][name: %s][active: %s]',
$_->{id},
$_->{name},
$_->{active}
)
);
}
$self->{output}->output_add(
severity => 'OK',
short_msg => 'List agents:'
);
$self->{output}->display(nolabel => 1, force_ignore_perfdata => 1, force_long_output => 1);
$self->{output}->exit();
}
sub disco_format {
my ($self, %options) = @_;
$self->{output}->add_disco_format(elements => ['id', 'name', 'active']);
}
sub disco_show {
my ($self, %options) = @_;
my $results = $self->manage_selection(%options);
foreach (@$results) {
$self->{output}->add_disco_entry(
id => $_->{id},
name => $_->{name},
active => $_->{active}
);
}
}
1;
__END__
=head1 MODE
List agents.
=over 8
=back
=cut

49
centreon-plugins/cloud/iics/restapi/plugin.pm Normal file
View File

@ -0,0 +1,49 @@
#
# Copyright 2022 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package cloud::iics::restapi::plugin;
use strict;
use warnings;
use base qw(centreon::plugins::script_custom);
sub new {
my ($class, %options) = @_;
my $self = $class->SUPER::new(package => __PACKAGE__, %options);
bless $self, $class;
$self->{modes} = {
'agents' => 'cloud::iics::restapi::mode::agents',
'list-agents' => 'cloud::iics::restapi::mode::listagents'
};
$self->{custom_modes}->{api} = 'cloud::iics::restapi::custom::api';
return $self;
}
1;
__END__
=head1 PLUGIN DESCRIPTION
Check Informatica Intelligent Cloud Services through HTTP/REST API.
=cut