#
# Copyright 2021 Centreon (http://www.centreon.com/)
#
# Centreon is a full-fledged industry-strength solution that meets
# the needs in IT infrastructure and application monitoring for
# service performance.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
# Author : CHEN JUN , aladdin.china@gmail.com

package apps::kingdee::eas::mode::oracletable;

use base qw(centreon::plugins::templates::counter);

use strict;
use warnings;

sub set_counters {
    my ($self, %options) = @_;

    $self->{maps_counters_type} = [
        { name => 'datasource', type => 1, cb_prefix_output => 'prefix_datasource_output', skipped_code => { -10 => 1 } },
    ];

    $self->{maps_counters}->{datasource} = [
        { label => 'table-rows', nlabel => 'datasource.table.rows.count', set => {
                key_values => [ { name => 'num_rows' } ],
                output_template => 'number of rows: %s',
                perfdatas => [
                    { value => 'num_rows', template => '%s', min => 0, label_extra_instance => 1 },
                ],
            }
        },
        { label => 'table-actual-rows', nlabel => 'datasource.table.actual.rows.count', set => {
                key_values => [ { name => 'actual_num_rows' } ],
                output_template => 'number of actual rows: %s',
                perfdatas => [
                    { value => 'actual_num_rows', template => '%s', min => 0, label_extra_instance => 1 },
                ],
            }
        }
    ];
}

sub new {
    my ($class, %options) = @_;
    my $self = $class->SUPER::new(package => __PACKAGE__, %options, force_new_perfdata => 1);
    bless $self, $class;

    $options{options}->add_options(arguments => {
        'urlpath:s'    => { name => 'url_path', default => "/easportal/tools/nagios/checkoracletable.jsp" },
        'datasource:s' => { name => 'datasource' },
        'tablename:s'  => { name => 'tablename' , default => 'T_GL_VOUCHER' },
        'actualrows:s' => { name => 'actualrows', default => 'false' },
    });

    return $self;
}

sub prefix_datasource_output {
    my ($self, %options) = @_;

    return "Datasource table '" . $options{instance_value}->{display} . "' ";
}

sub check_options {
    my ($self, %options) = @_;
    $self->SUPER::check_options(%options);

    if (!defined($self->{option_results}->{datasource}) || $self->{option_results}->{datasource} eq "") {
        $self->{output}->add_option_msg(short_msg => 'Missing datasource name.');
        $self->{output}->option_exit();
    }
    $self->{option_results}->{url_path} .= 
        "?ds=" . $self->{option_results}->{datasource} 
        . "\&tablename=" . $self->{option_results}->{tablename}
        . "\&actual=" . $self->{option_results}->{actualrows};
}

sub manage_selection {
    my ($self, %options) = @_;

    my $webcontent = $options{custom}->request(path => $self->{option_results}->{url_path});
	if ($webcontent !~ /^TABLE_NAME=\w+/i) {
		$self->{output}->add_option_msg(short_msg => 'cannot find oracle table status');
		$self->{output}->option_exit();
	}

    my $name = $self->{option_results}->{datasource} . ':' . $self->{option_results}->{tablename};
    $self->{datasource}->{$name} = { display => $name };
    $self->{datasource}->{$name}->{num_rows} = $1 if ($webcontent =~ /NUM_ROWS=(\d+)/mi);
    $self->{datasource}->{$name}->{actual_num_rows} = $1 if ($webcontent =~ /ACTUAL_NUM_ROWS=(\d+)/mi);
}

1;

__END__

=head1 MODE

Check oracle table info for specify datasource.

=over 8

=item B<--urlpath>

Set path to get status page. (Default: '/easportal/tools/nagios/checkoracletable.jsp')

=item B<--datasource>

Specify the datasource name.

=item B<--tablename>

Specify the table name , MUST BE uppercase.

=item B<--actualrows>

Specify whether check actual rows of table or not , true or false. 
MAY have performance problem for large table if specify true. 

=item B<--warning-*> B<--critical-*>

Thresholds.
Can be: 'table-rows', 'table-actual-rows'.

=back

=cut